{
==============================================================================
    PROGRAMA    : CGPRRP024
    SISTEMA     : Sistema de Contabilidad General
    Objetivo    : Documentos o transaccion descuadradas
    PROGRAMADOR : Tadeo A. Ferreras
    FECHA       : Oct. 05, 1993
==============================================================================
}
GLOBALS
  "cgprgb000.4gl"

 DEFINE datos_1 RECORD
   ref          CHAR(14),
   valor        DECIMAL(12,2)
 END RECORD

 DEFINE diario RECORD
   ref          CHAR(14),
   fecha        DATE,
   tipo         SMALLINT,
   cuenta_no    CHAR(8),
   descripcion  CHAR(30),
   detalle1     CHAR(30),
   detalle2     CHAR(30),
   debito       DECIMAL(12,2),
   credito      DECIMAL(12,2),
   status_t     CHAR(1),
   orden        INTEGER
  END RECORD
  DEFINE fecha_inicial,fecha_final DATE
   
  FUNCTION cgprrp024()
  LET int_flag = FALSE

  OPTIONS
     FORM LINE 8
     
   OPEN FORM cgfmrp024 FROM "cgfmrp024"
   DISPLAY FORM cgfmrp024
   DISPLAY "cgprrp024" AT 4,3
   DISPLAY "Chequeo Cuadre de Transacciones" AT 6,24 

   LET tipo_papel = 1
   CALL msgrp000(tipo_papel)

   INPUT BY NAME fecha_inicial,fecha_final

    AFTER FIELD fecha_inicial
     IF fecha_inicial IS NULL THEN
        LET numero_msg = 16
        CALL msg(numero_msg)
        NEXT FIELD fecha_inicial
     END IF

     AFTER FIELD fecha_final
      IF fecha_final IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD fecha_final
       END IF

       IF fecha_inicial > fecha_final THEN
          LET numero_msg = 51
          CALL msg(numero_msg)
          NEXT FIELD fecha_inicial
        END IF
    END INPUT
    
    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
     END IF

     CONSTRUCT criterio ON a.ref FROM ref 

     IF int_flag THEN
        LET numero_msg = 2
        CALL msg(numero_msg)
        LET int_flag = FALSE
        RETURN
      END IF

      LET selec = 
       "SELECT a.ref,SUM(a.debito - a.credito) ",
       "FROM cgtb00004 a ",
       "WHERE ",criterio CLIPPED,
       "  AND a.status_t IS NULL AND a.fecha BETWEEN ? AND ? ",
       "GROUP BY 1 HAVING SUM(a.debito-a.credito) <> 0 " 

       DISPLAY "<<<Buscando Informacion... Espere por Favor>>>" AT 19,14
       ATTRIBUTE(blue)

       PREPARE comando FROM selec
       DECLARE busco CURSOR FOR comando
       OPEN busco USING fecha_inicial,fecha_final

       START REPORT trans_e TO "C:\\archivo"
       DISPLAY "<<<Reporte Generandose...  Espere por Favor>>>" AT 19,14
       ATTRIBUTE(blue)
                  
       WHILE status != NOTFOUND
       FETCH busco INTO datos_1.*
            IF STATUS = NOTFOUND THEN
               EXIT WHILE
            END IF

            IF int_flag THEN
                LET numero_msg = 2
                CALL msg(numero_msg)
                LET int_flag = FALSE
                RETURN    
            END IF 

  DECLARE busca1 CURSOR FOR
  SELECT  b.ref,b.fecha,b.tipo,b.cuenta_no,c.descripcion, 
          b.detalle_1,b.detalle_2,b.debito,b.credito,b.status_t,b.rowid  
  INTO diario.ref,diario.fecha,diario.tipo,diario.cuenta_no,diario.descripcion,
       diario.detalle1,diario.detalle2,diario.debito,diario.credito,
       diario.status_t,diario.orden
  FROM cgtb00004 b,cgtb00001 c 
  WHERE b.ref = datos_1.ref AND b.cuenta_no = c.cuenta_no AND 
        b.status_t IS NULL AND b.fecha BETWEEN fecha_inicial AND fecha_final 

        FOREACH busca1
          IF int_flag THEN
             LET numero_msg = 2
             CALL msg(numero_msg)
             LET int_flag = FALSE
             RETURN
           END IF

           OUTPUT TO REPORT trans_e(diario.*,fecha_inicial,fecha_final)
        END FOREACH
      END WHILE
      FINISH REPORT trans_e
      CLEAR SCREEN
     RUN "type C:\\archivo > %USPRINT%" END FUNCTION

REPORT trans_e(x,fecha1,fecha2)
   DEFINE x RECORD
     ref          CHAR(14),
     fecha        DATE,
     tipo         SMALLINT,
     cuenta_no    CHAR(8),
     descripcion  CHAR(30),
     detalle1     CHAR(30),
     detalle2     CHAR(30),
     debito       DECIMAL(12,2),
     credito      DECIMAL(12,2),
     status_t     CHAR(1),
     orden        INTEGER
   END RECORD
   DEFINE fecha1,fecha2 DATE
   DEFINE total1,total2,total3,total4,total5,total6,total7,total8,total9,
          debito,credito,balance DECIMAL(12,2)

## DEFINICION DE LAS VARIABLES DE IMPRESION
    DEFINE descripcion1 CHAR(30)
    DEFINE doble_on CHAR(3)
    DEFINE doble_off CHAR(3)
    DEFINE negrillas_on CHAR(6)
    DEFINE negrillas_off CHAR(6)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(3) 
    DEFINE doce CHAR(3)
    DEFINE normal CHAR(3)
    DEFINE hora CHAR(5)

    OUTPUT
## DEFINICION DE LOS MARGENES DE IMPRESION
     TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 3

     ORDER BY x.ref,x.orden 
    FORMAT
      PAGE HEADER


        LET doble_on =  ASCII 14
        LET doble_off = ASCII 20
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET comp_on = ASCII 15
        LET comp_off = ASCII 18
        LET doce = ASCII 27, ASCII 77
        LET normal = ASCII 27, ASCII 80

        LET hora = time

        LET l = (93 - LENGTH(p_compania.nombre CLIPPED))/2
## AQUI SE INDICA LA IMPRESION DE LOS ENCABEZADOS
           PRINT negrillas_on
           PRINT COLUMN   1, comp_on,
                 COLUMN   2, "cgprrp024",
                 COLUMN  15, doble_on,
                 COLUMN  l, p_compania.nombre CLIPPED,
                 COLUMN  65, negrillas_off,
                 COLUMN  66, doble_off,
                 COLUMN  83, "Pag. ",pageno using "###"
        LET l = (145 - LENGTH("Sistema de Contabilidad General"))/2
           PRINT COLUMN  l, "Sistema de Contabilidad General", 
                 COLUMN 124, today using "dd/mm/yyyy"
        LET l = (145 - LENGTH("Chequeo Cuadre de Transacciones"))/2
           PRINT COLUMN  l, "Chequeo Cuadre de Transacciones",
                 COLUMN 127, hora
        LET l = (145 - LENGTH("ffffffffffffffffffffffff"))/2
           PRINT COLUMN  l, "Del ",fecha1 USING "dd/mm/yyyy"," Al ",
                                    fecha2 USING "dd/mm/yyyy"

        PRINT COLUMN 1, "---------------------------------------------------",
                        "---------------------------------------------------",
                        "-----------------------------"

           PRINT COLUMN  1, "Documento",
                 COLUMN 16, "Cuenta_no",
                 COLUMN 26, "Fecha",   
                 COLUMN 35, "Detalle",
                 COLUMN 75, "Debito",
                 COLUMN 95, "Credito",
                 COLUMN 109,"Diferencia"

        PRINT COLUMN 1, "----------------------------------------------------",
                        "----------------------------------------------------" ,
                        "-----------------------------"

    skip 1 line
## AQUI SE INDICA LA IMPRESION DEL DETALLE

     BEFORE GROUP OF x.ref
         LET total1 = 0
         LET total2 = 0
         LET balance = 0
         IF balance is null THEN
            LET balance = 0
         END IF
         PRINT COLUMN   1,x.ref CLIPPED;
               
      ON EVERY ROW
         IF x.debito IS NULL THEN
            LET x.debito = 0
         END IF
         IF x.credito IS NULL THEN
            LET x.credito = 0
         END IF

         LET total1 = total1 + x.debito
         LET total2 = total2 + x.credito
         LET balance = balance + (x.debito - x.credito)

         PRINT COLUMN  16,x.cuenta_no CLIPPED,
               COLUMN  26,x.fecha USING "dd/mm/yyyy",
               COLUMN  35,x.detalle1 CLIPPED," ",
               COLUMN  68,x.debito USING "###,###,###.##",
               COLUMN  90,x.credito USING "###,###,###.##" ,
               COLUMN 110, balance USING "(((,(((,((#.##)"

         IF x.detalle2 is not null THEN
            PRINT COLUMN 32, x.detalle2 CLIPPED
         END IF

          AFTER GROUP OF x.ref      

         IF total3 IS NULL THEN
            LET total3 = 0
         END IF
         IF total4 IS NULL THEN
            LET total4 = 0
         END IF
         IF total5 IS NULL THEN
            LET total5 = 0
         END IF

                LET total3 = total3 + total1
                LET total4 = total4 + total2
                LET total5 = total5 + balance

          PRINT COLUMN  68,"--------------",
                COLUMN  90,"--------------",
                COLUMN 110,"--------------"

          PRINT COLUMN   1,"Total Transaccion -->",
                COLUMN  68,total1 USING "###,###,###.##", 
                COLUMN  90,total2 USING "###,###,###.##",
                COLUMN 110,balance USING "(((,(((,(((.##)"

          SKIP 1 LINE

          ON LAST ROW 
          PRINT COLUMN  68,"==============",
                COLUMN  90,"==============",
                COLUMN 110,"=============="

          PRINT COLUMN   1, "Total Gral. -->",
                COLUMN  68,total3 USING "###,###,###.##", 
                COLUMN  90,total4 USING "###,###,###.##",
                COLUMN 110,total5 USING "(((,(((,(((.##)"

          PRINT COLUMN  68,"==============",
                COLUMN  90,"==============",
                COLUMN 110,"=============="

            PRINT COLUMN 1,comp_off

                LET total3 = 0
                LET total4 = 0
                LET total5 = 0
                LET total1 = 0
                LET total2 = 0
                LET balance= 0

   END REPORT