{
==============================================================================
    PROGRAMA    : CGPRRP013
    SISTEMA     : Sistema de Contabilidad General
    OBJETIVO    : Imprimir Balance para las Cuentas con Estado_M Resultados
    PROGRAMADOR : Ing. Juan Soto
    FECHA       : Octubre 17, 2016
==============================================================================
}
GLOBALS
  "cgprgb000.4gl"
 DEFINE estado2 RECORD
   estado_a     CHAR(8),
   balance_ant  DECIMAL(12,2),
   actividad    DECIMAL(12,2),
   balance_act  DECIMAL(12,2),
   descripcion  VARCHAR(40),
   grupo        VARCHAR(40),
   orden_grupo SMALLINT,
   tasa        DEC(10,2),
   mes         VARCHAR(20),
   variacion   DEC(12,2),
   porc_v      DEC(10,2)
  END RECORD,
  p_ano,p_mes SMALLINT,
  estado,tipo_estado VARCHAR(50)



MAIN
 DEFER INTERRUPT
 CALL ARG_VAL(1) RETURNING usuarios
 CALL ARG_VAL(2) RETURNING clave
 CALL ARG_VAL(3) RETURNING impresor
  
  CONNECT to "smarmotech"  USER  usuarios USING clave
 SELECT a.* INTO p_compania.* FROM companias a

 CALL cgprrp013()
END MAIN
   
  FUNCTION cgprrp013()
  LET int_flag = FALSE

  OPTIONS
     FORM LINE 9
     
   OPEN FORM cgfmrp008 FROM "cgfmrp013"
   DISPLAY FORM cgfmrp008
   DISPLAY "cgprrp013" AT 4,3
   DISPLAY "Catalogo / Estado-M" AT 6,30

   LET tipo_papel = 1
   CALL msgrp000(tipo_papel)

  
   INPUT BY NAME p_ano,p_mes,estado,tipo_estado
    BEFORE INPUT
      LET p_ano = YEAR(TODAY) USING "&&&&"
      SELECT MAX(a.mes) INTO p_mes FROM cgtb00016 a WHERE a.ano=p_ano
      DISPLAY BY NAME p_ano,p_mes
    AFTER input
    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
     END IF
     SELECT DISTINCT a.tasa INTO estado2.tasa FROM cgtb00084 a
     WHERE a.mes = p_mes AND a.ano=p_ano AND a.ventas IN (2,3)
     SELECT a.descrip INTO estado2.mes FROM mestable a WHERE a.mes =p_mes
     
      
     EXIT INPUT
     END INPUT
     CALL seleccionarsalida() RETURNING r_output

     IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
     END IF

                                
      DECLARE busco CURSOR FOR
        SELECT a.estado_a,'0',SUM(a.actividad),ISNULL(SUM(a.balance_act),0),b.descripcion,b.grupo,
              b.orden_grupos
        FROM cgtb00016 a LEFT OUTER JOIN cgtb00036 b ON
         a.estado_a is not null  AND
              a.ano = p_Ano AND a.mes = p_mes AND a.estado_m = b.estado 
         WHERE     
              b.descripcion_estado = estado AND b.tipo_estado = tipo_estado
        GROUP BY a.estado_a,b.descripcion,b.grupo,b.orden_grupos

        UNION
        SELECT a.estado_a,ISNULL(SUM(a.balance_act),0),SUM(a.actividad),'0',b.descripcion,b.grupo,
              b.orden_grupos
        FROM cgtb00016 a LEFT OUTER JOIN cgtb00036 b ON
         a.estado_a is not null  AND
              a.ano = p_Ano-1 AND a.mes = p_mes AND a.estado_m = b.estado 
         WHERE     
              b.descripcion_estado = estado AND b.tipo_estado = tipo_estado
        GROUP BY a.estado_a,b.descripcion,b.grupo,b.orden_grupos
        ORDER BY b.orden_grupos,b.grupo


       DISPLAY "<< Buscando Informacion ... Espere por Favor. >>" AT 19,14
       ATTRIBUTE(REVERSE,BOLD)

       
       LET idx=1             
       FOREACH busco INTO estado2.*

            IF int_flag THEN
                LET numero_msg = 2
                CALL msg(numero_msg)
                LET int_flag = FALSE
                FINISH REPORT estado3_gral
                EXIT FOREACH
            END IF 
         IF idx=1 THEN
             IF fgl_report_loadCurrentSettings("cgprrp013.4rp") THEN 
                CALL fgl_report_selectDevice(r_output)                  
                LET handler = fgl_report_commitCurrentSettings()
             ELSE
                EXIT PROGRAM   
             END IF
                   
             START REPORT estado3_gral TO XML HANDLER HANDLER
          END IF
 
          OUTPUT TO REPORT estado3_gral(estado2.*,fecha_inicial,fecha_final)
          LET idx=idx+1
          
         END FOREACH

         IF idx > 1 THEN
            FINISH REPORT estado3_gral
         ELSE
            CALL fgl_winmessage("INFO","NO EXISTEN REGISTROS CON ESTA CONDICION","INFO")
         END IF 
     
END FUNCTION

REPORT estado3_gral(x,fecha1,fecha2)
   DEFINE x RECORD
        estado_a     CHAR(8),
          balance_ant  DECIMAL(12,2),
          actividad    DECIMAL(12,2),
          balance_act  DECIMAL(12,2),
          descripcion  VARCHAR(40),
          grupo        VARCHAR(40),
          orden_grupo SMALLINT,
          tasa        DEC(10,2),
          mes         VARCHAR(20),
          variacion   DEC(12,2),
          porc_v      DEC(10,2)
     END RECORD,
   total_g_actual,total_g_anterior,balance_actual,balance_anterior,total_b_anterior,total_b_actual DEC(12,2)
   DEFINE fecha1,fecha2 DATE,
   p_ano_ant SMALLINT
   
    DEFINE hora CHAR(5)

    OUTPUT
## DEFINICION DE LOS MARGENES DE IMPRESION
     TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 3

     
    ORDER BY x.orden_grupo,x.grupo,x.estado_a 
    FORMAT
       PAGE HEADER
          LET hora = TIME
          LET p_ano_ant = p_Ano -1

  BEFORE GROUP OF x.grupo
     LET total_b_anterior=0
     LET total_b_actual=0
     PRINTX x.grupo
     
  AFTER GROUP OF x.estado_a
         LET balance_actual = GROUP SUM(x.balance_act)
         LET balance_anterior = GROUP SUM(x.balance_ant)
         
         LET x.variacion = balance_actual-balance_anterior
         LET x.porc_v = (x.variacion/balance_anterior)*100
         PRINTX x.estado_a,x.descripcion, 
               balance_actual ,balance_anterior,
               x.actividad ,
               x.balance_act,
              p_compania.nombre,hora,p_ano,p_mes,p_ano_ant,
             estado2.mes,x.tasa,x.mes,x.variacion,x.porc_v,estado,tipo_estado
             
   AFTER GROUP OF x.grupo
     
     LET total_b_actual=GROUP SUM(x.balance_act)
     LET total_b_anterior=GROUP SUM(x.balance_ant)
     PRINTX total_b_anterior,total_b_actual
  ON LAST ROW
     LET total_g_actual=SUM(x.balance_act)
     LET total_g_anterior=SUM(x.balance_ant)
     PRINTX total_g_actual,total_g_anterior  
END REPORT