{
-------------------------------------------------------------------------------
PROGRAMA             :  INPRRP033
OBJETIVO             :  Dias de Inv. Categorizado (Temporal para Beato)
PROGRAMADOR          :  Tadeo Ferreras             
FECHA REALIZACION    :  Agosto 28, 1995
-------------------------------------------------------------------------------
}
GLOBALS "inprgb000.4gl"

DEFINE sale CHAR(1)
DEFINE p_ano CHAR(4)
DEFINE codigo_act CHAR(10)
DEFINE costo_e DECIMAL(12,4)


# Variable que se incrementa para imprimir el arreglo
DEFINE i SMALLINT

    DEFINE valor1 DECIMAL(12,2)

FUNCTION inprrp033()

# Variable que toma el valor de los dias que se va a valorar el reporte
DEFINE c_dias SMALLINT

# Variables varias para el control de busqueda de las informaciones
    DEFINE selec1,selec2,selec3,select_bal CHAR(1000)
    DEFINE mes CHAR(2)
    DEFINE tiene,salir,primera CHAR(1)
    DEFINE idx_3,idx_1,idx_b SMALLINT
    DEFINE dias1 SMALLINT

# Record para la validacion de los costos del material
    DEFINE costo RECORD
           mes1         CHAR(2),
           mes2         CHAR(2),
           cod_n        LIKE intb00001.cod_n,
           cod_grupo    LIKE intb00001.cod_grupo,
           cod_tipo     LIKE intb00001.cod_tipo,
           cod_sec      LIKE intb00001.cod_sec,
           costo_st     LIKE intb00013.costo_st
    END RECORD

# Record para el consumo de los materiales
    DEFINE consume RECORD
           cod_n        LIKE intb00001.cod_n,
           cod_grupo    LIKE intb00001.cod_grupo,
           cod_tipo     LIKE intb00001.cod_tipo,
           cod_sec      LIKE intb00001.cod_sec,
           consumo      DECIMAL(14,2)
    END RECORD

# Record para la impresion del reporte, estas variables se validan con el
# select que esta en la variable selec
    DEFINE estadis  RECORD
           cod_n        LIKE intb00001.cod_n,
           cod_grupo    LIKE intb00001.cod_grupo,
           cod_tipo     LIKE intb00001.cod_tipo,
           cod_sec      LIKE intb00001.cod_sec,
           descrip_esp  LIKE intb00001.descrip_esp,
           unidad_med   LIKE intb00001.unidad_med,
           dia_llegada  LIKE intb00002.dia_llegada,
           categoria    LIKE intb00014.categoria,
           consumo      LIKE intb00006.cantidad_1,
           existe       LIKE intb00002.existencia,
           valor        DECIMAL(12,4),
           costo        DECIMAL(12,4),
           dias         INTEGER 
    END RECORD

# Record para las existencia de la materia prima
    DEFINE balances RECORD
     cod_n   SMALLINT,
     cod_grupo SMALLINT,
     cod_tipo  SMALLINT,
     cod_sec   SMALLINT,
     balance   LIKE intb00006.cantidad_2
    END RECORD

#     WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

    OPEN FORM infmrp033 FROM "infmrp004"
    DISPLAY FORM infmrp033
    CALL pantalla()
    DISPLAY "inprrp033" AT 4,3
    DISPLAY "Dias de Inventarios Categoriados" AT 6,24
    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

    INPUT BY NAME datos_cons.fech_in,datos_cons.fech_fi
 
    AFTER FIELD fech_in
    IF datos_cons.fech_in IS NULL THEN
       LET numero_msg = 16
       CALL msg(numero_msg)
       NEXT FIELD fech_in
     END IF

    AFTER FIELD fech_fi
    IF datos_cons.fech_fi IS NULL THEN
       LET numero_msg = 16
       CALL msg(numero_msg)
       NEXT FIELD fech_fi
     END IF
   END INPUT

    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = false
       RETURN
    END IF
   LET dias1 = datos_cons.fech_fi - datos_cons.fech_in
   LET dias1 = dias1 + 1
   LET p_ano = year(datos_cons.fech_fi)
display dias1 at 24,1

    CONSTRUCT criterio ON b.cod_n,b.cod_grupo,b.cod_tipo,b.cod_sec
                     FROM cod_n,cod_grupo,cod_tipo,cod_sec

    IF int_flag THEN
      LET numero_msg = 2
      CALL msg(numero_msg)
      LET int_flag = false
      RETURN
    END IF
    LET c_dias = 0

# Busqueda de los costos de los materiales
   LET selec1 =
       "SELECT b.mes_ini,max(b.mes_fin),b.cod_n,b.cod_grupo,b.cod_tipo, ",
       "       b.cod_sec,b.costo_st ",
       "FROM intb00013 b ",
       "WHERE ",criterio clipped," and ano = ? ",
       "GROUP BY 1,3,4,5,6,7 ORDER BY 3,4,5,6"

    DISPLAY "<< Estoy Buscando Costos... Espere    >>" AT 19,14 

   PREPARE comando FROM selec1
   DECLARE busca3 SCROLL CURSOR FOR comando
   OPEN busca3 USING p_ano

   LET select_bal =
   "SELECT b.cod_n,b.cod_grupo,b.cod_tipo,b.cod_sec,sum(b.cantidad_2)  ",
   "FROM intb00006 b ",
   "WHERE ", criterio clipped," and b.status_t is null and b.fecha <= ? ",   
   "GROUP BY 1,2,3,4 ORDER BY 1,2,3,4"

    DISPLAY "<< Estoy Buscando Balances Iniciales  >>" AT 19,14 

    PREPARE busca_balan FROM select_bal
    DECLARE material_bal SCROLL CURSOR FOR busca_balan
    OPEN material_bal USING datos_cons.fech_fi

    LET SELEC = 
       "SELECT a.cod_n,a.cod_grupo,a.cod_tipo,a.cod_sec,a.descrip_esp, ",
       "       a.unidad_med,b.dia_llegada,c.categoria ",
       "FROM intb00001 a,intb00002 b,intb00014 c ",
       "WHERE ",criterio clipped," AND a.status_t IS NULL AND ",
       "      a.cod_n = b.cod_n AND a.cod_grupo = b.cod_grupo AND ",
       "      a.cod_tipo = b.cod_tipo AND a.cod_sec   = b.cod_sec AND ",
       "      a.cod_n = c.cod_n AND a.cod_grupo = c.cod_grupo AND ",
       "      a.cod_tipo = c.cod_tipo AND a.cod_sec   = c.cod_sec ",
       "ORDER BY 8,1,2,3,4"

    PREPARE busca  FROM selec
    DECLARE accion CURSOR FOR busca
    OPEN accion 

   LET selec3 =
      "SELECT b.cod_n,b.cod_grupo,b.cod_tipo,b.cod_sec,sum(b.cantidad_2)  ",
      "FROM intb00006 b ",
      "WHERE ",criterio clipped," AND b.status_t is null AND ",
      "         b.fecha between ? AND ? AND b.cod_mov = 36 ",
      "GROUP BY 1,2,3,4 ORDER BY 1,2,3,4"

    DISPLAY "<< Buscando Consumo Material... Por Favor Espere >>"
            AT 19,14 ATTRIBUTE (REVERSE) 

    PREPARE comando2 FROM selec3     
    DECLARE consu SCROLL CURSOR FOR comando2
    OPEN consu USING datos_cons.fech_in,datos_cons.fech_fi

    DISPLAY "<< Reporte Generandose ...  Por Favor Espere. >>"
            AT 19,14 ATTRIBUTE (REVERSE) 

    START REPORT reporte_33 TO "C:\\archivo" 

# Loop principal para la busqueda de la materia prima y el consumo
  LET idx = 1
  LET salir = "N"
  WHILE salir != "S"       
    FETCH   accion INTO estadis.* 
    IF status = notfound THEN
       LET salir = "S"
       EXIT WHILE
    END IF
    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = false
       RETURN
    END IF

     LET estadis.consumo = 0
     LET estadis.existe  = 0
     LET estadis.valor   = 0
     LET estadis.costo   = 0

 LET idx_b = 1
 LET sale = "N"
 WHILE sale != "S"
 FETCH ABSOLUTE idx_b consu INTO consume.*
 IF status = notfound THEN
    LET sale = "S"
    EXIT WHILE
 END IF
 LET idx_b = idx_b + 1
 IF consume.cod_n = estadis.cod_n AND
    consume.cod_grupo = estadis.cod_grupo AND
    consume.cod_Tipo = estadis.cod_tipo AND
    consume.cod_sec = estadis.cod_sec THEN
  
     LET estadis.consumo = consume.consumo
     LET sale = "S"
     LET idx_b = 1
     EXIT WHILE
 END IF
END WHILE

# Chequea que el codigo buscado no este como equivalente en el arreglo
 LET codigo_act = estadis.cod_n using "&","-",
                  estadis.cod_grupo using "&","-",
                  estadis.cod_tipo using "&&","-",
                  estadis.cod_sec using "&&&"

IF estadis.consumo IS NULL THEN
   LET estadis.consumo = 0
END IF
LET tiene = "N"

# Loop para busqueda del balance de la materia prima
     LET salir = "N"
     LET Idx_b = 1
     WHILE salir != "S"
      FETCH ABSOLUTE idx_b material_bal INTO balances.*
        IF status = notfound THEN
          LET idx_b = 1
          LET salir = "S"
          EXIT WHILE
        END IF

        LET idx_b = idx_b + 1
        IF balances.cod_n = estadis.cod_n AND
           balances.cod_grupo = estadis.cod_grupo AND
           balances.cod_tipo = estadis.cod_tipo AND
           balances.cod_sec  = estadis.cod_sec THEN
           
           IF balances.balance IS NULL THEN
              LET balances.balance = 0
           END IF

           LET estadis.existe = balances.balance
           LET salir = "S"
           LET idx_b = 1
           EXIT WHILE
        END IF
   END WHILE

# Busqueda del costo del material
LET salir = "N"
LET idx_1 = 1
WHILE salir != "S"
FETCH ABSOLUTE idx_1 busca3 INTO costo.*
IF status = notfound THEN
   LET idx_1 = 1
   LET salir = "S"
   EXIT WHILE
END IF
      LET idx_1 = idx_1 + 1

      IF costo.cod_n = estadis.cod_n AND
         costo.cod_grupo = estadis.cod_grupo AND
         costo.cod_tipo = estadis.cod_tipo AND
         costo.cod_sec  = estadis.cod_sec THEN

         DISPLAY estadis.cod_grupo at 3,20
         DISPLAY estadis.cod_tipo  at 3,30
         DISPLAY estadis.cod_sec   at 3,40
         DISPLAY costo.costo_st at 3, 50
         LET estadis.costo = costo.costo_st
         LET idx_1 = 1
         LET salir = "S"
         EXIT WHILE
     END IF
END WHILE

# Se multiplica por -1 por que el movimiento 36 es negativo
     IF estadis.consumo IS NULL THEN
        LET estadis.consumo = 0
     END IF
     LET estadis.consumo = estadis.consumo * -1 

# Calculo para los dias de produccion 
     LET estadis.dias =  0
     IF estadis.consumo > 0 THEN
        LET estadis.dias = (estadis.existe / estadis.consumo) * dias1
     END IF

# Calculo para el exedente de la existencia apartir de los dias de exeso
# especificado

LET estadis.valor = 0
LET valor1 = 0
    LET estadis.valor = estadis.existe * estadis.costo

# Control para salir el material, si: tiene = "S" es equivalente
# tiene = "N" es principal

IF tiene = "N" THEN
      OUTPUT TO REPORT reporte_33(estadis.*,dias1,c_dias)
 #LET estadis.consumo = 0
 #LET estadis.existe = 0
END IF
   LET tiene = "N"
LET salir = "N"
END WHILE  

    FINISH REPORT reporte_33
    CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION

    REPORT reporte_33(x,dias2,c_dias)
       DEFINE x RECORD
          cod_n       LIKE intb00001.cod_n,
          cod_grupo   LIKE intb00001.cod_grupo,
          cod_tipo    LIKE intb00001.cod_tipo,
          cod_sec     LIKE intb00001.cod_sec,
          descrip_esp LIKE intb00001.descrip_esp,
          unidad_med  LIKE intb00001.unidad_med,
          dia_llegada LIKE intb00002.dia_llegada,
          categoria   LIKE intb00014.categoria,
          consumo     LIKE intb00006.cantidad_1,
          existe      LIKE intb00002.existencia,
          valor       DECIMAL(12,3),
          costo       DECIMAL(12,4),
          dias        INTEGER 
       END RECORD

    DEFINE c_dias SMALLINT
    DEFINE primera CHAR(1)
    DEFINE codigo_ant CHAR(10)
    DEFINE consume DECIMAL (12,2)
    DEFINE normal,dsiete,negra,doble,doble_off,borra,comp_off CHAR(2)
    DEFINE promedio DECIMAL(10,2)
    DEFINE doce,comp CHAR(3)
    DEFINE dias,no_r SMALLINT
    DEFINE dias2 SMALLINT
    DEFINE hora CHAR(5)
    DEFINE t_valor,existe_p,consumo_p DECIMAL(12,2)

    OUTPUT
      LEFT MARGIN 1

    FORMAT
      PAGE HEADER
           IF no_r is null THEN
              LET no_r = 0 
           END IF

        LET doble =  ASCII 14
        LET doble_off =  ASCII 20
        LET negra = ASCII 27, ASCII 69
        LET borra = ASCII 27, ASCII 70
        LET comp  =  ASCII 15 
        LET dsiete = ASCII 17
        LET comp_off = ASCII 18
        LET doce =  ASCII 030                
        LET normal = ASCII 27, ASCII 80
        LET hora = time
    
        LET lj = (126 - LENGTH(p_companias.nombre CLIPPED))/2
           PRINT COLUMN   1, comp 
           PRINT COLUMN   1, "inprrp033",
                 COLUMN  lj, p_companias.nombre CLIPPED,
                 COLUMN 119, "Pag. ", pageno USING "###"
           PRINT COLUMN  40, "    Sistema de Inventario de Materia Prima",
                 COLUMN 119, today using "dd/mm/yyyy"
           PRINT COLUMN  40, "       Dias De Inventarios Categorizados",  
                 COLUMN 122, hora

           SKIP 1 LINES
           PRINT COLUMN 1, "Desde ",datos_cons.fech_in using "dd/mm/yyyy",
                 COLUMN 20, "Hasta ", datos_cons.fech_fi using "dd/mm/yyyy"

           PRINT COLUMN 1, "--------------------------------------------------",
                           "--------------------------------------------------",
                           "--------------------------"
           PRINT COLUMN  50, "Consumo",
                 COLUMN  79, "Dias de" ,
                 COLUMN  92, "Dias de",
                 COLUMN 102, "Costo"

           PRINT COLUMN   1, "Codigo",
                 COLUMN  14, "Descripcion",
                 COLUMN  50, "Del Periodo",
                 COLUMN  68, "Existencia",
                 COLUMN  79, "Inventario",
                 COLUMN  92, "Llegada",
                 COLUMN 102, "Standard",
                 COLUMN 117, "Valor"

           PRINT COLUMN 1, "--------------------------------------------------",
                           "--------------------------------------------------",
                           "--------------------------"
          
   skip 1 line
         
      BEFORE GROUP OF x.categoria
         PRINT COLUMN  1, negra
         PRINT COLUMN  1,"Categoria ",x.categoria CLIPPED
         PRINT COLUMN  1, borra

      ON EVERY ROW
       IF t_valor is null THEN
          LET t_valor = 0
       END IF
         PRINT COLUMN   1, x.cod_n USING "&","-",x.cod_grupo USING "&","-",
                           x.cod_tipo USING "&&","-",x.cod_sec USING "&&&",
               COLUMN  14, x.descrip_esp,
               COLUMN  45, x.unidad_med,
               COLUMN  48, x.consumo USING "##,###,###.##",
               COLUMN  64, x.existe USING "---,---,---.##",
               COLUMN  83, x.dias USING "######"  ,
               COLUMN  96, x.dia_llegada using "###",
               COLUMN 100, x.costo using "##,###.####",
               COLUMN 112, x.existe * x.costo using "#,###,###.##"

           LET no_r = no_r + 1
           LET consumo_p = 0
           LET existe_p = 0
           LET t_valor = t_valor + (x.existe * x.costo)

     AFTER GROUP OF x.categoria
         PRINT COLUMN   1, negra
         PRINT COLUMN 110, "--------------"
         PRINT COLUMN   1, "Total Registro Por Categoria ",GROUP COUNT(*)
                           USING "<<<<",
               COLUMN 110, GROUP SUM(x.costo * x.existe) using "###,###,###.##"
         PRINT COLUMN   1, borra
         
     ON LAST ROW
         PRINT COLUMN   1, negra
         PRINT COLUMN   1, "Total Registro Impresos      ",COUNT(*)
                           USING "<<<<",
               COLUMN 110, SUM(x.costo*x.existe) using "###,###,###.##"
         PRINT COLUMN 111, "============="
         PRINT COLUMN   1, borra
     PRINT comp_off
END REPORT