# Property of Four Js*
# (c) Copyright Four Js 1995, 2019. All Rights Reserved.
# * Trademark of Four Js Development Tools Europe Ltd
#   in the United States and elsewhere
# 
# Four Js and its suppliers do not warrant or guarantee that these
# samples are accurate and suitable for your purposes. Their inclusion is
# purely for information purposes only.

ACTION DEFAULTS
   ACTION insert ( IMAGE="listins", TEXT="Ins" )
   ACTION append ( IMAGE="listadd", TEXT="App" )
   ACTION delete ( IMAGE="listdel", TEXT="Del" )
   ACTION foo ( IMAGE="smiley", TEXT="Foo" )
   ACTION bar ( IMAGE="ssmiley", TEXT="Bar" )
   ACTION close ( VALIDATE = NO, DEFAULTVIEW=YES )
end

TOPMENU
   GROUP global (TEXT="global")
     COMMAND foo (COMMENT="Bound with the name 'foo'")
     COMMAND bar (COMMENT="Bound with the name 'bar'")
   END
   GROUP input1 (TEXT="Input1")
     COMMAND input1.foo (TEXT="input1.foo", COMMENT="Bound with the name 'input1.foo'")
     COMMAND input1.bar (TEXT="input1.bar", COMMENT="Bound with the name 'input1.bar'")
   END
   GROUP sr1 (TEXT="List1")
     COMMAND sr1.insert (TEXT="sr1.insert", COMMENT="Bound with the name 'sr1.insert'")
     COMMAND sr1.append (TEXT="sr1.append", COMMENT="Bound with the name 'sr1.append'")
     COMMAND sr1.delete (TEXT="sr1.delete", COMMENT="Bound with the name 'sr1.delete'")
     COMMAND sr1.foo (TEXT="sr1.foo", COMMENT="Bound with the name 'sr1.foo'")
   END
   GROUP sr2 (TEXT="List2")
     COMMAND sr2.insert (TEXT="sr2.insert", COMMENT="Bound with the name 'sr2.insert'")
     COMMAND sr2.append (TEXT="sr2.append", COMMENT="Bound with the name 'sr2.append'")
     COMMAND sr2.delete (TEXT="sr2.delete", COMMENT="Bound with the name 'sr2.delete'")
     COMMAND sr2.foo (TEXT="sr2.foo", COMMENT="Bound with the name 'sr2.foo'")
   END
   GROUP bothlists (TEXT="Both Lists")
     COMMAND insert (TEXT="insert", COMMENT="Bound with the name 'insert'")
     COMMAND append (TEXT="append", COMMENT="Bound with the name 'append'")
     COMMAND delete (TEXT="delete", COMMENT="Bound with the name 'delete'")
     SEPARATOR
     COMMAND firstrow (COMMENT="Bound with the name 'firstrow'")
     COMMAND prevrow  (COMMENT="Bound with the name 'prevrow'")
     COMMAND nextrow  (COMMENT="Bound with the name 'nextrow'")
     COMMAND lastrow  (COMMENT="Bound with the name 'lastrow'")
   END
END

TOOLBAR
   ITEM insert (COMMENT="Bound with the name 'insert'")
   ITEM append (COMMENT="Bound with the name 'append'")
   ITEM delete (COMMENT="Bound with the name 'delete'")
   SEPARATOR
   ITEM firstrow (COMMENT="Bound with the name 'firstrow'")
   ITEM prevrow  (COMMENT="Bound with the name 'prevrow'")
   ITEM nextrow  (COMMENT="Bound with the name 'nextrow'")
   ITEM lastrow  (COMMENT="Bound with the name 'lastrow'")
   SEPARATOR
   ITEM foo (COMMENT="Bound with the name 'foo'")
   ITEM bar (COMMENT="Bound with the name 'bar'")
END

LAYOUT
VBOX
GRID
{
<g g1                                          >
 This group defines foo, bar actions
[f1                                            ]
[f2                                            ]
[f3                                            ]
                                 [in_foo|in_bar]
<                                              >
<g g2                                          >
 This group defines insert,append,delete,foo
 <t                                  >
 [c11     |c12                       ][t1_ins]
 [c11     |c12                       ][t1_app]
 [c11     |c12                       ][t1_del]
 [c11     |c12                       ][t1_foo]
 [c11     |c12                       ]
 <                                   >
<                                              >
<g g3                                          >
 This group defines insert,append,delete,foo
 <t                                  >
 [c21   |c22                         ][t2_ins]
 [c21   |c22                         ][t2_app]
 [c21   |c22                         ][t2_del]
 [c21   |c22                         ][t2_foo]
 [c21   |c22                         ]
 <                                   >
<                                              >
<g g4                                          >
 This group defines no actions
[f4                                            ]
<                                              >
}
END
END
END

ATTRIBUTES

GROUP g1: TEXT = "This is input1";
EDIT f1 = formonly.field1;
BUTTONEDIT f2 = formonly.field2, ACTION=foo,
                COMMENT="Bound with the name 'foo'";
BUTTONEDIT f3 = formonly.field3, ACTION=input1.bar,
                COMMENT="Bound with the name 'input1.bar'";
BUTTON in_bar: input1.bar, COMMENT="Bound with the name 'input1.bar'";
BUTTON in_foo: input1.foo, COMMENT="Bound with the name 'input1.foo'";

GROUP g2: TEXT = "This is list sr1";
EDIT c11 = formonly.col11;
EDIT c12 = formonly.col12;
BUTTON t1_ins: sr1.insert, image="listins";
BUTTON t1_app: sr1.append, image="listadd";
BUTTON t1_del: sr1.delete, image="listdel";
BUTTON t1_foo: sr1.foo, COMMENT="Bound with the name 'sr1.foo'";

GROUP g3: TEXT = "This is list sr2";
EDIT c21 = formonly.col21;
EDIT c22 = formonly.col22;
BUTTON t2_ins: sr2.insert, image="listins";
BUTTON t2_app: sr2.append, image="listadd";
BUTTON t2_del: sr2.delete, image="listdel";
BUTTON t2_foo: sr2.foo, COMMENT="Bound with the name 'sr2.foo'";

GROUP g4: TEXT = "This is input2";
EDIT f4 = formonly.field4;

END

INSTRUCTIONS
SCREEN RECORD sr1 (FORMONLY.col11, FORMONLY.col12);
SCREEN RECORD sr2 (FORMONLY.col21, FORMONLY.col22);
END