{
----------------------------------------------------------------------------
FORMULARIO          : CGFMMT004
OBJETIVO            : Capturar las transacciones contables (CGPRMT004)
PROGRAMADOR         : Ing. Juan Soto
FECHA REALIZACION   : Octubre 6, 1993
----------------------------------------------------------------------------
}
schema smarmotech   
TOOLBAR
ITEM nuevo (TEXT="NUEVO",IMAGE="new")
ITEM buscar (TEXT="BUSCAR",IMAGE="find")
ITEM entradas (TEXT="PROCESO BUSQUEDA REGISTROS",IMAGE="zoom")
ITEM SALIR (TEXT="SALIR",IMAGE="exit")

END

LAYOUT (TEXT="ENTRADAS DIARIO", STYLE="basic")
 GRID

{
<G Generales                                                                   >
 Fecha    :[fe        ]  Entrada No.  [f00           ] 
 Detalle  :[a1                            ][b1                            ]
 Impresion:[imp                           ]
 Cheques : [ck]          Tipo Suplidor[tp] 
 Fecha Inicial[f1        ]Fecha Final[f2        ]
 Cuenta  : [cu        ][des1                                   ]
 
<G Detalle                                                                           >
    Cuenta No    Depto   Cod Aux       Refer           Debito          Credito
  [f003    ]  [f004] [f9][f009]   [f007      ]    [f005          ][f006          ]
  [f003    ]  [f004] [f9][f009]   [f007      ]    [f005          ][f006          ]
  [f003    ]  [f004] [f9][f009]   [f007      ]    [f005          ][f006          ]
  [f003    ]  [f004] [f9][f009]   [f007      ]    [f005          ][f006          ]
  [b                             ]               
  [a                             ] Totales     [pk4           ][pk5          ]
  [c                             ]

}
END
tables
cgtb00004,cgtb00001,
adtb00001
ATTRIBUTES
COMBOBOX imp = formonly.preview, ITEMS=(("1","VISTA PREVIA"),("0","DIRECTA"));
DATEEDIT fe  = formonly.fecha,format = "dd/mm/yyyy";
RADIOGROUP ck = formonly.cheques,ITEMS =(("CK","CHEQUES"),("CP","CUENTAS POR PAGAR")),DEFAULT="CK";
COMBOBOX tp = formonly.pcod_sp,ITEMS=("22","23","","24","25"),COMMENTS="Elija tipo Suplidor",DEFAULT="22";
DATEEDIT f1 = formonly.fecha1,FORMAT="dd/mm/yyyy";
DATEEDIT f2 = formonly.fecha2,FORMAT="dd/mm/yyyy";
         cu = formonly.pcuenta_no;
         des1 = formonly.pdescripcion;
f00 = formonly.entrada_no,upshift,autonext,picture = "ED.##-###/####",
  comments = 
"Para Entradas al diario 24-00/0893 o 24-02/0893 ";
f003 = formonly.cuenta,autonext,WIDGET="FIELD_BMP",config="combo.bmp control-w",
 comments = "Digite Cuenta Contable o Presione Ctrl-W Para Crear y/o Buscar";
f004 = cgtb00004.departamento,autonext,
  comments = "Digite el numero de departamento";
f9 = cgtb00004.cod_aux,comments = "12- Clientes   Suplidores   01- Empleados";
     
f009 = cgtb00004.cod_sec,comments = "Digite Codigo secuencial del auxiliar";
f007 = cgtb00004.num_doc,comments = "Digite el no. referencia";
f005 = cgtb00004.debito,comments =
"Digite el monto del debito o digite CTRL-P regresa al # Cta.";     
f006 = cgtb00004.credito,comments = 
"Digite el monto del credito o digite CTRL-P regresa al # Cta.";     
a1 = cgtb00004.detalles,autonext,upshift,comments = "Digite el detalle";
b1 = cgtb00004.detalle_1,upshift,comments = "Digite el detalle";
b = formonly.descrip,noentry;
a = formonly.nombre,noentry;
c = formonly.nombre_aux,noentry;
pk4 = formonly.t_debito,noentry;
pk5 = formonly.t_credito,NOENTRY;
instructions
delimiters " "
screen record s_trx[4] (cuenta,departamento,cod_aux,cod_sec,num_doc,
                        debito,credito)
end 
--