{
------------------------------------------------------------------------------
 PROGRAMA          : IPPRCS003
 OBJETIVO          : Programa Consulta Balances Producto Terminado.
                     (Factor de Conversion)
 PROGRAMADOR       : Tadeo A. Ferreras F.   
 FECHA REALIZACION : Febrero 08, 1996
------------------------------------------------------------------------------
}
GLOBALS
  "ipprgb000.4gl"

FUNCTION ipprcs003()

  DEFINE segunda CHAR(1)
  DEFINE cajas INTEGER
  DEFINE fecha1 char(8)
  DEFINE hora1 char(5)
  DEFINE balance_in DECIMAL(12,2)
  DEFINE primera CHAR(1)
  DEFINE nombre CHAR(8)
  LET fecha1 = today using "dd/mm/yy"
  LET hora1 = time
  LET int_flag = false
  LET bandera = 0
  
# WHENEVER ERROR CONTINUE

  CLEAR SCREEN
  OPTIONS
    ERROR LINE 24,
    FORM LINE 4,
    COMMENT LINE 22,
    PROMPT LINE 23
    DISPLAY " R A Y . O . V A C  D O M I N I C A N A " AT 1,19
            ATTRIBUTE (REVERSE,BLUE)
    DISPLAY fecha1 AT 1,70 ATTRIBUTE (BLUE)
    DISPLAY hora1 AT 2,73 ATTRIBUTE (BLUE)
    DISPLAY "Balances Productos            (Factor De Conversion)" AT 2,14 
    DISPLAY "<Esc> Continua Consultando" AT 3,2 ATTRIBUTE (BLUE,REVERSE)
    DISPLAY "<Delete> Cancela Operacion"    AT 3,56 ATTRIBUTE (BLUE,REVERSE)
    DISPLAY "ipprcs003" AT 1,3 ATTRIBUTE (BLUE)
    OPEN FORM ipfmcs003 FROM "ipfmcs006" 
    DISPLAY FORM ipfmcs003
   
    INITIALIZE datos_gen.* TO NULL

    LABEL volver:
    INPUT BY NAME datos_cons.*                                   

     BEFORE FIELD fech_in
      LET datos_cons.fech_in = today using "dd/mm/yy"
      DISPLAY BY NAME datos_cons.fech_in

     BEFORE FIELD fech_fi
       LET datos_cons.fech_fi = today using "dd/mm/yy"
       DISPLAY BY NAME datos_cons.fech_fi

     AFTER FIELD cod_sec
      IF datos_cons.cod_n is not null and
         datos_cons.cod_grupo is not null and
         datos_cons.cod_tipo is not null and
         datos_cons.cod_sec is not null THEN

         SELECT descrip_esp,descrip_ing,unidad_med 
         INTO descripcion,descrip1,articulos.unidad_med
         FROM intb00001
         WHERE cod_n = datos_cons.cod_n and cod_grupo = datos_cons.cod_grupo and
               cod_tipo=datos_cons.cod_tipo and cod_sec = datos_cons.cod_sec and
               status_t is null

         IF STATUS = NOTFOUND THEN
            LET numero_msg = 3
            CALL msg(numero_msg)
            CLEAR FORM
            NEXT FIELD cod_n  
         END IF
      END IF

      LET descripcion = descripcion CLIPPED
      DISPLAY BY NAME descripcion ,articulos.unidad_med

      LET p_conteo.cantidad = 1
      SELECT cantidad INTO p_conteo.cantidad FROM vetb00014
      WHERE cod_n = datos_cons.cod_n and cod_grupo = datos_cons.cod_grupo and
            cod_tipo = datos_cons.cod_tipo and cod_sec = datos_cons.cod_sec and
            status_t is null

      IF p_conteo.cantidad IS NULL THEN
         LET p_conteo.cantidad = 1
      END IF
 
   AFTER FIELD bodega
      IF datos_cons.bodega IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD bodega
      END IF
      SELECT * FROM intb00009 where cod_bodega = datos_cons.bodega
      IF STATUS = NOTFOUND THEN
         LET numero_msg = 3
         CALL msg(numero_msg)
         NEXT FIELD bodega
      END IF

      SELECT a.* FROM iptb00002 a
      WHERE a.cod_n = datos_cons.cod_n and a.cod_grupo=datos_cons.cod_grupo and
            a.cod_tipo=datos_cons.cod_tipo and a.cod_sec=datos_cons.cod_sec and
            a.bodega= datos_cons.bodega

      IF STATUS = NOTFOUND THEN
         LET numero_msg = 3
         CALL msg(numero_msg)
         CLEAR FORM
         NEXT FIELD cod_n  
      END IF

   AFTER FIELD fech_in
      IF datos_cons.fech_in IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD fech_in
      END IF

   AFTER FIELD fech_fi
      IF datos_cons.fech_fi IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD fech_fi
      END IF

      IF datos_cons.fech_in > datos_cons.fech_fi THEN
         LET numero_msg = 36
         CALL msg(numero_msg)
         NEXT FIELD fech_in
      END IF

   AFTER INPUT             
      IF int_flag THEN
         LET numero_msg = 2
         CALL msg(numero_msg)
         LET int_flag = false
         CLEAR SCREEN
         RETURN
      END IF

   EXIT INPUT
 END INPUT

 DISPLAY "Buscando Informacion... Espere Por Favor" AT 24,2 ATTRIBUTE (BLUE)

   SELECT SUM(cantidad_2) INTO balance FROM iptb00006 
   WHERE cod_n = datos_cons.cod_n and cod_grupo = datos_cons.cod_grupo and
        cod_tipo = datos_cons.cod_tipo and cod_sec  = datos_cons.cod_sec and
        fecha < datos_cons.fech_in and status_t is null 

   IF balance IS NULL THEN
      SELECT cantidad_2 INTO balance FROM iptb00006 
      WHERE cod_n=datos_cons.cod_n and cod_grupo = datos_cons.cod_grupo and
            cod_tipo=datos_cons.cod_tipo and cod_sec=datos_cons.cod_sec and
            cod_mov = 99 and                      status_t is null
   END IF
   LET balance = balance/p_conteo.cantidad

   DISPLAY "Balance Inicial Al: " AT 13,30 ATTRIBUTE (BLUE)
   DISPLAY datos_cons.fech_in using "dd/mm/yy" AT 13,51 ATTRIBUTE (BLUE)
   DISPLAY balance using "---,---,---" AT 13,62 ATTRIBUTE (BLUE)

   DECLARE jhonn_1  CURSOR FOR 
   SELECT unique p.num_doc,p.fecha,p.cantidad_2,p.cod_mov FROM iptb00006 p 
   WHERE p.cod_n = datos_cons.cod_n and p.cod_grupo = datos_cons.cod_grupo and 
         p.cod_tipo = datos_cons.cod_tipo and p.cod_sec=datos_cons.cod_sec and  
         p.status_t is null and p.bodega = datos_cons.bodega and
         p.fecha between datos_cons.fech_in and datos_cons.fech_fi and
         p.cod_mov != 99 ORDER BY 2,1

   OPEN jhonn_1 
   LET idx = 1

FOREACH  jhonn_1  INTO csmov.*

   CALL integridad()
   IF bandera = 1 THEN
      LET bandera = 0  
      RETURN
   END IF
   
   LET balance = balance + (csmov.cantidad_2/p_conteo.cantidad)
   LET csmov1[idx].fecha_2 = csmov.fecha_1
   LET csmov1[idx].balance = balance USING "---,---,---"
   LET csmov1[idx].num_doc = "(",csmov.cod_mov using "&&",")"," ",
                                 csmov.num_doc USING "&&&&&&"

    LET cajas = csmov.cantidad_2/p_conteo.cantidad
    IF csmov.cantidad_2 < 0 THEN
       LET csmov1[idx].entrada = null
       LET csmov1[idx].salida  = cajas USING "---,---,---"
    ELSE 
       LET csmov1[idx].salida  = null
       LET csmov1[idx].entrada = cajas USING "###,###,###"
    END IF

    IF idx < 9 THEN
       DISPLAY csmov1[idx].num_doc TO s_csmov[idx].num_doc
       DISPLAY csmov1[idx].fecha_2  TO s_csmov[idx].fecha
       DISPLAY csmov1[idx].entrada TO s_csmov[idx].entrada
       DISPLAY csmov1[idx].salida  TO s_csmov[idx].salida
       DISPLAY csmov1[idx].balance TO s_csmov[idx].balance
    END IF

       LET idx = idx + 1
 END FOREACH

   DISPLAY "                                                       " AT 24,2
   LET balance = 0
   CALL set_count(idx - 1)

 DISPLAY ARRAY csmov1 TO s_csmov.*
  IF int_flag THEN
     LET numero_msg = 2
     CALL msg(numero_msg)
     LET int_flag = false
     CLEAR SCREEN
     RETURN
  END IF
  CLEAR FORM
  DISPLAY "                                                       " AT 13,6
  DISPLAY "                  " AT 13,60
 GOTO volver
END FUNCTION