{
-------------------------------------------------------------------------------
PROGRAMA             :  CPPRRP009
OBJETIVO             :  Partidas Pendientes - Cuentas Detalladas     
PROGRAMADOR          :  Tadeo A. Ferreras           
FECHA REALIZACION    :  Julio 28, 1993 
-------------------------------------------------------------------------------
}
GLOBALS "cpprgb000.4gl"

  DEFINE prima DECIMAL(10,2) ### Varible que equivale a la prima de otra moneda
  DEFINE mov CHAR(1)
  DEFINE idx_1, idx_2, idx_3 SMALLINT ## Variables usadas para formar arreglos 
  DEFINE fecha_final DATE ## Varible usada para busqueda por fecha de corte
  DEFINE salir, salir1, salir3, tipo_venta CHAR(1) ## Bandera para control loop
  DEFINE selec5, selec6 CHAR(1500) ## Variables para almacenar busquedas
  DEFINE cod_sup SMALLINT

 ####### Variables para desplegar resultados por pantalla ante de la impresion

    DEFINE tot_gen1 RECORD 
       totald     DECIMAL(10,2),
       totalc     DECIMAL(10,2),
       totalg     DECIMAL(10,2)
   END RECORD

##### Registro que almacena la infoprmacion a imprimir ####

    DEFINE movtos1 RECORD
           cod_sp         SMALLINT,
           cod_sp_sec     SMALLINT,
           aplica_a       CHAR(10),
           valor          DECIMAL(12,2)
    END RECORD

FUNCTION cpprrp009()

#   WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

 ####### Abriendo y desplegando formulario de captura de datos

    OPEN FORM cpfmrp009 FROM "cpfmrp008"
    DISPLAY FORM cpfmrp009
    CALL pantalla()
    DISPLAY "cpprrp009" AT 4,3
    DISPLAY "Partida Pendiente de Cuenta Detallada" AT 6,20

    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

 ##### Creando el criterio de busqueda

 ##### Aceptando la fecha de corte para busqueda de informacion

  INPUT BY NAME fecha_final,prima,cod_sup  

        AFTER FIELD cod_sup      
              IF cod_sup      is null THEN  
                 LET numero_msg = 16
                 CALL msg(numero_msg)
                 NEXT FIELD cod_sup      
              END IF
    
        BEFORE FIELD fecha_final
               LET fecha_final = today

        AFTER FIELD fecha_final 
              IF fecha_final is null THEN  
                 LET numero_msg = 16
                 CALL msg(numero_msg)
                 NEXT FIELD fecha_final 
              END IF
    
        END INPUT 

###### Creando facilidad para cancelar operacion mediante la tecla DELETE
###### o SUPR

              IF int_flag THEN
                 LET numero_msg = 2
                 CALL msg(numero_msg)
                 LET int_flag = false
                 RETURN
              END IF

  CONSTRUCT criterio ON a.cod_sp_sec FROM cod_sp_sec
# Busca los documentos que esten en el rango de fechas especificado  

LET selec5 = 
 "SELECT a.cod_sp,a.cod_sp_sec,a.aplica_a,sum(a.valor) ",
 "FROM cptb00001 a WHERE a.status_t IS NULL AND a.fecha_orig <= ? AND ",
 "                       a.aplica_a IS NOT NULL AND a.cod_sp = ? AND ",
 criterio CLIPPED," GROUP BY 1,2,3 HAVING SUM(a.valor) <> 0 "

   DISPLAY "<< Buscando Informacion ... Espere Por Favor. >>" AT 19,14
            ATTRIBUTE (REVERSE,BOLD)

    DISPLAY "<<    Buscando los Movimientos del Rango    >>" AT 20,14
            ATTRIBUTE (REVERSE,BOLD)

    PREPARE movi FROM selec5 
    DECLARE movtos1_cli CURSOR FOR movi 
    OPEN movtos1_cli USING fecha_final,cod_sup

 LET selec6 =
 "SELECT UNIQUE a.cod_sp,a.cod_sp_sec,a.num_doc,a.valor ",
 "FROM cptb00001 a WHERE a.status_t IS NULL AND a.fecha_orig <= ? AND ",
 "                       a.aplica_a IS NULL AND ",
 "                       a.cod_sp = ? AND ",criterio CLIPPED

    DISPLAY "                                                " AT 20,14

   DISPLAY "<< Buscando Informacion ... Espere Por Favor. >>" AT 19,14
            ATTRIBUTE (REVERSE,BOLD)

    PREPARE comando FROM selec6 
    DECLARE movtos2_cli CURSOR FOR comando
    OPEN movtos2_cli USING fecha_final,cod_sup

   ###### Envia la informacion a un archivo

   START REPORT report09 TO "C:\\archivo"
   DISPLAY "                                                " AT 19,14
   DISPLAY "<< Reporte Generandose ...  Por Favor Espere. >>"
           AT 19,14 ATTRIBUTE (REVERSE) 


 ###### Comienza el loop para enviar informacion al reporte

WHILE STATUS != NOTFOUND
     FETCH movtos1_cli INTO movtos1.* 

         IF status = NOTFOUND THEN
            EXIT WHILE
         END IF

         IF int_flag THEN
            LET numero_msg = 2
            CALL msg(numero_msg)
            LET int_flag = FALSE
            RETURN 
         END IF

         IF prima IS NULL THEN
            LET prima = 1
         END IF
   
            LET movtos1.valor = movtos1.valor * prima

     IF movtos1.aplica_a IS NOT NULL OR movtos1.aplica_a != " " THEN
         OUTPUT TO REPORT report09(movtos1.*,fecha_final)  
     END IF
   END WHILE

   LET salir1 = "N"
   WHILE salir1 != "S"    
     FETCH movtos2_cli INTO movtos1.* 

         IF status = NOTFOUND THEN
            LET salir1 = "S"
            EXIT WHILE
         END IF

         IF int_flag THEN
            LET numero_msg = 2
            CALL msg(numero_msg)
            LET int_flag = FALSE
            RETURN 
         END IF

      SELECT SUM(a.valor*-1) INTO valor1 FROM cptb00001 a
      WHERE a.cod_sp = movtos1.cod_sp AND a.cod_sp_sec = movtos1.cod_sp_sec AND 
            a.num_doc = movtos1.aplica_a AND a.status_t IS NULL AND
            a.fecha_orig <= fecha_final AND a.aplica_a IS NOT NULL

         IF valor1 IS NULL THEN
            LET valor1 = 0
         END IF

         LET movtos1.valor = movtos1.valor + valor1	
         IF prima IS NULL THEN
            LET prima = 1
         END IF
            LET movtos1.valor = movtos1.valor * prima
         
   IF movtos1.valor <> 0 THEN
         OUTPUT TO REPORT report09(movtos1.*,fecha_final)  
   END IF
   END WHILE

      FINISH REPORT report09 
   CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION

####### Funcion para dar salida a la informacion

    REPORT report09(x,fecha1)
    DEFINE x RECORD
           cod_sp   SMALLINT,
           cod_sp_sec    SMALLINT,
           aplica_a       LIKE cptb00001.aplica_a,
           valor          DECIMAL(12,2)
    END RECORD

    DEFINE j RECORD
          num_doc   CHAR(10),
          fecha     DATE,
          tipo      CHAR(2),
          valor     DECIMAL(12,2)
    END RECORD
    DEFINE fecha1,fecha2 DATE,
           p_nombre         CHAR(45),
           p_limite_credito DECIMAL(10,2)
    DEFINE dias SMALLINT ## Variable que almacena la diferencia de dias
    DEFINE p_calle,p_descrip CHAR(30)
    DEFINE p_casa,p_zona,p_numero CHAR(10),
           balance        DECIMAL(12,2)
    DEFINE doble_on CHAR(2)
    DEFINE doble_off CHAR(2)
    DEFINE negrillas_on CHAR(2)
    DEFINE negrillas_off CHAR(2)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(2)
    DEFINE normal CHAR(2) 
    DEFINE hora CHAR(5)
    DEFINE tipo CHAR(2) 
    DEFINE imp_cli CHAR(1)
    DEFINE credito, debito, tcredito, tdebito,  tbalance,
           limite, b_balance, v1_30, v31_45, v46_60, vm_60,p_valor DECIMAL(12,2) 
    OUTPUT
       TOP MARGIN 0
       LEFT MARGIN 0
       BOTTOM MARGIN 2

   #### Proceso para sortear la informacion

    ORDER BY x.cod_sp,x.cod_sp_sec,x.aplica_a 

    ###### Diseno de la salida de la informacion

    FORMAT
      PAGE HEADER

        LET doble_on =  ASCII 14
        LET doble_off = ASCII 20
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET comp_on = ASCII 15
        LET comp_off = ASCII 18
        LET doce = ASCII 27, ASCII 77
        LET normal = ASCII 27, ASCII 80

        LET hora = time
        LET lj = (110 - LENGTH(p_companias.nombre CLIPPED))/2

           PRINT COLUMN   1, comp_on    
           PRINT COLUMN   1, "cpprrp009",
                 COLUMN  lj, p_companias.nombre CLIPPED,
                 COLUMN 103, "Pag. ",pageno using "###"
           PRINT COLUMN  31, "         Sistema de Cuentas por Pagar",
                 COLUMN 103, today using "dd/mm/yy"
           PRINT COLUMN  31, "    Partida Pendiente de Cuenta Detallada",
                 COLUMN 106, hora
           PRINT COLUMN 47, " Al ", fecha1 using "dd/mm/yy"

         IF x.cod_sp < 23 AND prima = 1 THEN
           PRINT COLUMN 53, "US$"
         ELSE
           PRINT COLUMN 53, "RD$"
         END IF

   ##### Si el cliente es local el valor de la prima de la moneda es nulo

     SKIP 1 LINE
    BEFORE GROUP OF x.cod_sp_sec

             LET v1_30 = 0
             LET v31_45 = 0
             LET v46_60 = 0
             LET vm_60 = 0

             IF tdebito IS NULL THEN
                LET tdebito = 0
             END IF

             IF tcredito IS NULL THEN
                LET tcredito = 0
             END IF

             IF tbalance IS NULL THEN
                LET tbalance = 0
             END IF

#### Seleciona los datos generales de identificacion del cliente

 SELECT UNIQUE b.nom_sp INTO p_nombre
 FROM cotb00001 b 
 WHERE b.cod_sp = x.cod_sp and b.cod_sp_sec = x.cod_sp_sec 

             IF balance IS NULL THEN
                LET balance = 0
             END IF

             IF limite IS NULL THEN 
                LET limite = 0
             END IF
             IF prima > 1 THEN
             PRINT COLUMN 1,"Prima: ", prima using "###.##"
             END IF

             PRINT COLUMN 1, 
                   "--------------------------------------------------",
                   "--------------------------------------------------",
                   "-----------"
                   , negrillas_on 

             PRINT COLUMN   1, "Suplidor:", 
                   COLUMN  10, x.cod_sp using "&&","-",
                               x.cod_sp_sec using "&&&&", 
                   COLUMN  18, p_nombre  clipped 

             PRINT COLUMN 1, 
                   "--------------------------------------------------",
                   "--------------------------------------------------",
                   "-----------"
 
                   LET b_balance = balance

             PRINT COLUMN   4, "D O C U M E N T O" 

             PRINT COLUMN   1, "|----------------------|" 

             PRINT COLUMN   1, "Numero", 
                   COLUMN  11, "Tipo",   
                   COLUMN  17, "Fecha", 
                   COLUMN  63, "Pendiente ",
                   COLUMN  99, "B A L A N C E" 

             PRINT COLUMN 1, 
                   "--------------------------------------------------",
                   "--------------------------------------------------" ,
                   "-----------"

             LET debito = 0
             LET credito = 0

      ON EVERY ROW

         SELECT UNIQUE a.tipo_doc,MIN(a.fecha_orig) INTO tipo,fecha2
         FROM cptb00001 a WHERE a.num_doc = x.aplica_a AND 
              a.cod_sp = x.cod_sp AND a.cod_sp_sec = x.cod_sp_sec AND
              a.status_t IS NULL GROUP BY 1

    LET existe = "S"
    IF STATUS = NOTFOUND THEN
       LET existe = "N"
       LET tipo = NULL
    ELSE
       LET existe = "S"
    END IF 

   ###### Balanceando la informacion
         LET b_balance = b_balance + x.valor
         PRINT COLUMN   1, x.aplica_a; 
       IF existe = "S" THEN
             LET dias = fecha1 - fecha2
         PRINT COLUMN  12, tipo, 
               COLUMN  16, fecha2 using "dd/mm/yy"; 
       ELSE
             LET dias = 65
         PRINT COLUMN  12, "DCTO. APLICADO NO EXISTE";
       END IF
         PRINT COLUMN  59, x.valor  using "(((,(((,((&.&&)",
               COLUMN  97, b_balance using "(((,(((,((&.&&)" 
     
          LET p_valor = x.valor
          IF p_valor <> 0 THEN

####### Calculando los dias de vencimiento del documento

             IF dias < 31 THEN
                LET v1_30 = p_valor + v1_30
             END IF
             IF dias > 30 and dias < 46 THEN
                LET v31_45 = p_valor + v31_45
             END IF
             IF dias > 45 and dias < 61 THEN
                LET v46_60 = p_valor + v46_60
             END IF
             IF dias > 60 THEN
                LET vm_60 = vm_60 + p_valor
             END IF
           END IF

        AFTER GROUP OF x.aplica_a

        SKIP 1 LINE
         PRINT COLUMN  20, "Documento",
               COLUMN  35, "Fecha ",
               COLUMN  45, "Tipo",
               COLUMN  55, "Valor"
     
         DECLARE busco CURSOR FOR
         SELECT a.num_doc,a.fecha_orig,a.tipo_doc,a.valor FROM cptb00001 a
         WHERE a.aplica_a = x.aplica_a AND a.status_t IS NULL AND
               a.cod_sp   = x.cod_sp AND a.cod_sp_sec = x.cod_sp_sec

       FOREACH busco INTO j.*

         PRINT COLUMN  20, j.num_doc, 
               COLUMN  35, j.fecha USING "dd/mm/yy",
               COLUMN  47, j.tipo,
               COLUMN  50, x.valor  using "(((,(((,((&.&&)"
       END FOREACH
        SKIP 1 LINE

        AFTER GROUP OF x.cod_sp_sec
        PRINT COLUMN 1, "ANALISIS POR ANTIGUEDAD",negrillas_on,
              COLUMN 34, "1 a 30",
              COLUMN 50, "31 a 45",
              COLUMN 68, "46 a 60",
              COLUMN 85, "Mas de 60",negrillas_off

        PRINT COLUMN 1, "DE SU APRECIADA CUENTA: ",
              COLUMN 26, v1_30 using "(((,(((,((&.&&)",
              COLUMN 45, v31_45 using "(((,(((,((&.&&)",
              COLUMN 65, v46_60 using "(((,(((,((&.&&)",
              COLUMN 81, vm_60 using "(((,(((,((&.&&)"

  SKIP 1 LINE
  PRINT COLUMN 1, 
   "NOTA: FAVOR REVISAR ESTE ESTADO Y NOTIFICAR A NUESTRO DEPARTAMENTO "
  PRINT COLUMN 1, 
   "      DE CONTABILIDAD SOBRE CUALQUIER DISCREPANCIA O REPARO  A LA MAYOR "
  PRINT COLUMN 1, 
   "      BREVEDAD POSIBLE."
 {PRINT COLUMN 1, 
   "      APRECIAMOS SU RESPUESTA, POR TANTO, QUEDAREMOS AGRADECIDOS POR SU "
  PRINT COLUMN 1, 
   "      ATENCION, SIRVANSE USAR LA COPIA DE ESTE ESTADO PARA SU CONFIRMACION."
}
              LET  v1_30  =   0
              LET  v31_45  =  0
              LET  v46_60  =  0
              LET  vm_60  =   0
   SKIP TO TOP OF PAGE

 PAGE TRAILER
  SKIP 1 LINE
  PRINT COLUMN 1, negrillas_on,     
 "CK-Cheque  FT-Factura Local  FE-Factura Exterior  ",
 "ND-Nota Debito  NC-Nota Credito  ",
               negrillas_off
 END REPORT