{  
------------------------------------------------------------------
 PROGRAMA          : COPRRP022 
 OBJETIVO          : Reporte de Maestra Compania Aseguradora
 PROGRAMADOR       : Tadeo A. Ferreras F.   
 FECHA REALIZACION : Mayo 13, 1993
------------------------------------------------------------------
}

GLOBALS 
     "coprgb000.4gl"
   DEFINE prt_comp RECORD
      cod_ca      LIKE cotb00022.cod_ca, # CODIGO DE LA COMPANIA
      nom_ca      LIKE cotb00022.nom_ca, # NOMBRE DE LA COMPANIA
      poliza      LIKE cotb00022.poliza  # POLIZA DE SEGURO 
   END RECORD

#### Funcion para buscar la informacion a imprimir

FUNCTION coprrp022() 
   OPTIONS
   FORM LINE 10
   CALL pantalla() 
   DISPLAY "coprrp022" AT 4,3 
   DISPLAY " Maestra de Companias Aseguradoras " AT 6,23
   LET int_flag = FALSE 
   OPEN FORM cofmrp022 FROM "cofmrp022"
   DISPLAY FORM cofmrp022
   LET tipo_papel = 1
   CALL msgrp000(tipo_papel)

 ##### Creando criterio de busqueda
  CONSTRUCT criterio ON a.cod_ca,a.nom_ca,a.poliza 
                   FROM cod_ca,nom_ca,poliza

  IF int_flag THEN
     LET numero_msg = 2
     CALL msg(numero_msg)
     LET int_flag = FALSE
     RETURN
  END IF

 #### Selecionando la informacion a imprimir

  LET selec = 
      "SELECT a.cod_ca,a.nom_ca,a.poliza FROM cotb00022 a ",
      "WHERE ",criterio clipped," ORDER BY 1"

  IF int_flag THEN
     LET numero_msg = 2
     CALL msg(numero_msg)
     LET int_flag = FALSE
     RETURN
  END IF

  DISPLAY "Buscando Informacion ... Por favor espere"  
           AT 19,14 ATTRIBUTE(REVERSE,BOLD)

  PREPARE busqueda1 FROM selec
  DECLARE busca1 CURSOR FOR busqueda1

  DISPLAY "                                        " AT 19,14
  DISPLAY "Reporte generandose ... Por favor espere"  
           AT 19,14 ATTRIBUTE(REVERSE)

  START REPORT list_comp TO "C:\\archivo"
  FOREACH busca1 INTO prt_comp.* 
     OUTPUT TO REPORT list_comp(prt_comp.*)
  END FOREACH
  FINISH REPORT list_comp 
RUN "type C:\\archivo > %USPRINT%" END FUNCTION

##### Funcion para crear el reporte requerido

REPORT list_comp(x)  
  DEFINE x RECORD
      cod_ca    LIKE cotb00022.cod_ca,
      nom_ca    LIKE cotb00022.nom_ca,  
      poliza    LIKE cotb00022.poliza
  END RECORD

  DEFINE comprimido_12_off,comprimido_12_on,comprimido_on,comprimido_off,
         doble_on,doble_off,negrillas_on,negrillas_off     CHAR(2),
         hora              CHAR(5)

   OUTPUT 
         LEFT MARGIN 6
         TOP MARGIN 1 
 
   ##### Creando formato de salida

     FORMAT
     PAGE HEADER
           LET negrillas_on      = ASCII 27, ASCII 71 
           LET negrillas_off     = ASCII 27, ASCII 72 
           LET doble_on          = ASCII 14 
           LET doble_off         = ASCII 20 
           LET comprimido_on     = ASCII 15
           LET comprimido_off    = ASCII 18
           LET comprimido_12_on  = ASCII 27, ASCII 77
           LET comprimido_12_off = ASCII 27, ASCII 80
           LET hora = time

           LET l = (78 - LENGTH(p_companias.nombre CLIPPED))/2
           PRINT COLUMN  1, Negrillas_on
           PRINT COLUMN  1, "coprrp022",
                 COLUMN  l, p_companias.nombre CLIPPED,
                 COLUMN 71, "Pag. ", pageno using "###"
           PRINT COLUMN 16, "             Sistema de Compras",
                 COLUMN 71, today using "dd/mm/yy"
           PRINT COLUMN 16, "     Maestra de Companias Aseguradoras",
                 COLUMN 74, hora
           SKIP 1 LINES
 
           PRINT COLUMN   1, "----------------------------------------",
                             "--------------------------------------"
           PRINT COLUMN  8, "CODIGO", 
                 COLUMN 19, "COMPANIA",
                 COLUMN 53, "POLIZA"
           PRINT COLUMN   1, "----------------------------------------",
                             "--------------------------------------"
           PRINT negrillas_off

     ON EVERY ROW

           PRINT COLUMN  8, x.cod_ca, 
                 COLUMN 19, x.nom_ca clipped,
                 COLUMN 53, x.poliza 
END REPORT