{
-------------------------------------------------------------------------------
PROGRAMA             :  CCPRRP023
OBJETIVO             :  Deducciones por Ventas  
PROGRAMADOR          :  Tadeo A. Ferreras        
FECHA REALIZACION    :  Noviembre 26, 1993   
-------------------------------------------------------------------------------
}
GLOBALS "ccprgb000.4gl"
# Variables para controlar que el nombre del articulo y del deduciones 
# se busque una sola vez

    DEFINE fecha1,fecha2 DATE
    DEFINE codigo,codigo_ant CHAR(7)
    DEFINE vende,vende_ant CHAR(7)
    DEFINE mes1 ARRAY[12] OF CHAR(10)
    DEFINE selec28 CHAR(1000)
    DEFINE p_ano CHAR(4)

# Variables para la captura de la informacion del reporte

    DEFINE mes SMALLINT
    DEFINE cod_cia SMALLINT
    DEFINE salir,ventas CHAR(1)

FUNCTION ccprrp023()
# Variables que toman los valores del query y a la vez estas mismas variables
# Asignan estos valores a otra que se imprimira posteriormente
    DEFINE deduc RECORD
          sec_vend       SMALLINT,
          fecha_factura  DATE,    
          factura        INTEGER,  
          cod_n          SMALLINT,
          cod_grupo      SMALLINT,
          cod_tipo       SMALLINT,
          cod_sec        SMALLINT,
          descrip_esp    CHAR(30),
          cantidad       INTEGER,
          porc_venta     DECIMAL(10,4),
          precio         DECIMAL(10,2),
          vende          CHAR(6)
     END RECORD
# Atrapa el error de run-time

#   WHENEVER ERROR CONTINUE
# Especificaciones para el desplegue de errores y formulario.
# Reserva lineas para tales fines.

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21
# Desplegue del formulario de entrada de informacion

    OPEN FORM ccfmrp023 FROM "ccfmrp023"
    DISPLAY FORM ccfmrp023
#----------------------------------------------------------

    CALL pantalla()

    DISPLAY "ccprrp023" AT 4,3
    DISPLAY "Deducciones por Vendedor" AT 6,28 

## Tipo de papel necesari para imprimir el reporte
    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

# Entrada de datos para el reporte

   INPUT BY NAME cod_cia,p_ano,mes,ventas
    AFTER FIELD p_ano   
       IF p_ano   IS NULL THEN
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD p_ano   
       END IF
    AFTER FIELD cod_cia
       IF cod_cia IS NULL THEN
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD cod_cia
       END IF

    AFTER FIELD mes 
      IF mes IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD mes
      END IF

     SELECT a.fecha_inicio,a.fecha_corte INTO fecha1,fecha2
     FROM prdtable a WHERE a.ano = p_ano AND a.mes = mes

    AFTER FIELD ventas    
      IF ventas IS NULL THEN
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD ventas
      END IF
    
    END INPUT
   
      IF int_flag THEN
         LET numero_msg = 2
         CALL msg(numero_msg)
         LET int_flag = false
         RETURN
      END IF

# Buscando las informaciones del reporte

 IF ventas = "1" THEN
 LET selec28 =
  "SELECT a.sec_vend,c.fecha,c.num_doc,c.cod_n,c.cod_grupo,c.cod_tipo, ",
  "       c.cod_sec,b.descrip_esp,SUM(c.cantidad_2) ",
  "FROM intb00001 b,iptb00006 c,OUTER vetb00028 a ",
  "WHERE c.cod_n = b.cod_n AND c.cod_grupo = b.cod_grupo AND ",
  "      c.cod_tipo = b.cod_tipo AND c.cod_sec = b.cod_sec AND ",
  "      c.fecha between ? and ? AND c.status_t IS NULL AND ",
  "      c.cod_mov IN (12,13) AND c.cod_cia=? AND c.cod_sp=a.tipo_cliente AND ",
  "      c.cod_sp_sec  = a.sec_cliente AND c.cod_sp_sec  < 9000 ",
  " GROUP BY 1,2,3,4,5,6,7,8 " 
 ELSE
 LET selec28 =
  "SELECT a.sec_vend,c.fecha,c.num_doc,c.cod_n,c.cod_grupo,c.cod_tipo, ",
  "       c.cod_sec,b.descrip_esp,SUM(c.cantidad_2) ",
  "FROM iptb00006 c,intb00001 b,OUTER vetb00028 a ",
  "WHERE c.cod_n = b.cod_n AND c.cod_grupo = b.cod_n AND ",
  "      c.cod_tipo = b.cod_tipo AND c.cod_sec = b.cod_sec AND ",
  "      c.fecha between ? and ? AND c.status_t IS NULL AND ",
  "      c.cod_mov IN (12,13) ",
  "  AND c.cod_cia = ? AND c.cod_sp = a.tipo_cliente AND ",
  "      c.cod_sp_sec  = a.sec_cliente AND c.cod_sp_sec  >= 9000 ",
  " GROUP BY 1,2,3,4,5,6,7,8 "
 END IF

    DISPLAY "                                                     " AT 19,14
    DISPLAY "<< Buscando Informacion ... Espere Por Favor >>" AT 19,14
           ATTRIBUTE (REVERSE,BOLD)

      PREPARE b_vende FROM selec28
      DECLARE c_vende CURSOR FOR b_vende
      OPEN c_vende USING fecha1,fecha2,cod_cia

#---------------------------------------------------------------------------

      START REPORT deduccion TO "C:\\archivo" 
    DISPLAY "                                              " AT 19,14
    DISPLAY "<< Reporte Generandose ... Por Favor Espere >>" AT 19,14
            ATTRIBUTE (REVERSE)

# Loop para darle salida al Query hasta que la variable global status = 100

      LET codigo_ant = "  "
      LET salir = "N"
      WHILE salir != "S"         
      FETCH   c_vende INTO deduc.*
      IF status = notfound THEN
         LET salir = "N"
         EXIT WHILE
      END IF

      IF int_flag THEN
         LET int_flag = FALSE
         LET numero_msg = 2
         CALL msg(numero_msg)
         RETURN
       END IF

# Busco los datos detallados de la factura en la tabla de detalle de ventas
        LET deduc.precio = 0
        SELECT a.precio INTO deduc.precio FROM vetb00025 a
        WHERE a.cod_n = deduc.cod_n AND a.cod_grupo = deduc.cod_grupo AND
              a.cod_tipo = deduc.cod_tipo AND a.cod_sec = deduc.cod_sec AND
              a.ventas = ventas AND a.status_t IS NULL AND a.sec_cliente IS NULL

# Busco la descripcion del articulo
       LET codigo = deduc.cod_n using "&",
                    deduc.cod_grupo using "&",
                    deduc.cod_tipo using "&&",
                    deduc.cod_sec using "&&&"

#-------------------------------------------------------------------------------
# Se hace esta asignacion a otra variable para tener el codigo del deduc
# que esta en dos campos, en una sola variable para poder hacer ruptura de 
# control
       LET deduc.vende = deduc.sec_vend using "&&&&"

# Salida hacia la impresion del reporte, este llama la rutina que
# resuelve los reportes en 4GL

   LET deduc.porc_venta = 0
   SELECT MAX(a.porc_ventas) INTO deduc.porc_venta
   FROM vetb00011 a
   WHERE a.cod_n = deduc.cod_n and a.cod_grupo = deduc.cod_grupo and
         a.cod_tipo = deduc.cod_tipo and a.cod_sec  = deduc.cod_sec and
         a.sec_vend = deduc.sec_vend and a.status_t is null

        IF deduc.porc_venta IS NULL THEN
           LET deduc.porc_venta = 0
        END IF

       OUTPUT TO REPORT deduccion (deduc.*)
    END WHILE

# Aqui se le especifica al sistema operativo que el reporte ha terminado
# el sistema operativo hace el resto

   FINISH REPORT deduccion
#---------------------------------------------------------------------
   CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION
# Rutina de reporte 

REPORT deduccion(x)
# Variable que toma el valor de la funcion que llamo a esta rutina

    DEFINE x RECORD
          sec_vend       SMALLINT,
          fecha_factura  DATE,    
          factura        INTEGER,  
          cod_n          SMALLINT,
          cod_grupo      SMALLINT,
          cod_tipo       SMALLINT,
          cod_sec        SMALLINT,
          descrip_esp    CHAR(30),
          cantidad       INTEGER,
          porc_venta     DECIMAL(10,4),
          precio         DECIMAL(10,2),
          vende          CHAR(6)  
    END RECORD
# Esta variable toma el valor del nombre del mes para imprimirse

    DEFINE nombre_mes CHAR(10)
#------------------------------------------------------------------
# Estas variables son constantes en todos los reportes de RAYOVAC 
# para no estar definiendolas en cada momento.
# Estas variables son los caracteres ASCII para ser interpretados por
# el printer.

    DEFINE nombre_vend,apellido_vend  CHAR(30) 
    DEFINE doble_on CHAR(3)
    DEFINE doble_off CHAR(3)
    DEFINE negrillas_on CHAR(6)
    DEFINE negrillas_off CHAR(6)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(3) 
    DEFINE doce CHAR(3)
    DEFINE normal CHAR(2) 
#----------------------------------------------------------------------
# Esta variable es para asignarle la hora del dia e imprimir en HH:MM

    DEFINE hora CHAR(5)
#-----------------------------------------------------------------------
# Con esta variable se hace un calculo porcentual

    DEFINE porc DECIMAL(10,4)
#-----------------------------------------------------------------------
# Variables totales del reporte
    DEFINE t_valor,t_unidades,total_gen,total_vend,valor_pagar DECIMAL(12,2)
# Definicion de salida del reporte, margenes.

    OUTPUT
      TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 4
#------------------------------------------------------------------------

    ORDER BY x.vende,x.cod_n,x.cod_grupo,x.cod_tipo,x.cod_sec,x.factura

    FORMAT
      PAGE HEADER
# Asignaciones de los valores ASCII para la impresion

        LET doble_on =  ASCII 001
        LET doble_off = ASCII 002
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 69
        LET comp_on = ASCII 15 
        LET comp_off = ASCII 18
        LET doce = ASCII 27, ASCII 77
        LET normal = ASCII 029
        LET hora = time
# Funcion  que busca los meses del ano

        #CALL p_meses()
        LET nombre_mes = mes1[mes]
#--------------------------------------------------------------------------

        LET lj = (99 - LENGTH(p_companias.nombre CLIPPED))/2
        PRINT COLUMN 1, comp_on
        PRINT COLUMN 1, "ccprrp023",
              COLUMN lj, p_companias.nombre CLIPPED,
              COLUMN 92, "Pag. ",pageno using "###"
        PRINT COLUMN 27, "         Sistema de Cuentas Por Cobrar",
              COLUMN 90, today using "dd/mm/yyyy"
        PRINT COLUMN 33, "Relacion Deducciones por Vendedor",
              COLUMN 95, hora
        PRINT COLUMN 37, "Del ",fecha1 USING "dd/mm/yy",     
                         " Al ",fecha2 USING "dd/mm/yy"

        PRINT COLUMN 40, doble_on,nombre_mes,doble_off

        SKIP 1 LINES
        PRINT COLUMN 1, "--------------------------------------------------",
                        "--------------------------------------------------", 
                        "--------------------"
        PRINT COLUMN   2, "DOCTO.", 
              COLUMN  10, "FECHA",
              COLUMN  20, "PRODUCTO",
              COLUMN  66, "VALOR",
              COLUMN  75, "UNIDADES",    
              COLUMN  84, "COMISION",    
              COLUMN  94, "DEDUCCION"

              PRINT COLUMN 1, 
                    "--------------------------------------------------", 
                    "--------------------------------------------------", 
                    "--------------------"

      SKIP 1 LINE
      BEFORE GROUP OF x.vende
             LET total_vend = 0

# Impresion del nombre del deduc
       SELECT nom1_emp,apell1_emp INTO nombre_vend,apellido_vend
       FROM adtb00003 WHERE num_emp = x.sec_vend  

             PRINT COLUMN  1,doble_on,"VENDEDOR : ", 
                             x.sec_vend,"  ",nombre_vend clipped," ",
                             apellido_vend clipped, doble_off 

             SKIP 1 LINE
# Impresion detalle del reporte

      ON EVERY ROW

             IF cod_cia = "1" THEN
                LET valor_pagar = x.cantidad * x.porc_venta
             ELSE
                LET valor_pagar = (x.cantidad * x.precio) * x.porc_venta 
             END IF
             IF x.sec_vend = 144 THEN
                LET valor_pagar = (x.cantidad * x.precio) * x.porc_venta 
             END IF
                  
             IF total_gen is null THEN
                LET total_gen = 0
             END IF

# Esta es la acumulacion de lo que se le va ha pagar al deduc
             LET total_vend = valor_pagar + total_vend
             LET total_gen = total_gen + total_vend
#-----------------------------------------------------------------------------

             PRINT COLUMN 1, x.factura using "&&&&&&",
                   COLUMN 9, x.fecha_factura using "dd/mm/yy",
                   COLUMN 20, x.cod_n using "&","-",x.cod_grupo using "&","-",
                              x.cod_tipo using "&&","-",x.cod_sec using "&&&", 
                              " ",x.descrip_esp,
                   COLUMN 63, x.cantidad * x.precio using "##,###,###",
                   COLUMN 74, x.cantidad using "###,###",
                   COLUMN 84, x.porc_venta using "###.####",
                   COLUMN 93, valor_pagar using "###,###.##"


      AFTER GROUP OF x.vende
            PRINT COLUMN  63, "----------",
                  COLUMN  74, "----------",
                  COLUMN  93, "----------"

            PRINT COLUMN  50, "Total A Pagar: ",
                  COLUMN  63, GROUP SUM(x.cantidad*x.precio) using "##,###,###",
                  COLUMN  74, GROUP SUM(x.cantidad) using "###,###",
                  COLUMN  93, total_vend     using "###,###.##"
            SKIP 1 LINE

        AFTER GROUP OF x.factura
           SKIP 1 LINE
     ON LAST ROW
     PRINT COLUMN 50, "Total General: ",
                  COLUMN  63, SUM(x.cantidad*x.precio) using "##,###,###",
                  COLUMN  74, SUM(x.cantidad) using "###,###",
                  COLUMN  93, total_gen      using "###,###.##"
     LET total_gen = 0
     PRINT comp_off
     END REPORT