{
------------------------------------------------------------------------
 FORMULARIO        : ADFMMT017
 OBJETIVO          : Pantalla para introducir las informaciones de la
                     accion de personal. Es utilizada por: ADPRMT017
 PROGRAMADOR       : Ing. Betania Guerrero Perez
 FECHA REALIZACION : Junio 24, 1993  
------------------------------------------------------------------------
}
SCHEMA smarmotech  

TOOLBAR
  ITEM nuevo (TEXT="Nuevo", IMAGE="new", COMMENT="Adicionar Registos")
  ITEM buscar (TEXT="Buscar", IMAGE="find", COMMENT="Buscar Regustros")  SEPARATOR
  ITEM salir (TEXT="Salir", COMMENT = "Salir del Programa", IMAGE="quit") 
END

LAYOUT (TEXT="FORMULARIO MANTENIMIENTO ACCION DE PERSONAL", STYLE="basic")
  
GRID

{
<G                                                                                              >
 Tipo de Movimiento [f]-[f8] [g                                    ]
 Numero Documento   [nt    ]     Numero Solicitante [sn  ]
 Fecha              [f000      ] Fecha Efectiva     [f001      ] NIS  [nis                   ] 
 Ficha No.          [f002]-[f003]-[f4 ]-[f5 ] Cedula  [ce            ]Cuenta No:[ca            ]
 Nombre             [b                             ] Apellido [c                             ]
                    [dp                            ][n                            ] 
 Sueldo/Salario     [f013       ]Nomina[a][d        ]Estado Civil [s] [es         ]
 Sexo               [x][tx       ]   Tipo de Sangre [ts ] Monto Liquidacion[lq1              ]
 Observaciones      [f009                                                                    ]
 Solicitado         [f011]-[f012]-[f2]-[f3][h                                                ] 
 Autorizado         [f015]-[f016]-[f7]-[f1][j                                                ]
 Aprobado           [f019]-[f020]-[f0]-[f9][k                                                ]
 
 <G                                                                                             >
  Usuario Creador   [fk               ]  Usuario Modificador [fk2             ]
  Fecha Creacion    [fk1              ]  Fecha Modificacion  [fk3             ]
}
end
end
tables
adtb00020,adtb00009,adtb00012,
adtb00003,adtb00004,adtb00001
attributes
nis = formonly.pnis,comments = "CODIGO IDENTIFICACION SEGURIDAD SOCIAL";
ca = adtb00003.cuenta_no, comments="No. de Cuenta para pago automatico";
f = adtb00020.cod_mto,autonext,include = (1,2,3,4),
 comments ="1= EMPLEO 2=CAMBIO 3=NOVEDADES 4=TERMINACION o Presione Ctrl-W";
f8 = adtb00020.sec_mto,autonext,
 comments = "Digite la accion a ejecutarse";
g = adtb00009.desc_mto,noentry;
nt   = adtb00020.num_trx,noentry;
sn   = adtb00020.cod_sol, comments = "Digite el Numero del Solicitante";
dateedit f000 = adtb00020.fecha,format = "dd/mm/yyyy",
 comments = "Digite la fecha de elaboracion de la accion";
dateedit f001 = adtb00020.fech_efec,format = "dd/mm/yyyy",
 comments = "Digite la fecha de efectividad de la accion";
f002 = adtb00020.num_emp,autonext,
 comments = "Digite la ficha del empleado o Presione Ctrl-W para busqueda";
f003 = adtb00020.departamento,autonext,comments = 
     "Digite el departamento del empleado o Presione Ctrl-W para busqueda";
f4 = adtb00020.nivel_emp,autonext,comments = 
     "Digite el nivel del empleado o Presione Ctrl-W para busqueda";
f5 = adtb00020.cod_puesto,autonext,comments = 
     "Digite el puesto del empleado o Presione Ctrl-W para busqueda";
ce = formonly.cedula,picture="###-#######-#";
b = formonly.descrip1,noentry;
c = formonly.descrip2,noentry;
dp= formonly.nombre_dpto,noentry;
n = adtb00004.nom_puesto,noentry;
f013 = adtb00020.sueldo_ac,comments = "Digite el sueldo/salario del empleado"; 
a = adtb00020.nomina,upshift,autonext,include = ("S","Q","V"),
 comments = "Digite S = Semanal, Q = Quincenal, V = Vendedor";
d = formonly.descr,noentry;
s = adtb00003.estado_civil,autonext,upshift,include = ("S","C"),comments =
    "  S = Soltero        C = Casado  ";
es   = formonly.estado,noentry,color=blue;
ts   = adtb00012.tipo_sangre,upshift;
f009 = adtb00020.observacion,upshift;
f011 = adtb00020.num1_emp,autonext,comments = 
   "Digite la ficha del empleado solicitante o Presione Ctrl-W para busqueda";
f012 = adtb00020.departamento1,noentry;
f2 = adtb00020.nivel1_emp,noentry;
f3 = adtb00020.cod1_puesto,noentry;
h = formonly.descrip3,noentry;
f015 = adtb00020.num2_emp,autonext,comments = 
   "Digite el numero del empleado que autoriza o Presione Ctrl-W para busqueda";
f016 = adtb00020.departamento2,noentry;
f7 = adtb00020.nivel2_emp,noentry;
f1 = adtb00020.cod2_puesto,noentry;
j = formonly.descrip4,noentry;
f019 = adtb00020.num3_emp,autonext,comments = 
   "Digite el numero del empleado que aprueba o Presione Ctrl-W para busqueda";
f020 = adtb00020.departamento3,noentry;
f0 = adtb00020.nivel3_emp,noentry;
f9 = adtb00020.cod3_puesto,noentry;
k = formonly.descrip5,noentry;
x = formonly.sexo type char,include = ("M","F"),autonext,upshift,comments =
    "Digite   M   Para Sexo Masculino   y     F    Para el Femenino";
tx= formonly.tipo_sexo,noentry;
lq1 = formonly.sueldo_lq type decimal(12,2), default=0;
fk  = adtb00020.us_crea,noentry;
fk1 = adtb00020.fech_crea,noentry;
fk2 = adtb00020.us_mod,noentry;
fk3 = adtb00020.fech_mod,noentry;
end