jsoto/MBS
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
77e844390e67511730304f5d3cf8cb0f8363011d
MBS/PROYECTO/indir/inprrp030.4gl
T
jpeguero efdf8953dd Reorganiza MATERIA PRIMA a PROYECTO y avanza inprmt002/005/013/046 
- Mueve todo el contenido de PROYECTOS/indir y varias funciones
  compartidas de PROYECTOS/otrodir hacia PROYECTO, siguiendo
  instruccion de Johnny (PROYECTOS se va a eliminar).
- inprmt002: agrega campo Desglose faltante, corrige typo "eLiminar".
- inprmt005: agrega formulario y 3 campos faltantes (Consumo,
  Requiere Autorizacion, Requisiciones), corrige typo "eLiminar".
- inprmt013: agrega formulario, titulo, corrige typo "eLiminar".
- inprmt046: agrega formulario y varias funciones/dependencias
  faltantes (cincodmov, clasf_bloque, medidas, defecto,
  buscaEmp, consultaTransportista, busca_departamento);
  corrige nombres de campo desalineados con el codigo
  (depto_a, bodega) y los convierte a ComboBox donde el
  codigo lo requiere.
- Corrige dependencia faltante de FORMULARIOS_IN a la libreria
  Database (bloqueaba todo el modulo de MATERIA PRIMA).
2026-08-26 13:31:09 -04:00

361 lines
13 KiB
Plaintext
Raw Blame History

{
-------------------------------------------------------------------------------
PROGRAMA : INPRRP030
OBJETIVO : Valorizacion Inventario (UEPS-PEPS)
PROGRAMADOR : Tadeo A. Ferreras F.
FECHA REALIZACION : Diciembre 08, 1994.
Observaciones : Programa sustiutido por el INPRRP034 y INPRRP035
-------------------------------------------------------------------------------
}
GLOBALS "inprgb000.4gl"
DEFINE cantidad_i ARRAY[3] OF DECIMAL(12,2)
DEFINE cantidad_h ARRAY[3] OF DECIMAL(12,2)
DEFINE precio_i ARRAY[3] OF DECIMAL(10,4)
DEFINE precio_h ARRAY[3] OF DECIMAL(10,4)
DEFINE ano_act CHAR(4)
DEFINE fecha_corte DATE
DEFINE descrip_esp CHAR(30)
DEFINE unidad_med CHAR(3)
DEFINE valor_1,valor_2,valor_3,cantidad_2,precio1,valor,
costo_st,cantidad1,cantidad3 DECIMAL(12,4)
DEFINE metodo,j,idx1 INTEGER
DEFINE salir,salir1 CHAR(1)
DEFINE inventa30 RECORD
cod_n SMALLINT,
cod_grupo SMALLINT,
cod_tipo SMALLINT,
cod_sec SMALLINT,
descrip_esp CHAR(30),
unidad_med CHAR(3),
fecha DATE,
cantidad DECIMAL(12,2),
precio DECIMAL(10,4),
costo_st DECIMAL(10,4)
END RECORD
DEFINE inventa30_1 RECORD
cod_n SMALLINT,
cod_grupo SMALLINT,
cod_tipo SMALLINT,
cod_sec SMALLINT,
fecha DATE,
cantidad DECIMAL(12,2),
precio DECIMAL(12,2)
END RECORD
FUNCTION inprrp30()
# WHENEVER ERROR CONTINUE
OPTIONS
FORM LINE 8,
ERROR LINE 23,
COMMENT LINE 21
OPEN FORM infmrp30 FROM "infmrp30"
DISPLAY FORM infmrp30
CALL pantalla()
DISPLAY "inprrp030 " AT 4,3
DISPLAY "Valorizacion Inventario (UEPS-PEPS)" AT 6,22
LET tipo_papel = 2
CALL msgrp000(tipo_papel)
INPUT BY NAME datos_cons.fech_fi,metodo
AFTER FIELD fech_fi
IF datos_cons.fech_fi IS NULL THEN
LET numero_msg = 16
CALL msg(numero_msg)
NEXT FIELD fech_fi
END IF
AFTER FIELD metodo
IF metodo IS NULL THEN
LET numero_msg = 16
CALL msg(numero_msg)
NEXT FIELD metodo
END IF
END INPUT
IF int_flag THEN
LET numero_msg = 2
CALL msg(numero_msg)
LET int_flag = false
RETURN
END IF
CONSTRUCT criterio ON d.cod_n,d.cod_grupo,d.cod_tipo,d.cod_sec
FROM cod_n,cod_grupo,cod_tipo,cod_sec
LET ano_act = year(datos_cons.fech_fi)
LET selec =
"SELECT d.cod_n,d.cod_grupo,d.cod_tipo,d.cod_sec,d.descrip_esp, ",
" d.unidad_med,a.fecha,a.cantidad,a.costo_lq,c.costo_st, ",
" MAX(c.mes_fin) ",
"FROM intb00001 d,intb00013 c,cttb00013 a ",
"WHERE d.cod_n = a.cod_n AND d.cod_grupo = a.cod_grupo AND ",
" d.cod_tipo = a.cod_tipo AND d.cod_sec = a.cod_sec AND ",
" d.cod_n = c.cod_n AND d.cod_grupo = c.cod_grupo AND ",
" d.cod_tipo = c.cod_tipo AND d.cod_sec = c.cod_sec AND ",
" c.ano = ? and ",
criterio CLIPPED," AND d.status_t IS NULL AND a.fecha <=? ",
"GROUP BY 1,2,3,4,5,6,7,8,9,10 "
DISPLAY "<< Buscando Inventario Final ... Espere Por Favor" AT 19,14
PREPARE busca FROM selec
DECLARE busca1 CURSOR FOR busca
OPEN busca1 USING ano_act,datos_cons.fech_fi
START REPORT reporte_30 TO "C:\\archivo"
DISPLAY "<< Reporte Generandose ... Por Favor Espere. >>" AT 19,14
LET valor_1 = 0
LET valor_2 = 0
LET valor_3 = 0
LET salir = "N"
WHILE salir != "S"
FETCH busca INTO inventa30.*
IF status = notfound THEN
LET salir = "S"
EXIT WHILE
END IF
OUTPUT TO REPORT reporte_30(inventa30.*)
END WHILE
FINISH REPORT reporte_30
RUN "type C:\\archivo > %USPRINT%" END FUNCTION
REPORT reporte_30(x)
DEFINE x RECORD
cod_n SMALLINT,
cod_grupo SMALLINT,
cod_tipo SMALLINT,
cod_sec SMALLINT,
descrip_esp CHAR(30),
unidad_med CHAR(3),
fecha DATE,
cantidad DECIMAL(12,2),
precio DECIMAL(10,4),
costo_st DECIMAL(10,4)
END RECORD
DEFINE t_valor_p,t_valor_c,diferencia,valor_p,valor_c,total_c,
total_p DECIMAL (12,2)
DEFINE doble_on CHAR(2)
DEFINE doble_off CHAR(2)
DEFINE negrillas_on CHAR(2)
DEFINE negrillas_off CHAR(2)
DEFINE comp_on CHAR(3)
DEFINE comp_off CHAR(3)
DEFINE doce CHAR(3)
DEFINE hora CHAR(5)
OUTPUT
TOP MARGIN 0
LEFT MARGIN 0
BOTTOM MARGIN 2
ORDER BY x.cod_n,x.cod_grupo,x.cod_tipo,x.cod_sec,x.fecha DESC
FORMAT
PAGE HEADER
LET doble_on = ASCII 14
LET doble_off = ASCII 20
LET negrillas_on = ASCII 27, ASCII 69
LET negrillas_off = ASCII 27, ASCII 70
LET comp_on = ASCII 15
LET comp_off = ASCII 18
LET doce = ASCII 27, ASCII 77
LET hora = time
LET lj = (205 - LENGTH(p_companias.nombre CLIPPED))/2
PRINT COLUMN 1, comp_on,negrillas_on
PRINT COLUMN 1, "inprrp030",
COLUMN lj, p_companias.nombre CLIPPED,
COLUMN 198, "Pag. ", pageno using "###"
PRINT COLUMN 80, " SISTEMA DE INVENTARIO DE MATERIA PRIMA",
COLUMN 198, today using "dd/mm/yyyy"
IF metodo = 1 THEN
PRINT COLUMN 80, " VALORIZACION INVENTARIO (UEPS) ",
COLUMN 201, hora
ELSE
PRINT COLUMN 80, " VALORIZACION INVENTARIO (PEPS) ",
COLUMN 201, hora
END IF
SKIP 1 LINE
PRINT COLUMN 1, "FECHA DE CORTE : AL ",
datos_cons.fech_fi using "dd/mm/yyyy"
PRINT COLUMN 1, "----------------------------------------------",
"----------------------------------------------",
"----------------------------------------------",
"----------------------------------------------",
"----------------------"
IF metodo = 1 THEN
PRINT COLUMN 47, "| INVENTARIO PRECIO STANDARD",
"| < ANTEPENULTIMA COMPRA >",
"| < PENULTIMA COMPRA > ",
"| < ULTIMA COMPRA > || ",
"| | |"
ELSE
PRINT COLUMN 47, "| INVENTARIO PRECIO STANDARD",
"| < ULTIMA COMPRA > ",
"| < PENULTIMA COMPRA > ",
"| < ANTEPENULTIMA COMPRA >|| ",
"| | |"
END IF
PRINT COLUMN 47, "|---------------------------------------",
"--------------------------",
"--------------------------",
"--------------------------|| VALORIZACION ",
"|---------|-------------|"
PRINT COLUMN 1, "MATERIAL",
COLUMN 47, "| CANTIDAD PRECIO VALOR ",
"| CANTIDAD PRECIO ",
"| CANTIDAD PRECIO ",
"| CANTIDAD PRECIO || AL REAL ",
"|PROM | VARIACION |"
PRINT COLUMN 1, "----------------------------------------------",
"----------------------------------------------",
"----------------------------------------------",
"----------------------------------------------",
"----------------------"
PRINT negrillas_off
BEFORE GROUP OF x.cod_sec
LET valor = 0
LET cantidad3 = 0
LET precio1 = 0
LET l = 86
LET cantidad_2 = 0
SELECT SUM(a.cantidad_2) INTO cantidad_2
FROM intb00006 a
WHERE a.cod_n = x.cod_n AND a.cod_grupo = x.cod_grupo AND
a.cod_tipo = x.cod_tipo AND a.cod_sec = x.cod_sec AND
a.status_t IS NULL AND a.fecha <= datos_cons.fech_fi
IF cantidad_2 IS NULL OR cantidad_2 < 0 THEN
LET cantidad_2 = 0
END IF
IF x.costo_st IS NULL THEN
LET x.costo_st = 0
END IF
FOR j = 1 TO 3
LET cantidad_i[j] = 0
LET precio_i[j] = 0
LET cantidad_h[j] = 0
LET precio_h[j] = 0
END FOR
PRINT COLUMN 1,x.cod_n USING "&","-",x.cod_grupo USING "&","-",
x.cod_tipo USING "&&","-",x.cod_sec USING "&&&"," ",
x.descrip_esp," ",x.unidad_med CLIPPED,
COLUMN 47,cantidad_2 USING "###,###,###.##"," ",
x.costo_st USING "#,###.####"," ",
cantidad_2*x.costo_st USING "###,###,###.##";
IF valor_2 IS NULL THEN
LET valor_2 = 0
END IF
LET valor_2 = valor_2 + (cantidad_2 * x.costo_st)
LET cantidad1 = cantidad_2
LET j = 0
ON EVERY ROW
IF x.cantidad > 0 THEN
LET j = j + 1
IF j <= 3 THEN
LET cantidad_h[j] = x.cantidad
LET precio_h[j] = x.precio
END IF
END IF
AFTER GROUP OF x.cod_sec
IF metodo = 1 THEN
LET cantidad_i[1] = cantidad_h[3]
LET precio_i[1] = precio_h[3]
LET cantidad_i[2] = cantidad_h[2]
LET precio_i[2] = precio_h[2]
LET cantidad_i[3] = cantidad_h[1]
LET precio_i[3] = precio_h[1]
ELSE
LET cantidad_i[1] = cantidad_h[1]
LET precio_i[1] = precio_h[1]
LET cantidad_i[2] = cantidad_h[2]
LET precio_i[2] = precio_h[2]
LET cantidad_i[3] = cantidad_h[3]
LET precio_i[3] = precio_h[3]
END IF
FOR j = 1 TO 3
IF cantidad_i[j] IS NULL THEN
LET cantidad_i[j] = 0
LET precio_i[j] = 0
END IF
IF precio_i[j] IS NULL THEN
LET precio_i[j] = 0
END IF
PRINT COLUMN l,"|", cantidad_i[j] USING "###,###,###.##"," ",
precio_i[j] USING "#,###.####";
LET l = l + 26
END FOR
FOR j = 1 TO 3
IF precio_i[j] > 0 THEN
LET precio1 = precio_i[j]
END IF
IF cantidad_i[j] <= cantidad1 THEN
LET valor = valor + (cantidad_i[j]*precio1)
LET cantidad1 = cantidad1 - cantidad_i[j]
ELSE
LET valor = valor + (cantidad1 * precio1)
EXIT FOR
END IF
END FOR
IF cantidad_i[1] >= cantidad_2 THEN
LET valor = cantidad_2*precio_i[1]
END IF
PRINT COLUMN l, "|",valor USING "###,###,###.##",
"|",(precio_i[1]+precio_i[2]+precio_i[3])/3
USING "#,###.####",
"|",((cantidad_2*x.costo_st) - valor)
USING "###,###,###.##"
IF valor_1 IS NULL THEN
LET valor_1 = 0
END IF
IF valor_3 IS NULL THEN
LET valor_3 = 0
END IF
LET valor_1 = valor_1 + valor
LET valor_3 = valor_3 + ((cantidad_2 * x.costo_st) - valor)
ON LAST ROW
PRINT COLUMN 1, "----------------------------------------------",
"----------------------------------------------",
"----------------------------------------------",
"----------------------------------------------",
"----------------------"
PRINT COLUMN 1, "totales --->",
COLUMN 74, valor_2 USING "###,###,###.##",
COLUMN l+1, "|",valor_1 USING "###,###,###.##",
"|", " ",
"|",valor_3 USING "###,###,###.##"
PRINT COLUMN 1, "----------------------------------------------",
"----------------------------------------------",
"----------------------------------------------",
"----------------------------------------------",
"----------------------"
LET valor_1 = 0
LET valor_2 = 0
LET valor_3 = 0
PRINT COLUMN 1,comp_off
END REPORT
Reference in New Issue View Git Blame Copy Permalink