{
-------------------------------------------------------------------------------
PROGRAMA             :  EDPRRP030
OBJETIVO             :  Listar las Entrada de Diario Reservas Honorarios
                        Auditorias.
PROGRAMADOR          :  Tadeo A. Ferreras          
FECHA REALIZACION    :  Julio 28, 3093 
-------------------------------------------------------------------------------
}
DATABASE rayovac
GLOBALS 

###### Variables para busqueda de rango de fecha
DEFINE afecta CHAR(1)
DEFINE cant_dias,cant_dias1,mes,mes1 SMALLINT 
DEFINE ano CHAR(4)  
DEFINE tasa DECIMAL(5,2) 
DEFINE p_fecha,fecha1, fecha2 DATE  
DEFINE ventas CHAR(1)
DEFINE entra  CHAR(14)
DEFINE entra1 CHAR(5)
DEFINE detalle CHAR(30)

###### Variables para almacenar los datos selecionados
DEFINE selec5, selec6 CHAR(1500) 

###### Variables que la almacenan la informacion enviada al reporte

###### Variables que la almacenan la informacion enviada al reporte
DEFINE diario2 RECORD 
       valor        DECIMAL(12,2)
END RECORD
DEFINE tipo_papel SMALLINT
END GLOBALS

MAIN 
 DEFER INTERRUPT
 CALL edprrp030()
END MAIN 

FUNCTION edprrp030()

#   WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

##### Abriendo y desplegando el formulario de captura de datos

    OPEN FORM edfmrp030 FROM "edfmrp030"
    DISPLAY FORM edfmrp030
    CALL pantalla()
    DISPLAY "edprrp030" AT 4,3
    DISPLAY "Entrada de Diario Honarario Auditores" AT 6,33

    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

 ###### Aceptando los valores para el rango de fecha

  INPUT BY NAME entra,fecha1,fecha2,afecta,detalle

        AFTER FIELD entra

     SELECT  UNIQUE ref FROM cgtb00004 WHERE ref = entra

     IF STATUS != NOTFOUND THEN
        ERROR "(12) REGISTRO EXISTE"
        NEXT FIELD entra
     END IF
   
         LET entra1 = entra

        BEFORE FIELD fecha1
         SELECT max(fecha) INTO p_fecha FROM cgtb00004
         WHERE ref[1,5] = entra1
         LET fecha1 = p_fecha + 1
         DISPLAY BY NAME fecha1 

         AFTER FIELD fecha1
          IF fecha1 IS NULL THEN
            ERROR "(16) CAMPO EN BLANCO"
            NEXT FIELD fecha1
          END IF

          IF fecha1 <= p_fecha THEN
             ERROR "(179) EXISTE ENTRADA DE DIARIO CON ESA FECHA"
             NEXT FIELD fecha1
          END IF

        AFTER FIELD fecha2
          IF fecha2 IS NULL THEN
            ERROR "(16) CAMPO EN BLANCO"
            NEXT FIELD fecha2
          END IF

          IF fecha1 > fecha2 THEN
             ERROR "(86) FECHA INICIAL NO PUEDE SER MAYOR QUE LA ANTERIOR"
             NEXT FIELD fecha1
          END IF

        AFTER FIELD afecta
          IF afecta IS NULL THEN
            ERROR "(16) CAMPO EN BLANCO"
            NEXT FIELD afecta
          END IF

 END INPUT 
##### Creando la facilidad para cancelar proceso con DELETE O SUPR

              IF int_flag THEN
                 ERROR "(2) OPERACION CANCELADA"
                 LET int_flag = false
                 RETURN
              END IF


# Busca la informacion requerida
LET ano = YEAR(fecha2) USING "&&&&"
LET mes1 = MONTH(fecha2) 
SELECT SUM(a.dias_habiles) INTO cant_dias FROM prdtable a 
WHERE a.ano = ano

SELECT SUM(a.dias_habiles) INTO cant_dias1 FROM prdtable a 
WHERE a.ano = ano AND a.mes = mes1

   DECLARE buscar1 CURSOR FOR 
    SELECT (((a.valor*1.05)/cant_dias)*cant_dias1)/12 FROM pgtb00002 a 
    WHERE a.cuenta_no = '7430' AND a.departamento = 2100 AND a.ano = ano

    DISPLAY "<< Buscando Informacion ... Espere Por Favor. >>" AT 17,14
            ATTRIBUTE (REVERSE,BOLD)

   OPEN buscar1 

  ##### Envia la Informacion al printer de contabilidad

   START REPORT report30 TO "ed30" #PIPE "lp -dcentral"
   DISPLAY "<< Reporte Generandose ...  Por Favor Espere. >>"
           AT 17,14 ATTRIBUTE (REVERSE) 

##### Loop para enviar informacion al reporte

   WHILE STATUS != NOTFOUND
     FETCH buscar1 INTO diario2.*

         IF status = NOTFOUND THEN
            EXIT WHILE
         END IF

         IF int_flag THEN
            ERROR "(2) OPERACION CANCELADA"
            LET int_flag = FALSE
            RETURN     
         END IF

  OUTPUT TO REPORT report30(diario2.*,fecha1,fecha2,ano,entra,detalle)
 END WHILE
      FINISH REPORT report30 
   CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION

#### Funcion para dar salida ordenada a la informacion requerida de
#### una entrada de diario de ventas exportacion

    REPORT report30(x,fecha1,fecha2,ano1,entrada,detalle1)
    DEFINE x RECORD
       valor        DECIMAL(12,2)
    END RECORD

 #### Acumula los valores de las diferentes cuentas para entrada diario de venta
    DEFINE total1,total2,total3,total4,total5,total6 DECIMAL(12,2)

    DEFINE total7,total8 DECIMAL(12,2) ## Acumula los totales DEBITO Y CREDITO 
    DEFINE fecha1,fecha2 DATE #### Almacena las fecha del rango de busqueda
    DEFINE ano1 CHAR(4)
    DEFINE mes2 CHAR(16)
    DEFINE mes1 SMALLINT
    DEFINE doble_on CHAR(4)
    DEFINE doble_off CHAR(4)
    DEFINE negrillas_on CHAR(6)
    DEFINE negrillas_off CHAR(6)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(2)
    DEFINE normal CHAR(2) 
    DEFINE normall CHAR(3) 
    DEFINE comprimido CHAR(3)
    DEFINE hora CHAR(5)
    DEFINE dpto CHAR(4)
    DEFINE venta1 CHAR(24)
    DEFINE entrada CHAR(14)
    DEFINE aux CHAR(7)
    DEFINE tasa1 DECIMAL(5,2)
    DEFINE detalle1 CHAR(30)
    OUTPUT
       TOP MARGIN 0
       LEFT MARGIN 0
       BOTTOM MARGIN 2

    FORMAT
      PAGE HEADER
        LET doble_on =  ASCII 001
        LET doble_off = ASCII 002
        LET negrillas_on = ASCII 027, ASCII 098
        LET negrillas_off = ASCII 027, ASCII 099
        LET comp_on = ASCII 31
        LET comp_off = ASCII 029
        LET comprimido = ASCII 031
        LET doce = ASCII 030
        LET normal = ASCII 27, ASCII 80
        LET normall = ASCII 029 
        LET hora = time

##### Selecionado la descripcion del mes

SELECT a.descrip INTO mes2 FROM mestable a WHERE a.mes = mes1

           PRINT COLUMN   1, comp_off     
           PRINT COLUMN   1, "edprrp030",
                 COLUMN  26, "R A Y . O . V A C  D O M I N I C A N A,  S. A.",
                 COLUMN 75, "Pag. ",pageno using "###"
           PRINT COLUMN 26, "           Sistema de Contabilidad",
                 COLUMN 75, today using "dd/mm/yy"

           PRINT COLUMN 23, "Entrada de Diario Honorario Auditores",   
                 COLUMN 78, hora

           PRINT COLUMN 30, "Del ",fecha1 USING "dd/mm/yy", " Al ",fecha2
                            USING "dd/mm/yy"
#                         , negrillas_off 
           SKIP 1 LINE
           PRINT COLUMN 34,"Entrada de Diario No. ",doble_on,entrada,doble_off 

         PRINT COLUMN 01, "Observaciones: _____________________________________"
         PRINT COLUMN 01, "               _____________________________________"

         PRINT COLUMN 1, 
                   "--------------------------------------------------",
                   "----------------------------------",
                    negrillas_on 

             PRINT COLUMN   2, "Cuenta",
                   COLUMN  11, "Dpto", 
                   COLUMN  56, "Debe", 
                   COLUMN  71, "Haber",negrillas_off 

             PRINT COLUMN 1, 
                   "--------------------------------------------------",
                   "----------------------------------"

      ON EVERY ROW
          PRINT COLUMN  2, "7430", 
               COLUMN  11, "2100",
               COLUMN  18, "SERVICIOS PROFESIONALES",
               COLUMN  50, x.valor using "###,###,##&.&&" 

 IF afecta = "S" THEN
  INSERT INTO cgtb00004 VALUES(fecha2,1,entrada,"7430",2100,null,null,null,null,
                                detalle1,null,x.valor,0,null,user,current,
                                null,null)
 END IF
 
  ###### La cuenta 1124 es igual a la sumatoria de de la 1121 multiplicado
  ###### por la tasa de cambio menos 1
  #### La cuenta 4100 es igual al bruto de la factura por tasa de cambio

         LET total1 = x.valor
         PRINT COLUMN   2, "2134", 
               COLUMN  18, "RESERVA HONORARIOS AUDITORES",
               COLUMN  65, x.valor using "###,###,##&.&&" 

 IF afecta = "S" THEN
  INSERT INTO cgtb00004 VALUES(fecha2,1,entrada,"2134",null,null,null,null,null,
                                detalle1,null,0,x.valor,null,user,current,
                                null,null)
 END IF
 
    ON LAST ROW
###### Imprime total DEBITO y total CREDITO
         PRINT COLUMN 1,negrillas_on 
         PRINT COLUMN 50,"______________",
               COLUMN 65,"______________"

         PRINT COLUMN 35,"Totales-->",
               COLUMN 50,total1 USING "###,###,##&.&&",
               COLUMN 65,total1 USING "###,###,##&.&&"
     SKIP 2 LINE
         PRINT COLUMN  1, detalle1
         SKIP 1 LINE
         PRINT COLUMN 1,comp_off,negrillas_off

     END REPORT

{
  Esta funcion se utiliza para desplegar mensajes de los reportes de 
  los sistemas de Ray-O-Vac Dominicana. 

  Realizada por Lic. Abner Montalvo y Johnny Soto         Agosto 21, 1992 
}
FUNCTION msgrp000(tipo_papel)
         DEFINE tipo_papel SMALLINT,
                longitud   CHAR(11),
                linea_papel CHAR(50) 

         CASE 
            WHEN tipo_papel = 1
                 LET longitud = " 9 1/2 x 11"
            WHEN tipo_papel = 2
                 LET longitud = "14 7/8 x 11"
         END CASE

         LET linea_papel = "Coloque papel ",longitud," en la impresora." 
         DISPLAY linea_papel 
                 AT 15,14 
         DISPLAY "Asegurese de que la impresora este encendida."
                 AT 16,14 
         DISPLAY "<Esc> Ejecuta impresion     <Supr> Cancela impresion" 
                 AT 18,14 

RUN "type C:\\archivo > %USPRINT%" END FUNCTION

FUNCTION pantalla() 
    DEFINE fecha CHAR(8),
           hora char(5) 
    LET fecha = today USING "dd/mm/yy"  
    LET hora = time
    DISPLAY "R A Y . O . V A C  D O M I N I C A N A,  S. A." AT 4,17
            ATTRIBUTE (REVERSE,YELLOW)
    DISPLAY fecha AT 4,70 ATTRIBUTE (YELLOW)
    DISPLAY "Sistema de Contabilidad General" AT 5,24
    DISPLAY hora AT 6,73 ATTRIBUTE(YELLOW)

    CALL fgl_drawbox(5,79,3,1)
    CALL fgl_drawbox(1,79,22,1)
RUN "type C:\\archivo > %USPRINT%" END FUNCTION