{
------------------------------------------------------------------------
 FORMULARIO        : ADFMMT011
 OBJETIVO          : Pantalla para introducir las informaciones de los
                     datos basicos de la solicitud de empleo.
                     Es utilizada por: ADPRMT011
 PROGRAMADOR       : Ing. Betania Guerrero Perez
 FECHA REALIZACION : Junio 24, 1993  
------------------------------------------------------------------------
}
SCHEMA smarmotech  

TOOLBAR
  ITEM nuevo (TEXT="Nuevo", IMAGE="new", COMMENT="Adicionar Registos")
  ITEM buscar (TEXT="Buscar", IMAGE="find", COMMENT="Buscar Regustros")  SEPARATOR
  ITEM salir (TEXT="Salir", COMMENT = "Salir del Programa", IMAGE="quit") 
END

screen size 24 by 80
{
Applicant's Number     [f000]          Application Date [f018      ]
Applicant's Name       [f001           ] [n2             ] 
Last Name              [f002           ] [a2             ]
Street           [f003                          ]House Apt. No.  [f004      ]
City             [f005                ]         Location[f006                ]
Telephone Number [f07     ]   Birthplace [c ] [d                             ]
Birthdate        [f008      ] Nationality[f09][g                             ]
Marital Status   [a] [h      ]Height [f010]Weight     [f11] Lbs.
ID               [f012     ][f13] License No.[f014     ]Blood Type[a0 ]
Native Language  [f015      ] [b] [k] [m]
Other Language   [f016                                              ]
Position Applynes[f1] [n                              ]
Profession       [b1 ] [n1                            ] Sex [s]
}
end
tables
adtb00012,vetb00020,
adtb00004,adtb00007,
adtb00010
attributes
f000 = adtb00012.cod_sol,noentry;
f018 = adtb00012.fecha,format = "dd/mm/yyyy", 
 comments = "Digite la Fecha de la Solicitud";
f001 = adtb00012.nom1_sol,upshift,
 comments = "Digite el primer nombre del Solicitante";
n2 = adtb00012.nom2_sol,upshift,
 comments = "Digite el segundo nombre del Solicitante";
f002 = adtb00012.apell1_sol,upshift,
 comments = "Digite el primer apellido del Soliciante";
a2 = adtb00012.apell2_sol,upshift,
 comments = "Digite el segundo apellido del Soliciante";
f003 = adtb00012.calle,upshift,comments = "Digite el nombre de la Calle";
f004 = adtb00012.casa_num,comments = "Digite el numero de la Casa";
f005 = adtb00012.barrio,upshift,comments = "Digite el nombre del Barrio";
f006 = adtb00012.urbanizacion,upshift,
 comments = "Digite el nombre de la Urbanizacion";
f07 = adtb00012.telefono,autonext,picture = "XXX-XXXX";
c = adtb00012.cod_provincia,autonext,
comments = "Digite el codigo de la provincia o Presione Ctrl-W para busqueda";
d = vetb00020.nombre_provincia,noentry;
f008 = adtb00012.fech_nac,format = "dd/mm/yyyy",
 comments = "Digite la fecha de nacimiento del Solicitante";
f09 = adtb00012.cod_nac,autonext,comments = 
   "Digite el codigo de la Nacionalidad o Presione Ctrl-W para busqueda";
g = adtb00007.nom_nac,noentry;
a = adtb00012.estado_civil,include = ("S","C"),autonext,upshift,
  comments = "Digite S = Soltero o C = Casado";
h = formonly.descr,noentry;
f010 = adtb00012.estatura,autonext,
 comments = "Digite la Estatura del Solicitante. Ej.: 5'7''";
f11 = adtb00012.peso,autonext,comments = "Digite el Peso del Solicitante";
f012 = adtb00012.cedula,comments = "Digite el Numero de Cedula";
f13 = adtb00012.serie,comments = "Digite el Numero de Serie";
f014 = adtb00012.licencia,comments = "Digite el Numero de Licencia";
a0 = adtb00012.tipo_sangre,upshift,comments = "Digite el Tipo de Sangre";
f015 = adtb00012.idioma,upshift,
   comments = "Digite el idioma que conoce";
b = adtb00012.h_idioma,upshift,autonext,
 comments = "Digite H = Habla el idioma";
k = adtb00012.l_idioma,upshift,autonext,
 comments = "Digite L = Lee el idioma";
m = adtb00012.e_idioma,upshift,autonext,
 comments = "Digite E = Escribe el idioma";
f016 = adtb00012.otros_idioma,upshift,
 comments = "Digite otros idiomas que conoce";
f1 = adtb00012.cod_puesto,autonext,
 comments = "Digite el codigo del Puesto o Presione Ctrl-W para busqueda";
n = adtb00004.nom_puesto,noentry;
b1 = adtb00012.cod_prof,autonext,
 comments = "Digite el codigo de la profesion o Presione Ctrl-W para busqueda";
n1 = adtb00010.nom_prof,noentry;
s  = adtb00012.sexo,upshift,include = ("M","F"),comments=
     "Digite el Sexo Del Solicitante";
end