{
==============================================================================
    PROGRAMA    : LQPRRP002
    SISTEMA     : Sistema de Liquidacion Mercancia
    Objetivo    : Imprimir Mercancia en transito 
    COMENTARIOS : Este reporte tiene una busqueda de todas las referencias
                  Para las cuentas 1161 y 1161-01
    PROGRAMADOR : Juan Soto
    FECHA       : Mayo 19, 1994
==============================================================================
}
GLOBALS
  "lqprgb000.4gl"
 DEFINE mayor RECORD
   cod_aux      SMALLINT,
   cod_sec      SMALLINT,
   fecha        DATE,
   tipo         SMALLINT,
   ref          CHAR(14),
   cuenta_no    CHAR(8),
   num_doc      CHAR(12),
   detalle1     CHAR(30),
   detalle2     CHAR(30),
   debito       DECIMAL(12,2),
   credito      DECIMAL(12,2),
   clave        CHAR(6),
   descripcion  CHAR(30)
  END RECORD
  DEFINE fecha_inicial,fecha_final DATE
   
  FUNCTION lqprrp002()
  LET int_flag = FALSE

  OPTIONS
     FORM LINE 8
     
   OPEN FORM lqfmrp002 FROM "lqfmrp002"
   DISPLAY FORM lqfmrp002
   DISPLAY "lqprrp002" AT 4,3 
   DISPLAY "Mercancia En Transito" AT 6,28 

   LET tipo_papel = 1
   CALL msgrp000(tipo_papel)

   INPUT BY NAME fecha_inicial,fecha_final

    AFTER FIELD fecha_inicial
     IF fecha_inicial IS NULL THEN
        LET numero_msg = 16
        CALL msg(numero_msg)
        NEXT FIELD fecha_inicial
     END IF

     AFTER FIELD fecha_final
      IF fecha_final IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD fecha_final
       END IF

       IF fecha_inicial > fecha_final THEN
          LET numero_msg = 51
          CALL msg(numero_msg)
          NEXT FIELD fecha_inicial
        END IF
    END INPUT
    
    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
     END IF

     CONSTRUCT criterio ON a.num_doc
                         FROM num_doc

     IF int_flag THEN
        LET numero_msg = 2
        CALL msg(numero_msg)
        LET int_flag = FALSE
        RETURN
      END IF

# Buscando las referencias de las cuentas que tienen resumenes pendientes
# a una fecha determinada y movimientos a la fecha
      LET selec = "SELECT a.cod_aux,a.cod_sec,a.fecha,a.tipo,a.ref, ",
                  "a.cuenta_no[1,4],a.num_doc,a.detalle_1, ",
                  "a.detalle_2,a.debito,a.credito ",
                  "FROM cgtb00004 a ",
                  "WHERE a.status_t IS NULL AND ",
                  "      a.fecha <= ? AND a.cod_sec is not null AND ",
                  "      a.num_doc is not null and ",
                  "      a.cuenta_no[1,4] = '1161' and ",
                  criterio CLIPPED

       DISPLAY "<<<Buscando Informacion... Espere por Favor>>>" AT 19,14
       ATTRIBUTE(YELLOW)

       PREPARE comando FROM selec
       DECLARE busco CURSOR FOR comando
       OPEN busco USING fecha_final

       START REPORT transi TO PIPE "lp -dcentral"
#      START REPORT transi TO "rpg14"
       DISPLAY "<<<Reporte Generandose...  Espere por Favor>>>" AT 19,14
       ATTRIBUTE(YELLOW)
                  
       WHILE status != NOTFOUND
       FETCH busco INTO mayor.*
            IF STATUS = NOTFOUND THEN
               EXIT WHILE
            END IF

            IF int_flag THEN
                LET numero_msg = 2
                CALL msg(numero_msg)
                LET int_flag = FALSE
                FINISH REPORT transi
                EXIT WHILE
            END IF 

          LET mayor.clave = mayor.cod_aux using "&&",mayor.cod_sec using "&&&&"
          OUTPUT TO REPORT transi(mayor.*,fecha_inicial,fecha_final)
         END WHILE
         FINISH REPORT transi
         CLEAR SCREEN
      RUN "type C:\\archivo > %USPRINT%" END FUNCTION

REPORT transi(x,fecha1,fecha2)
   DEFINE x RECORD
     cod_aux      SMALLINT,
     cod_sec      SMALLINT,
     fecha        DATE,
     tipo         SMALLINT,
     ref          CHAR(14),
     cuenta_no    CHAR(8),
     num_doc      CHAR(12),
     detalle1     CHAR(30),
     detalle2     CHAR(30),
     debito       DECIMAL(12,2),
     credito      DECIMAL(12,2),
     clave        CHAR(6),
     descripcion  CHAR(30)
   END RECORD
   DEFINE fecha1,fecha2 DATE
   DEFINE total1,total2,total3,total4,total5,total6,debito,credito,balance
          DECIMAL(12,2)

   DEFINE nosale CHAR(1)
## DEFINICION DE LAS VARIABLES DE IMPRESION
    DEFINE doble_on CHAR(2)
    DEFINE doble_off CHAR(2)
    DEFINE negrillas_on CHAR(2)
    DEFINE negrillas_off CHAR(2)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(2)
    DEFINE normal CHAR(2)
    DEFINE hora CHAR(5)

    DEFINE nombre1,nombre2 CHAR(30)
    OUTPUT
## DEFINICION DE LOS MARGENES DE IMPRESION
     TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 3
    ORDER BY x.cuenta_no,x.clave,x.num_doc

    FORMAT
      PAGE HEADER
        LET doble_on =  ASCII 001
        LET doble_off = ASCII 002
        LET negrillas_on = ASCII 027, ASCII 098
        LET negrillas_off = ASCII 027, ASCII 099
        LET comp_on = ASCII 31
        LET comp_off = ASCII 30
        LET doce = ASCII 30
        LET normal = ASCII 029
        LET hora = time

## AQUI SE INDICA LA IMPRESION DE LOS ENCABEZADOS
           PRINT COLUMN   1, comp_on,
                 COLUMN   2, "lqprrp002",
                 COLUMN  14, negrillas_on,
                 COLUMN  15, doble_on,
                 COLUMN  17, "R A Y . O . V A C  D O M I N I C A N A,  S. A.",
                 COLUMN  65, negrillas_off,
                 COLUMN  66, doble_off,
                 COLUMN  83, "Pag. ",pageno using "###"
           PRINT COLUMN  43, "Sistema de Contabilidad General", 
                 COLUMN 124, today using "dd/mm/yy"
           PRINT COLUMN  32, "Mayor General Detallado Por Referencia",
                 COLUMN 127, hora
           PRINT COLUMN  47, "Del ",fecha1 USING "dd/mm/yy"," Al ",
                                    fecha2 USING "dd/mm/yy"

        PRINT COLUMN 1, "---------------------------------------------------",
                        "---------------------------------------------------",
                        "-----------------------------"

           PRINT COLUMN  1, "C O D.",
                 COLUMN 19, "D e s c r i p c i o n", 
                 COLUMN 104,"B a l a n c e"

        PRINT COLUMN 1, "----------------------------------------------------",
                        "----------------------------------------------------" ,
                        "-------------------------"

    skip 1 line
## AQUI SE INDICA LA IMPRESION DEL DETALLE
      BEFORE GROUP OF x.cuenta_no

         SELECT descripcion INTO x.descripcion FROM cgtb00001
         WHERE cuenta_no = x.cuenta_no

         PRINT COLUMN  1, negrillas_on
         PRINT COLUMN  2, "Cuenta No. ",x.cuenta_no CLIPPED,"  ",
                          x.descripcion CLIPPED
         PRINT COLUMN  1, negrillas_off
   
         LET total3 = 0
         LET total4 = 0
       BEFORE GROUP OF x.clave
         
         LET total5 = 0
         LET total6 = 0
         PRINT COLUMN  1, negrillas_on
         PRINT COLUMN  2, "Auxiliar   ",x.cod_aux using "&&","-",
                                        x.cod_sec using "&&&&";
        IF x.cod_aux = 1 THEN
          SELECT nom1_emp,apell1_emp INTO nombre1,nombre2 FROM adtb00003
          WHERE num_emp = x.cod_sec
          PRINT " ",nombre1 clipped," ",nombre2,negrillas_off

        ELSE
          LET nombre1 = null
          LET nombre2 = null
          SELECT nom_sp INTO nombre2 FROM cotb00001
          WHERE cod_sp  = x.cod_aux and
                cod_sp_sec = x.cod_sec
          PRINT " ",nombre2 #,negrillas_off

        END IF
        SKIP 1 LINE
        
           PRINT COLUMN  1, "Fecha",
                 COLUMN 11, "Refer.",
                 COLUMN 24, "Documento",   
                 COLUMN 38, "Detalle",
                 COLUMN 80, "DR",
                 COLUMN 95, "CR",
                 COLUMN 110,"Balance"
          PRINT COLUMN   1,negrillas_off

       BEFORE GROUP OF x.num_doc
         LET balance = 0

         SELECT SUM(b.debito - b.credito) INTO balance FROM cgtb00004 b
         WHERE b.cuenta_no[1,4] = x.cuenta_no AND b.num_doc = x.num_doc
         and b.cod_sec = x.cod_sec and b.cod_aux = x.cod_aux
         AND   b.status_t IS NULL AND b.fecha <= fecha1

         LET nosale = "S"
         IF balance = 0 THEN
            LET nosale = "N"
         END IF
         IF balance IS NULL THEN
            LET balance = 0
         END IF
        IF balance >= 0 THEN
         LET total1 = balance 
         LET total2 = 0
        ELSE
         LET total2 = balance 
         LET total1 = 0
        END IF
         IF nosale = "S" THEN
         PRINT COLUMN   1,fecha1-1 USING "dd/mm/yy",
               COLUMN  11,x.num_doc,
               COLUMN  27,"Resumen"," ","Balance al Cierre", 
               COLUMN  68,total1  USING "###,###,###.##",
               COLUMN  90,total2  USING "###,###,###.##",
               COLUMN 110,balance USING "(((,(((,(((.##)"
          END IF

      ON EVERY ROW
        IF x.fecha >= fecha1 and
           x.fecha <= fecha2 THEN
         IF x.debito IS NULL THEN
            LET x.debito = 0
         END IF
         IF x.credito IS NULL THEN
            LET x.credito = 0
         END IF

         LET total1 = total1 + x.debito
         LET total2 = total2 + x.credito
         LET balance = balance + (x.debito - x.credito)

         PRINT COLUMN   1,x.fecha USING "dd/mm/yy",
               COLUMN  11, x.num_doc,
               COLUMN  24,x.ref CLIPPED,
               COLUMN  40,x.detalle1 CLIPPED," ",
               COLUMN  72,x.debito USING "###,###,###.##",
               COLUMN  90,x.credito USING "###,###,###.##",
               COLUMN 110,balance USING "(((,(((,(((.##)"

        IF x.detalle2 is not null THEN
           PRINT  COLUMN 27, x.detalle2 CLIPPED
        END IF
        END IF

        AFTER GROUP OF x.num_doc
          PRINT COLUMN   1,negrillas_on
         IF balance != 0 THEN
          PRINT COLUMN  72,"--------------",
                COLUMN  90,"--------------",
                COLUMN 110,"--------------"
          PRINT COLUMN   1, "Total Referencia   -->",
                COLUMN  68,total1 USING "###,###,###.##", 
                COLUMN  90,total2 USING "###,###,###.##",
                COLUMN 110,balance USING "(((,(((,(((.##)"
          PRINT COLUMN   1,negrillas_off

           LET total3 = total3 + total1
           LET total4 = total4 + total2
           LET total5 = total5 + total1   
           LET total6 = total6 + total2   
         END IF
       
        AFTER GROUP OF x.clave
          PRINT COLUMN   1,negrillas_on
          PRINT COLUMN  72,"--------------",
                COLUMN  90,"--------------",
                COLUMN 110,"--------------"
          PRINT COLUMN   1, "Total Auxiliar     -->",
                COLUMN  68,total5 USING "###,###,###.##", 
                COLUMN  90,total6 USING "###,###,###.##",
                COLUMN 110,total5+total6 USING "(((,(((,(((.##)"
          PRINT COLUMN   1,negrillas_off

          AFTER GROUP OF x.cuenta_no
          PRINT COLUMN   1,negrillas_on 
          PRINT COLUMN  68,"--------------",
                COLUMN  90,"--------------",
                COLUMN 110,"--------------"
          PRINT COLUMN   1, "Total cuenta -->",
                COLUMN  68,total3 USING "###,###,###.##", 
                COLUMN  90,total4 USING "###,###,###.##",
                COLUMN 110,total3 + total4 USING "(((,(((,(((.##)"
          PRINT COLUMN  68,"==============",
                COLUMN  90,"==============",
                COLUMN 110,"=============="
          
          PRINT COLUMN   1,negrillas_off

         ON LAST ROW
            PRINT COLUMN 1,comp_off

   END REPORT