database marmotech
screen size 24 by 80
{
Orden No. [f000       ]   Fecha: [f001      ] Tipo Producto [p                 ]
Cliente   [f0][f003] [b1                                      ]
Vendedor  [v1  ] [ve                            ]Orden Pedido[or1    ]  
Producto A Producir: [a][b][c  ][d   ][a1                             ]
Unidad de Medida   : [und ] Cantidad [f008          ]Fecha Termina[fe        ]
\g--------------------------------------------------------------------------\g
  COMPOSICION PRODUCTO...
\g--------------------------------------------------------------------------\g
  [e][f][g  ][h   ][a2                               ][f10 ][f9               ]
  [e][f][g  ][h   ][a2                               ][f10 ][f9               ]
  [e][f][g  ][h   ][a2                               ][f10 ][f9               ]
  [e][f][g  ][h   ][a2                               ][f10 ][f9               ]
  [e][f][g  ][h   ][a2                               ][f10 ][f9               ]
}
end
tables
prtb00007,prtb00008,vetb00004,iptb00002
attributes
v1 = prtb00007.sec_vend,comments = "Control-W Para Buscar Vendedores";
ve = formonly.nombre_vend,reverse,noentry;
f000 = prtb00007.num_oc;
f001 = prtb00007.fecha,required,format="dd/mm/yyyy";
or1  = prtb00007.orden_pedido,comments = "Introduzca Numero Orden Pedido";
f0   = prtb00007.tipo_cliente,required,comments = "Control-W Busca CLientes";
f003 = prtb00007.sec_cliente,required,comments = "Control-W Busca CLientes";
b1   = vetb00004.nombre,reverse;
a = prtb00007.cod_n,required,comments="Control-W Busca Producto";
b = prtb00007.cod_grupo,required,comments="Control-W Busca Producto";
c = prtb00007.cod_tipo,required,comments="Control-W Busca Producto";
d = prtb00007.cod_sec,required,comments="Control-W Busca Producto";
a1 = iptb00002.descrip_esp,reverse;
fe = prtb00007.fecha_termina,format = "dd/mm/yyyy";
und=formonly.unidad,reverse;
f008 = prtb00007.cantidad,required;

p = formonly.descrip,noentry,reverse;
e = formonly.cod_n_c,comments = "Digite Materia Prima";
f = formonly.cod_grupo_c,comments = "Digite Materia Prima";
g = formonly.cod_tipo_c,comments = "Digite Materia Prima";
h = formonly.cod_sec_c,comments = "Digite Materia Prima";
a2=formonly.descrip_esp_c,reverse,noentry;
f9= formonly.cantidad_c type decimal(12,3),comments= "Cantidad de Material A Usarse";
f10 = formonly.unidad_c type CHAR,reverse,noentry;
instructions
  screen record s_orden[5] 
  (cod_n_c,cod_grupo_c,cod_tipo_c,cod_sec_c,cantidad_c,descrip_esp_c,unidad_c)
end