{
-------------------------------------------------------------------------------
PROGRAMA             :  COPRRP024
SISTEMA              :  Sistema de Compras
OBJETIVO             :  Validacion de Ordenes Pendientes
PROGRAMADOR          :  Tadeo A. Ferreras           
FECHA REALIZACION    :  Julio 28, 1993 
-------------------------------------------------------------------------------
}
GLOBALS "coprgb000.4gl"

  DEFINE mov CHAR(1)
  DEFINE idx_1, idx_2, idx_3 SMALLINT ## Variables usadas para formar arreglos 
  DEFINE fecha1,fecha2 DATE ## Varible usada para busqueda por fecha de corte
  DEFINE salir, salir1, salir3, tipo_venta CHAR(1) ## Bandera para control loop
  DEFINE selec5, selec6 CHAR(1500) ## Variables para almacenar busquedas

 ####### Variables para desplegar resultados por pantalla ante de la impresion

    DEFINE tot_gen1 RECORD 
       totald     DECIMAL(10,2),
       totalc     DECIMAL(10,2),
       totalg     DECIMAL(10,2)
   END RECORD

##### Registro que almacena la informacion a imprimir ####

    DEFINE movtos RECORD
           num_oc         INTEGER, 
           cod_n          SMALLINT,
           cod_grupo      SMALLINT,
           cod_tipo       SMALLINT,
           cod_sec        SMALLINT,
           descrip_esp    CHAR(30),
           unidad_med     CHAR(10),
           fecha_oc       DATE,    
           fech_emb       DATE,
           fech_ent       DATE,
           fecha_a        DATE,
           dia_llegada    SMALLINT
    END RECORD

####### Funcion para busqueda de informacion
FUNCTION coprrp024()

   WHENEVER ERROR CONTINUE

  OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

 ####### Abriendo y desplegando formulario de captura de datos

  OPEN FORM cofmrp024 FROM "cofmrp005"
  DISPLAY FORM cofmrp024
  CALL pantalla()
  DISPLAY "coprrp024" AT 4,3
  DISPLAY "Validacion Ordenes Pendientes" AT 6,25

  LET tipo_papel = 1
  CALL msgrp000(tipo_papel)

 ##### Aceptando la fecha de corte para busqueda de informacion

  INPUT BY NAME fecha1,fecha2

     AFTER FIELD fecha1 
       IF fecha1 is null THEN  
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD fecha1 
       END IF

     BEFORE FIELD fecha2
       LET fecha2 = today

     AFTER FIELD fecha2 
       IF fecha2 is null THEN  
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD fecha2 
       END IF

       IF fecha1 > fecha2 THEN
          LET numero_msg = 51
          CALL msg( numero_msg)
          NEXT FIELD fecha1
       END IF
    
 END INPUT 

###### Creando facilidad para cancelar operacion mediante la tecla DELETE
###### o SUPR

 IF int_flag THEN
    LET numero_msg = 2
    CALL msg(numero_msg)
    LET int_flag = false
    RETURN
 END IF

# Busca los documentos que esten en el rango de fechas especificado  

 LET selec5 = 
 "SELECT a.num_oc,a.cod_n,a.cod_grupo,a.cod_tipo,a.cod_sec,b.descrip_esp, ",
 "       b.unidad_med,c.fech_oc,a.fech_emb,a.fech_ent,a.fecha_a,d.dia_llegada ",
 "FROM cotb00014 c,cotb00025 a,intb00002 d,intb00001 b ",
 "WHERE c.num_oc = a.num_oc AND b.cod_n = a.cod_n AND ",
 "      b.cod_grupo = a.cod_grupo AND b.cod_tipo = a.cod_tipo AND ",
 "      b.cod_sec = a.cod_sec AND a.cod_n = d.cod_n AND a.cod_grupo = ",
 "      d.cod_grupo AND a.cod_tipo = d.cod_tipo AND a.cod_sec=d.cod_sec AND ",
 "      c.status_t is null AND ",
 "     c.fech_oc BETWEEN ? AND ? AND c.cierre = 'N' ORDER BY 1,2,3,4,5"

 DISPLAY "<< Buscando Informacion ... Espere Por Favor. >>" AT 19,14
          ATTRIBUTE (REVERSE,BOLD)
 DISPLAY "<<    Buscando los Movimientos del Rango    >>" AT 19,14
         ATTRIBUTE (REVERSE,BOLD)

 PREPARE movi FROM selec5 
 DECLARE movtos_cli CURSOR FOR movi 
 OPEN movtos_cli USING fecha1,fecha2

 DISPLAY "                                                " AT 19,14

 START REPORT compras1 TO "C:\\archivo"
 DISPLAY "                                                " AT 19,14
 DISPLAY "<< Reporte Generandose ...  Por Favor Espere. >>"
           AT 19,14 ATTRIBUTE (REVERSE) 

 ###### Comienza el loop para enviar informacion al reporte

 LET salir = "N" 
 WHILE salir != "S" 
         FETCH movtos_cli INTO movtos.* 

         IF status = NOTFOUND THEN
            LET salir = "S" 
            EXIT WHILE
         END IF

         IF int_flag THEN
            LET numero_msg = 2
            CALL msg(numero_msg)
            LET int_flag = FALSE
            RETURN     
         END IF

         OUTPUT TO REPORT compras1(movtos.*,fecha1,fecha2)  
   END WHILE
   FINISH REPORT compras1  
   CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION

####### Funcion para dar salida a la informacion

REPORT compras1(x,fecha3,fecha4)
  DEFINE x RECORD
         num_oc         INTEGER, 
         cod_n          SMALLINT,
         cod_grupo      SMALLINT,
         cod_tipo       SMALLINT,
         cod_sec        SMALLINT,
         descrip_esp    CHAR(30),
         unidad_med     CHAR(10),
         fecha_oc       DATE,    
         fech_emb       DATE,
         fech_ent       DATE,
         fecha_a        DATE,
         dia_llegada    SMALLINT
  END RECORD,
      cuenta SMALLINT

  DEFINE fecha3,fecha4 DATE
  DEFINE doble_on CHAR(2)
  DEFINE doble_off CHAR(2)
  DEFINE negrillas_on CHAR(6)
  DEFINE negrillas_off CHAR(6)
  DEFINE comp_on CHAR(2)
  DEFINE comp_off CHAR(2) 
  DEFINE doce CHAR(2)
  DEFINE normal CHAR(2) 
  DEFINE normall CHAR(3) 
  DEFINE comp CHAR(3)
  DEFINE hora CHAR(5)
  OUTPUT
    TOP MARGIN 0
    LEFT MARGIN 0
    BOTTOM MARGIN 2

    ###### Diseno de la salida de la informacion

    FORMAT
    PAGE HEADER
      LET doble_on =  ASCII 14
      LET doble_off = ASCII 20
      LET negrillas_on = ASCII 27, ASCII 69
      LET negrillas_off = ASCII 27, ASCII 70
      LET comp_on = ASCII 15
      LET comp_off = ASCII 18
      LET comp = ASCII 031
      LET doce = ASCII 27, ASCII 77  
      LET normal = ASCII 27, ASCII 80
      LET normall = ASCII 030 
      LET hora = time

      LET l = (117 - LENGTH(p_companias.nombre CLIPPED))/2
      PRINT COLUMN   1, doce,comp_on,negrillas_on
      PRINT COLUMN   1, "coprrp024",
            COLUMN   l, p_companias.nombre CLIPPED,
            COLUMN 110, "Pag. ",pageno using "###"
      PRINT COLUMN  53, "Sistema de Compra",
            COLUMN 110, today using "dd/mm/yy"
      PRINT COLUMN  44, "Reporte Validacion Ordenes Pendientes",
            COLUMN 113, hora
      PRINT COLUMN 50, "Del ",fecha3 USING "dd/mm/yy",
                       " Al ",fecha4 using "dd/mm/yy"

      PRINT COLUMN 1, "--------------------------------------------------",
                      "--------------------------------------------------",
                      "------------------"

      PRINT COLUMN  55,"Fecha",
            COLUMN  68,"Fecha",
            COLUMN  81,"Fecha"

      PRINT COLUMN   2,"Orden ",
            COLUMN  10,"Material",
            COLUMN  55,"Orden",
            COLUMN  68,"Embarque",
            COLUMN  81,"Entrega",
            COLUMN  93,"Fecha A",
            COLUMN 109,"Lead Time"

      PRINT COLUMN 1, "--------------------------------------------------",
                      "--------------------------------------------------" ,
                      "------------------"
      PRINT negrillas_off
    ON EVERY ROW

      PRINT COLUMN  1, x.num_oc USING "######",   
            COLUMN  10, x.cod_n USING "&","-",x.cod_grupo USING "&","-",
                        x.cod_tipo USING "&&","-",x.cod_sec USING "&&&",
                        " ",x.descrip_esp clipped,
            COLUMN  52, x.unidad_med CLIPPED, 
            COLUMN  55, x.fecha_oc USING "dd/mm/yy",
            COLUMN  68, x.fech_emb USING "dd/mm/yy",
            COLUMN  81, x.fech_ent USING "dd/mm/yy",
            COLUMN  93, x.fecha_a USING "dd/mm/yy",
            COLUMN 111, x.dia_llegada USING "###"

    AFTER GROUP OF x.num_oc
      IF cuenta IS NULL THEN
         LET cuenta = 0
      END IF
      SKIP 1 LINE
      LET cuenta = cuenta + 1
    ON LAST ROW
      SKIP 2 LINES
      PRINT "Total Ordenes Pendientes==> ",cuenta using "####"
      PRINT COLUMN 1,normal,comp_off,negrillas_off
END REPORT