{
-------------------------------------------------------------------------------
PROGRAMA             :  CCPRRP018
OBJETIVO             :  Listar los Estados De Cuentas de los clientes
                        (Partidas pendientes de cobros)
PROGRAMADOR          :  Tadeo A. Ferreras           
FECHA REALIZACION    :  Julio 28, 1993 
-------------------------------------------------------------------------------
}
GLOBALS "ccprgb000.4gl"

  DEFINE prima DECIMAL(10,2) ### Varible que equivale a la prima de otra moneda
  DEFINE mov CHAR(1)
  DEFINE idx_1, idx_2, idx_3 SMALLINT ## Variables usadas para formar arreglos 
  DEFINE fecha_final DATE ## Varible usada para busqueda por fecha de corte
  DEFINE salir, salir1, salir3, tipo_venta CHAR(1) ## Bandera para control loop
  DEFINE selec5, selec6 CHAR(1500) ## Variables para almacenar busquedas
  DEFINE valor_de DECIMAL(12,2)
  DEFINE dias2 INTEGER

 ####### Variables para desplegar resultados por pantalla ante de la impresion

    DEFINE tot_gen1 RECORD 
       totald     DECIMAL(10,2),
       totalc     DECIMAL(10,2),
       totalg     DECIMAL(10,2)
   END RECORD

##### Registro que almacena la infoprmacion a imprimir ####

    DEFINE movtos RECORD
           tipo_cliente   SMALLINT,
           sec_cliente    SMALLINT,
           aplica_a       LIKE cctb00001.aplica_a,
           valor          DECIMAL(12,2)
    END RECORD

FUNCTION ccprrp018()

#   WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

 ####### Abriendo y desplegando formulario de captura de datos

    OPEN FORM ccfmrp018 FROM "ccfmrp018"
    DISPLAY FORM ccfmrp018
    CALL pantalla()
    DISPLAY "ccprrp018" AT 4,3
    DISPLAY "Estado Cuentas Pendiente De Cobros" AT 6,21

    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

 ##### Creando el criterio de busqueda

  CONSTRUCT criterio ON a.tipo_cliente,a.sec_cliente FROM
                          tipo_cliente,  sec_cliente
 ##### Aceptando la fecha de corte para busqueda de informacion

  INPUT BY NAME prima,fecha_final,dias2  

        BEFORE FIELD fecha_final
               LET fecha_final = today

        AFTER FIELD fecha_final 
              IF fecha_final is null THEN  
                 LET numero_msg = 16
                 CALL msg(numero_msg)
                 NEXT FIELD fecha_final 
              END IF
    
        AFTER FIELD dias2 
              IF dias2 is null THEN  
                 LET numero_msg = 16
                 CALL msg(numero_msg)
                 NEXT FIELD dias2 
              END IF
    
        END INPUT 

###### Creando facilidad para cancelar operacion mediante la tecla DELETE
###### o SUPR

              IF int_flag THEN
                 LET numero_msg = 2
                 CALL msg(numero_msg)
                 LET int_flag = false
                 RETURN
              END IF

# Busca los documentos que esten en el rango de fechas especificado  

LET selec5 = 
 "SELECT a.tipo_cliente,a.sec_cliente,a.aplica_a,sum(a.valor+a.monto_desc) ",
 "FROM cctb00001 a,vetb00002 b ",
 "WHERE a.status_t IS NULL AND a.fecha_orig <= ? AND a.aplica_a=b.factura AND ",
 "      a.sec_cliente = b.sec_cliente AND a.tipo_doc not in ('PC') AND ",
 criterio CLIPPED," GROUP BY 1,2,3 HAVING SUM(a.valor+a.monto_desc) <> 0 "

    DISPLAY "<<    Buscando los Movimientos del Rango    >>" AT 20,14
            ATTRIBUTE (REVERSE,BOLD)

    PREPARE movi FROM selec5 
    DECLARE movtos_cli CURSOR FOR movi 
    OPEN movtos_cli USING fecha_final

LET selec4 = 
 "SELECT a.tipo_cliente,a.sec_cliente,a.num_doc,sum(a.valor+a.monto_desc) ",
 "FROM cctb00001 a ",
 "WHERE a.status_t IS NULL AND a.fecha_orig <= ? AND a.tipo_doc = 'DE' AND ",
 criterio CLIPPED,
 " GROUP BY 1,2,3 HAVING SUM(a.valor+a.monto_desc) <> 0 "

    DISPLAY "<<    Buscando los Movimientos del Rango    >>" AT 20,14
            ATTRIBUTE (REVERSE,BOLD)

    PREPARE movi1 FROM selec4 
    DECLARE movtos_cli1 CURSOR FOR movi1 
    OPEN movtos_cli1 USING fecha_final
    DISPLAY "                                                " AT 20,14

   ###### Envia la informacion a un archivo

   START REPORT report18 TO "C:\\archivo"
   DISPLAY "                                                " AT 19,14
   DISPLAY "<< Reporte Generandose ...  Por Favor Espere. >>"
           AT 19,14 ATTRIBUTE (REVERSE) 


 ###### Comienza el loop para enviar informacion al reporte

   LET salir = "N"
   WHILE salir  != "S" 
     FETCH movtos_cli INTO movtos.* 

         IF status = NOTFOUND THEN
            LET salir = "S"
            EXIT WHILE
         END IF

         IF int_flag THEN
            LET numero_msg = 2
            CALL msg(numero_msg)
            LET int_flag = FALSE
            RETURN 
         END IF

         IF prima IS NOT NULL THEN
            LET movtos.valor = movtos.valor * prima
         END IF
         
         OUTPUT TO REPORT report18(movtos.*)  
   END WHILE

   LET salir1 = "N"
   WHILE salir1 != "S" 
     FETCH movtos_cli1 INTO movtos.* 

         IF status = NOTFOUND THEN
            LET salir1 = "S"
            EXIT WHILE
         END IF

         IF int_flag THEN
            LET numero_msg = 2
            CALL msg(numero_msg)
            LET int_flag = FALSE
            RETURN 
         END IF

         IF prima IS NOT NULL THEN
            LET movtos.valor = movtos.valor * prima
         END IF
         IF movtos.valor > 0 THEN
            LET movtos.valor = movtos.valor * -1
         END IF
         IF movtos.valor <> 0 THEN
            OUTPUT TO REPORT report18(movtos.*)  
         END IF
   END WHILE
      FINISH REPORT report18 
   CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION

####### Funcion para dar salida a la informacion

    REPORT report18(x)
    DEFINE x RECORD
           tipo_cliente   SMALLINT,
           sec_cliente    SMALLINT,
           aplica_a       LIKE cctb00001.aplica_a,
           valor          DECIMAL(12,2)
    END RECORD

    DEFINE fecha1,fecha2 DATE,
           p_nombre         CHAR(30),
           p_limite_credito DECIMAL(10,2)
    DEFINE dias SMALLINT ## Variable que almacena la diferencia de dias
    DEFINE p_calle,p_descrip CHAR(30)
    DEFINE p_casa,p_zona,p_numero CHAR(10),
           balance        DECIMAL(12,2)
    DEFINE doble_on CHAR(2)
    DEFINE doble_off CHAR(2)
    DEFINE negrillas_on CHAR(6)
    DEFINE negrillas_off CHAR(6)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(2)
    DEFINE normal CHAR(2) 
    DEFINE normall CHAR(3) 
    DEFINE comprimido CHAR(3)
    DEFINE hora CHAR(5)
    DEFINE tipo CHAR(2) 
    DEFINE imp_cli CHAR(1)
    DEFINE credito, debito, tcredito, tdebito,  tbalance,
           limite, b_balance, v1_30, v31_45, v46_60, vm_60,p_valor DECIMAL(12,2) 
    OUTPUT
       TOP MARGIN 0
       LEFT MARGIN 0
       BOTTOM MARGIN 2
       ORDER BY x.sec_cliente,x.aplica_a

   #### Proceso para sortear la informacion

    FORMAT
      PAGE HEADER
        LET doble_on =  ASCII 14
        LET doble_off = ASCII 20
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 69
        LET comp_on = ASCII 15
        LET comp_off = ASCII 18
        LET comprimido = ASCII 031
        LET doce = ASCII 27, ASCII 77  
        LET normal = ASCII 27, ASCII 80
        LET normall = ASCII 030 
        LET hora = time

        LET lj = (110 - LENGTH(p_companias.nombre CLIPPED))/2
           PRINT COLUMN   1, comprimido 
           PRINT COLUMN   1, "ccprrp018",
                 COLUMN  lj, p_companias.nombre CLIPPED,
                 COLUMN 101, today using "dd/mm/yyyy"
           PRINT COLUMN  41,"Estado de Cuenta Al ",fecha_final USING "dd/mm/yy",
                 COLUMN 106, hora

         IF x.tipo_cliente = 20 THEN
           PRINT COLUMN 53, "US$"
         ELSE
          PRINT COLUMN 53, "RD$"
         END IF

   ##### Si el cliente es local el valor de la prima de la moneda es nulo
         IF x.tipo_cliente = 10 THEN
            LET prima = null
         END IF

     SKIP 1 LINE
    BEFORE GROUP OF x.sec_cliente

      LET idx = 0
             LET v1_30 = 0
             LET v31_45 = 0
             LET v46_60 = 0
             LET vm_60 = 0

             IF tdebito IS NULL THEN
                LET tdebito = 0
             END IF

             IF tcredito IS NULL THEN
                LET tcredito = 0
             END IF

             IF tbalance IS NULL THEN
                LET tbalance = 0
             END IF

#### Seleciona los datos generales de identificacion del cliente

 SELECT UNIQUE b.nombre,b.limite_credito,b.zona_postal,b.num_rnc,c.calle,
               c.casa_num
 INTO p_nombre,p_limite_credito,p_zona,p_numero,p_calle,p_casa
 FROM vetb00004 b ,vetb00005 c
 WHERE x.tipo_cliente = b.tipo_cliente and x.sec_cliente = b.sec_cliente and   
       b.tipo_cliente = c.tipo_cliente and b.sec_cliente = c.sec_cliente and
       b.status_t is null   

             IF balance IS NULL THEN
                LET balance = 0
             END IF

             LET b_balance = balance

             IF limite IS NULL THEN 
                LET limite = 0
             END IF

             LET debito = 0
             LET credito = 0

      ON EVERY ROW

         SELECT UNIQUE a.tipo_doc,MIN(a.fecha_ven) INTO tipo,fecha2
         FROM cctb00001 a 
         WHERE a.num_doc = x.aplica_a AND a.status_t IS NULL AND
               a.aplica_a = a.num_doc GROUP BY 1

   ###### Balanceando la informacion

####### Calculando los dias de vencimiento del documento

     IF (fecha_final - fecha2) > dias2 THEN
        LET dias = (fecha_final - fecha2) - dias2

         LET p_valor = x.valor
         IF p_valor <> 0 THEN
            LET Idx = idx + 1

          IF idx = 1 THEN
             IF prima is not null THEN
                PRINT COLUMN 1,"Prima: ", prima using "###.##"
             END IF

             PRINT COLUMN 1, 
                   "--------------------------------------------------",
                   "--------------------------------------------------",
                   "-----------"
                   , negrillas_on 

             PRINT COLUMN   1, "Cliente:", 
                   COLUMN  10, x.tipo_cliente using "&&","-",
                               x.sec_cliente using "&&&&", 
                   COLUMN  18, p_nombre  clipped 

             PRINT COLUMN 10, p_calle clipped," ",p_casa;
       IF p_numero IS NOT NULL THEN
             PRINT COLUMN 24, "RNC: ", p_numero;
       END IF
             PRINT COLUMN 80, " " 
      IF p_zona IS NOT NULL THEN
             PRINT COLUMN 22, "ZONA POSTAL: ",p_zona,negrillas_off
      END IF
                   
             PRINT COLUMN 1, 
                   "--------------------------------------------------",
                   "--------------------------------------------------",
                   "-----------"
 
             PRINT COLUMN   4, "D O C U M E N T O" 

             PRINT COLUMN   1, "|----------------------|" 

             PRINT COLUMN   3, "Numero", 
                   COLUMN  11, "Tipo",   
                   COLUMN  17, "Fecha", 
                   COLUMN  63, "Pendiente ",
                   COLUMN  99, "B A L A N C E" 

             PRINT COLUMN   1, 
                   "--------------------------------------------------",
                   "--------------------------------------------------" ,
                   "-----------"
      END IF

         LET b_balance = b_balance + x.valor

             IF dias < 31 THEN
                LET v1_30 = p_valor + v1_30
             END IF
             IF dias > 30 and dias < 46 THEN
                LET v31_45 = p_valor + v31_45
             END IF
             IF dias > 45 and dias < 61 THEN
                LET v46_60 = p_valor + v46_60
             END IF
             IF dias > 60 THEN
                LET vm_60 = vm_60 + p_valor
             END IF

         PRINT COLUMN   3, x.aplica_a using "######",
               COLUMN  12, tipo, 
               COLUMN  16, fecha2 using "dd/mm/yy",
               COLUMN  59, x.valor  using "(((,(((,(((.&&)",
               COLUMN  97, b_balance using "(((,(((,(((.&&)" 
         END IF
        END IF
     
        AFTER GROUP OF x.sec_cliente
     IF v1_30 <> 0 OR v31_45 <> 0 OR v46_60 <> 0 OR vm_60 <> 0 THEN
        SKIP 1 LINE
        PRINT COLUMN 1, "ANALISIS POR ANTIGUEDAD",negrillas_on,
              COLUMN 32, "1 a 30",
              COLUMN 46, "31 a 45",
              COLUMN 60, "46 a 60",
              COLUMN 74, "Mas de 60",negrillas_off

        PRINT COLUMN 1, "DE SU APRECIADA CUENTA: ",
              COLUMN 25, v1_30 using "((,(((,(((.&&)",
              COLUMN 41, v31_45 using "((,(((,(((.&&)",
              COLUMN 54, v46_60 using "((,(((,(((.&&)",
              COLUMN 70, vm_60 using "((,(((,(((.&&)"

              LET  v1_30  =   0
              LET  v31_45  =  0
              LET  v46_60  =  0
              LET  vm_60  =   0


 SKIP 1 LINE
 PRINT COLUMN 1,
 "NOTA: ESTAMOS REMITIENDO EL ESTADO DE SU CUENTA A LA FECHA SENALADA MAS ARR",
 "IBA.  EL MISMO PRESENTA UN BALANCE VEN-"
 PRINT COLUMN 1," " 
 PRINT COLUMN 1, 
 "      CIDO A MAS DE ",dias2 USING "###"," DIAS, EL CUAL ESTA COMPUESTO POR ",
 "LAS FACTURAS QUE SE INDICAN EN ESTE ESTADO. SI EXISTE AL-"
 PRINT COLUMN 1," " 
 PRINT COLUMN 1, 
 "      GUNA DIFERENCIA LUEGO DE REVISARLO LE AGRADECEREMOS SE COMUNIQUE  CON",
 " NUESTRO DEPARTAMENTO DE TESORERIA  CON"
 PRINT COLUMN 1," " 
 PRINT COLUMN 1, 
 "      LA LIC. IRIS SALSE AL TELEFONO 683-0353 A LA MAYOR BREVEDAD POSIBLE",
 ". EN CASO CONTRARIO  FAVOR ENVIARNOS EL"
 PRINT COLUMN 1," " 
 PRINT COLUMN 1, 
 "      PAGO VIA NUESTRO VENDEDOR. DEBIDO A ESTE ATRASO SU CREDITO QUEDA MOME",
 "NTANEAMENTE SUSPENDIDO"

 PRINT COLUMN 1," " 
 PRINT COLUMN 1," " 
 PRINT COLUMN 1, "   " 
 PRINT COLUMN 1, "   " 
 PRINT COLUMN 1, 

 "       ________________________________                ___________________________________"
 PRINT COLUMN 1, 
 "              NOMBRE QUIEN RECIBE                             FIRMA Y SELLO COMPANIA "
    SKIP TO TOP OF PAGE
    END IF

 PAGE TRAILER
  SKIP 1 LINE
  PRINT COLUMN 1, negrillas_on,     
 "PG-Pago  FT-Factura Local  FE-Factura Exterior  ",
 "ND-Nota Debito  NC-Nota Credito  DE-Devolucion",
               negrillas_off

 END REPORT