database smarmotech
ACTION DEFAULTS
 ACTION buscalista (TEXT="Busca Informacion",image="find")
 ACTION guardar    (TEXT="Actualiza Informacion",image="save")
 ACTION limpia    (TEXT="Limpia Screen",image="clear")
 ACTION cancel     (TEXT="Cancela operacion",image="stop")
END

TOOLBAR 
  ITEM nuevo (TEXT="Precio", IMAGE="new", COMMENT="Asignar Nuevo Precia a un producto")
  
 SEPARATOR
  ITEM salir (TEXT="Salir", IMAGE="quit")
END

LAYOUT (TEXT="ADMINISTRACION PRECIOS",STYLE="basic")
  FOLDER
   PAGE p1 (TEXT="LISTA PRODUCTOS")
     SCROLLGRID
{   

<t                                                                                                                                                                    >
  [cod ][x5 ][x6  ][x7  ][x8   ][x9                               ][x10 ][a1][a21   ][nom                            ][k1 |p         ][std          ][creal          ][k2]
  [cod ][x5 ][x6  ][x7  ][x8   ][x9                               ][x10 ][a1][a21   ][nom                            ][k1 |p         ][std          ][creal          ][k2]
  [cod ][x5 ][x6  ][x7  ][x8   ][x9                               ][x10 ][a1][a21   ][nom                            ][k1 |p         ][std          ][creal          ][k2]
  [cod ][x5 ][x6  ][x7  ][x8   ][x9                               ][x10 ][a1][a21   ][nom                            ][k1 |p         ][std          ][creal          ][k2]
  [cod ][x5 ][x6  ][x7  ][x8   ][x9                               ][x10 ][a1][a21   ][nom                            ][k1 |p         ][std          ][creal          ][k2]
  [cod ][x5 ][x6  ][x7  ][x8   ][x9                               ][x10 ][a1][a21   ][nom                            ][k1 |p         ][std          ][creal          ][k2]
  [cod ][x5 ][x6  ][x7  ][x8   ][x9                               ][x10 ][a1][a21   ][nom                            ][k1 |p         ][std          ][creal          ][k2]
  
}
 END 
END
PAGE p2 (TEXT="ADMINISTRACION PRODUTOS")
 GRID
{
 Codigo Lista   [co1 ]
 Tipo de Venta  [a                     ]
 Producto       [c ]-[d ]-[e  ]-[f  ][h                                       ][l  ]
 Cliente        [f4]-[f005] [m                             ]
 Precio         [f006        ] Costo STD[cst      ]Costo Lquidado[lq               ]
 Existencia     [ex          ]                     Fecha Liq.    [fe        ]  
 [j]
 Usuario Creador  [f007     ]              Usuario Modificador [f009     ]
 Fecha Creacion   [f008            ]       Fecha Modificacion  [f010            ]
}
   end
END 
END
tables
vetb00025,vetb00003
attributes
LABEL ex= formonly.existencia,FORMAT="---,--&.##";
LABEL fe= formonly.fecha_liq, FORMAT="dd/mm/yyyy";
cod = formonly.codLista,TITLE="Codigo Lista";
x5 = formonly.codn,TITLE="Clase";
x6 = formonly.codgrupo,TITLE="Grupo";
x7 = formonly.codtipo,TITLE="Tipo";
x8 = formonly.codsec,TITLE="Secuencia";
x9 = formonly.descripcion_p,TITLE="Producto";
x10 = formonly.unidadMed;
a1  = formonly.tipoCliente,TITLE="Tipo Cliente";
a21  = formonly.secCliente,TITLE="Codigo Cliente";
nom = formonly.nombreCliente,TITLE="Nombre";
p   = formonly.pprecio,TITLE="Precio";
std = formonly.costo_std1,TITLE="Costo STD";
creal = formonly.costo_r,TITLE="Costo Liquidado";

co1 = formonly.cod_lista;
cst = formonly.costo_std,noentry;
lq  = formonly.costo_lq,noentry,format="##,###,###.##";
COMBOBOX a = formonly.ventas,required;
c = vetb00025.cod_n,autonext,
  comments = "Presione Ctrl-W para busqueda o digite el nivel del producto";
d = vetb00025.cod_grupo,autonext,
  comments = "Presione Ctrl-W para busqueda o digite el grupo del producto";
e = vetb00025.cod_tipo,autonext,
  comments = "Presione Ctrl-W para busqueda o digite el tipo del producto";
f = vetb00025.cod_sec,autonext,
  comments = "Presione Ctrl-W para busqueda o digite la secuencia del producto";
 h = formonly.descripcion;
l = formonly.medida,noentry;
f4 = vetb00025.tipo_cliente,widget="FIELD_BMP",   config="combo.bmp control-w";
f005 = vetb00025.sec_cliente,widget="FIELD_BMP",   config="combo.bmp control-w";
m = formonly.nom_cliente,noentry;
k1 = formonly.moneda;
f006 = vetb00025.precio;
j = vetb00025.status_t,noentry;
f007 = vetb00025.us_crea,noentry;
f008 = vetb00025.fech_crea,noentry;
f009 = vetb00025.us_mod,noentry;
f010 = vetb00025.fech_mod,noentry;
k2   = formonly.pventas, HIDDEN;
instructions
 delimiters " "
 screen record lproducto (codLista,codn,codgrupo,codtipo,codsec,descripcion_p,unidadMed,tipoCliente,secCliente,nombreCliente,moneda,pprecio,costo_std1,costo_r,pventas)
end