{
-------------------------------------------------------------------------------
PROGRAMA             :  ACPRRP004
OBJETIVO             :  Validacion por tipo
PROGRAMADOR          :  Tadeo A. Ferreras 
FECHA REALIZACION    :  Sept. 28, 1993 
-------------------------------------------------------------------------------
}
GLOBALS "acprgb000.4gl"

    DEFINE act_fij4 RECORD
           codigo          SMALLINT,
           descripcion    CHAR(30),
           cuenta_no      CHAR(8),
           cta_depr       CHAR(8),
           cta_gasto      CHAR(8)
    END RECORD

MAIN
 DEFER INTERRUPT
 CALL ARG_VAL(1) RETURNING usuarios
 CALL ARG_VAL(2) RETURNING clave
 
 CONNECT to "smarmotech"  user  usuarios USING clave
 SELECT a.* INTO p_companias.* FROM companias a

 CALL acprrp004()
END MAIN

FUNCTION acprrp004()

#   WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

    OPEN FORM acfmrp004 FROM "acfmrp004"
    DISPLAY FORM acfmrp004
    CALL pantalla()
    DISPLAY "acprrp004" AT 4,3
    DISPLAY "Validacion Cuenta de Activos" AT 6,26

    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

# Busca la ultima cuenta_no y descripcion de cada cliente que no ha comprado en
# el rango de dias especificado 

CONSTRUCT criterio ON c.codigo,c.cuenta_no
                   FROM codigo,cuenta_no

 IF int_flag THEN
    LET numero_msg = 2
    CALL msg(numero_msg)
    LET int_flag = false
    RETURN
 END IF

 LET selec1 = 
    "SELECT c.codigo,c.descripcion,c.cuenta_no,c.cta_depr,c.cta_gasto ",
    "FROM actb00001 c ",
    "WHERE c.status_t IS NULL AND ", criterio CLIPPED

 DISPLAY "<< Buscando Informacion ... Espere Por Favor. >>" AT 19,14
 ATTRIBUTE (REVERSE,BOLD)

 PREPARE busca_act FROM selec1 
 DECLARE activos1 SCROLL CURSOR FOR busca_act     
 OPEN activos1 

 CALL seleccionarsalida() RETURNING r_output
 CALL configureoutput(r_output) RETURNING HANDLER
 
 START REPORT validacion TO XML HANDLER HANDLER
 
 DISPLAY "                                                " AT 19,14
 DISPLAY "<< Reporte Generandose ...  Por Favor Espere. >>"
           AT 19,14 ATTRIBUTE (REVERSE) 

  WHILE STATUS != NOTFOUND
    FETCH activos1 INTO act_fij4.*
    IF STATUS = NOTFOUND THEN
       EXIT WHILE
    END IF

    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = false
       RETURN
    END IF

    OUTPUT TO REPORT validacion(act_fij4.*)  
  END WHILE   
  FINISH REPORT validacion 
END FUNCTION

REPORT validacion(x)
   DEFINE x RECORD
       codigo          SMALLINT,
       descripcion    CHAR(30),
       cuenta_no      CHAR(8),
       cta_depr       CHAR(8), 
       cta_gasto      CHAR(8)
   END RECORD

   DEFINE hora CHAR(5)

   OUTPUT
       TOP MARGIN 0
       LEFT MARGIN 0
       BOTTOM MARGIN 2
       PAGE LENGTH 100
       
   ORDER BY x.cuenta_no,x.codigo

   FORMAT
      PAGE HEADER
        LET hora = time
        LET l = (81 - LENGTH(p_compania.nombre CLIPPED))/2
           PRINT COLUMN   1, "acprrp004",
                 COLUMN  l, p_companias.nombre CLIPPED,
                 COLUMN  76, "Pag. ",pageno USING "###"
        LET l = (81 - LENGTH("Sistema de Activos Fijos"))/2
           PRINT COLUMN  l, "Sistema de Activos Fijos",
                 COLUMN  76, today using "dd/mm/yyyy"
        LET l = (81 - LENGTH("Validacion de las Cuentas de Activos"))/2
           PRINT COLUMN  l, "Validacion de las Cuentas de Activos",
                 COLUMN  79, hora

          PRINT COLUMN 1, "--------------------------------------------------",
                          "---------------------------------"
                         
          PRINT COLUMN   50, "Cuenta",
                 COLUMN  61, "Cuenta",
                 COLUMN  73, "Cuenta"

           PRINT COLUMN   1, "Activo",
                 COLUMN  50, "Activos",
                 COLUMN  61, "Deprec.",
                 COLUMN  73, "Gastos" 

          PRINT COLUMN 1, "--------------------------------------------------",
                          "---------------------------------"
#                         , negrillas_off

       SKIP 1 LINE
      ON EVERY ROW
         PRINT COLUMN   1,x.codigo USING "&&&&&&"," ",x.descripcion CLIPPED,
               COLUMN 50,x.cuenta_no CLIPPED,
               COLUMN 61,x.cta_depr CLIPPED,
               COLUMN 73,x.cta_gasto CLIPPED
    ON LAST ROW
      PRINT COLUMN 1, normal
END REPORT