{
==============================================================================
    PROGRAMA    : CGPRRP026
    SISTEMA     : Sistema de Contabilidad General
    Objetivo    : Validacion de Cronologico de Entrega de Cheques
    PROGRAMADOR : Tadeo A. Ferreras
    FECHA       : Febrero 08, 1996
==============================================================================
}
GLOBALS
  "cgprgb000.4gl"
 DEFINE datos_26 RECORD
      cod_cro       CHAR(8),
      beneficiario  CHAR(60)
  END RECORD,
      decide CHAR(1)
   
  FUNCTION cgprrp026()
  LET int_flag = FALSE

  OPTIONS
     FORM LINE 8
     
   OPEN FORM cgfmrp026 FROM "cgfmrp026"
   DISPLAY FORM cgfmrp026
   DISPLAY "cgprrp026" AT 4,3 
   DISPLAY "Validacion de Cronologico de Entrega de Cheques" AT 6,17 

   LET tipo_papel = 1
   CALL msgrp000(tipo_papel)

   INPUT BY NAME decide
    AFTER FIELD decide
      IF decide IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD decide
      END IF

   END INPUT 

   IF int_flag THEN
      LET numero_msg = 2
      CALL msg(numero_msg)
      LET int_flag = FALSE
      RETURN
   END IF

   CONSTRUCT criterio ON a.cod_cro,a.beneficario FROM cod_cro,beneficiario

   IF int_flag THEN
      LET numero_msg = 2
      CALL msg(numero_msg)
      LET int_flag = FALSE
      RETURN
   END IF

   IF decide = "N" THEN
      LET selec = 
      "SELECT a.cod_cro,a.beneficiario FROM cgtb00031 a ",
      "WHERE a.status_t IS NULL AND ",criterio CLIPPED, "Order by 1,2 "

      DISPLAY "<<<Buscando Informacion... Espere por Favor>>>" AT 19,14
      ATTRIBUTE(blue)

   ELSE
      LET selec = 
      "SELECT a.cod_cro,a.beneficiario FROM cgtb00031 a ",
      "WHERE a.status_t IS NULL AND ",criterio CLIPPED, "Order by 2,1 "

      DISPLAY "<<<Buscando Informacion... Espere por Favor>>>" AT 19,14
      ATTRIBUTE(blue)
   END IF

   PREPARE comando FROM selec
   DECLARE busco CURSOR FOR comando
   OPEN busco 

   START REPORT reporte_26 TO "C:\\archivo"
   DISPLAY "<<<Reporte Generandose...  Espere por Favor>>>" AT 19,14
   ATTRIBUTE(blue)
                  
   WHILE status != NOTFOUND
       FETCH busco INTO datos_26.*
            IF STATUS = NOTFOUND THEN
               EXIT WHILE
            END IF

            IF int_flag THEN
                LET numero_msg = 2
                CALL msg(numero_msg)
                LET int_flag = FALSE
                RETURN
            END IF 
            OUTPUT TO REPORT reporte_26(datos_26.*)
   END WHILE
   FINISH REPORT reporte_26
   CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION

REPORT reporte_26(x)
   DEFINE x RECORD
     cod_cro       CHAR(8),
     beneficiario  CHAR(60)
   END RECORD

## DEFINICION DE LAS VARIABLES DE IMPRESION
    DEFINE negrillas_on,negrillas_off,normal CHAR(2)
    DEFINE hora CHAR(5)

    OUTPUT
## DEFINICION DE LOS MARGENES DE IMPRESION
     TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 3

    FORMAT
      PAGE HEADER
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET normal = ASCII 27, ASCII 80
        LET hora = time

## AQUI SE INDICA LA IMPRESION DE LOS ENCABEZADOS
        PRINT COLUMN  1, normal,negrillas_on
        PRINT COLUMN  1, "cgprrp026",
              COLUMN 17, "M A R M O T E C H, S. A.",
              COLUMN 73, "Pag. ",pageno using "###"
        PRINT COLUMN 17, "              Entrega de Cheques ", 
              COLUMN 73, today using "dd/mm/yy"
        PRINT COLUMN 17, "  Validacion de Cronologico de Beneficiarios",
              COLUMN 76, hora
        SKIP 1 LINE
        PRINT COLUMN 1, "--------------------------------------------------",
                        "------------------------------"

        PRINT COLUMN   1, "Codigo",
              COLUMN  11, "Beneficacio"

        PRINT COLUMN 1, "--------------------------------------------------",
                        "------------------------------"
         PRINT negrillas_off

## AQUI SE INDICA LA IMPRESION DEL DETALLE

      ON EVERY ROW
         PRINT COLUMN  1, x.cod_cro CLIPPED,
               COLUMN 11, x.beneficiario CLIPPED
   END REPORT