{
-------------------------------------------------------------------------------
PROGRAMA             :  IRPRRP014
OBJETIVO             :  Validacion Maestra de Motores
PROGRAMADOR          :  Tadeo A. Ferreras F.       
FECHA REALIZACION    :  Enero 29, 1993.  
-------------------------------------------------------------------------------
}
GLOBALS "irprgb000.4gl"

MAIN                
   DEFER INTERRUPT
   SELECT * INTO p_companias.* FROM companias
   CALL irprrp14()
END MAIN

FUNCTION irprrp14()
    DEFINE sel_exist CHAR(300)
    DEFINE salir1,salir CHAR(1)
    DEFINE idx1,idx SMALLINT 
    DEFINE hoy DATE

    DEFINE motor RECORD LIKE irtb00007.*
    DEFINE cod SMALLINT 

 #WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

    CLEAR SCREEN

    OPEN FORM irfmrp14 FROM "irfmrp014"
    DISPLAY FORM irfmrp14
    CALL pantalla()
    DISPLAY "irprrp014" AT 4,3
    DISPLAY "Validacion  Motores" AT 6,31

    LET tipo_papel = 2
    CALL msgrp000(tipo_papel)

    INPUT BY NAME decide
     AFTER FIELD decide
     IF decide IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD decide
     END IF
    END INPUT

    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
    END IF

    CONSTRUCT criterio ON a.codigo_m,a.marca
                     FROM codigo_m,marca 
    IF decide = "A" THEN 
    LET SELEC = 
      "SELECT a.* FROM irtb00007 a ",
      "WHERE a.status_t IS NULL AND ",criterio CLIPPED," ORDER BY a.marca "
    ELSE 
    LET SELEC = 
      "SELECT a.* FROM irtb00007 a ",
      "WHERE a.status_t IS NULL AND ",criterio CLIPPED," ORDER BY a.codigo_m "
    END IF

    DISPLAY "<< Buscando Informacion ... Espere Por Favor >>" AT 19,14
             ATTRIBUTE (BOLD)

    START REPORT reporte_14 TO "C:\\archivo"
    PREPARE busca FROM selec
    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
    END IF

    DECLARE accion CURSOR FOR busca

      DISPLAY "                                                " 
              AT 19,14 
      DISPLAY "<< Reporte Generandose ...  Por Favor Espere >>" 
              AT 19,14 ATTRIBUTE (REVERSE) 

    FOREACH accion INTO motor.* 

        IF int_flag THEN
         LET numero_msg = 2
         CALL msg(numero_msg)
         LET int_flag = false
         RETURN
        END IF

   OUTPUT TO REPORT reporte_14(motor.*)
   END FOREACH

    FINISH REPORT reporte_14

    CLEAR SCREEN

RUN "type C:\\archivo > %USPRINT%" END FUNCTION

    REPORT reporte_14(x)
    DEFINE x RECORD LIKE irtb00007.*

    DEFINE l smallint
    DEFINE varia CHAR(20)
    DEFINE descripcion CHAR(60)
    DEFINE primera CHAR(1)
    DEFINE doble_on CHAR(6)
    DEFINE doble_off CHAR(6)
    DEFINE negrillas_on CHAR(6)
    DEFINE negrillas_off CHAR(6)
    DEFINE comp_on CHAR(6)
    DEFINE comp_off CHAR(6) 
    DEFINE normal CHAR(6)
    DEFINE doce CHAR(6)
    DEFINE hora CHAR(5)
    OUTPUT
     TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 2
    FORMAT
      PAGE HEADER
        LET doble_on =  ASCII 14 
        LET doble_off = ASCII 002
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET comp_on = ASCII 15
        LET comp_off = ASCII 18 
        LET normal = ASCII 27,ASCII 80
        LET hora = time
           PRINT COLUMN  1, comp_on,negrillas_on
           PRINT COLUMN  1, "irprrp014", 
                 COLUMN  71, "              M A R M O T E C H  S. A.",
                 COLUMN 181, "Pag.  ",pageno using "<<<"
           PRINT COLUMN  71, "      Sistema de Inventario de Repuestos    ",
                 COLUMN 181, today using "dd/mm/yy"
           PRINT COLUMN  71, "              Validacion  Motores",
                 COLUMN 184, hora
             IF decide = "N" THEN
                 LET varia = "N u m e r i c o"
           ELSE 
                 LET varia = "A l f a b e t i c o"
       END IF
          LET l = (182 - LENGTH(varia))/2 

        PRINT COLUMN l, varia clipped
        PRINT COLUMN 1, "----------------------------------------------------",
                        "----------------------------------------------------",
                        "----------------------------------------------------",
                        "--------------------------------"
        PRINT COLUMN   1, "Codigo",
              COLUMN  30, "Frame",
              COLUMN  42, "Numero",
              COLUMN  60, "Fase",
              COLUMN  70, "Serie",
              COLUMN  92, "RPM X 1000",  
              COLUMN 103, "HP",  
              COLUMN 112, "Voltaje",  
              COLUMN 121, "Amperaje",
              COLUMN 130, "Ciclo",
              COLUMN 140, "Tipo",
              COLUMN 152, "Modelo"
        PRINT COLUMN 1, "----------------------------------------------------",
                        "----------------------------------------------------",
                        "----------------------------------------------------",
                        "--------------------------------"
        PRINT COLUMN 1, negrillas_off

      ON EVERY ROW

         PRINT COLUMN   1, x.codigo_m USING "&&&&"," ",x.marca,
               COLUMN  30, x.frame, 
               COLUMN  42, x.numero,
               COLUMN  60, x.fase_m USING "&&&&",
               COLUMN  70, x.serie,
               COLUMN  92, x.rpm_m/1000 USING "#,###,###",
               COLUMN 103, x.hp_m,
               COLUMN 112, x.voltaje,
               COLUMN 121, x.amperaje,
               COLUMN 130, x.ciclo USING "###,###",
               COLUMN 140, x.tipo,
               COLUMN 152, x.modelo
     SKIP 1 LINE

     ON LAST ROW
        PRINT COLUMN 1, "====================================================",
                        "====================================================",
                        "====================================================",
                        "================================"
       PRINT COLUMN 3, "Total de Registros Impresos = ", count(*) USING "####"
       PRINT COLUMN 3, comp_off

     END REPORT