{
==============================================================================
    PROGRAMA    : CGPRRP014
    SISTEMA     : Sistema de Contabilidad General
    Objetivo    : Imprimir el mayor general Por Referencia
    COMENTARIOS : Este reporte tiene una busqueda de todas las referencias
                  menores a la fecha final del reporte porque los balances
                  de las referencias que no entran en el periodo contable
                  del mes no trae los balances iniciales o resumenes.
    PROGRAMADOR : Juan Soto
    FECHA       : Enero 25, 1994
    MODIFICACION: Se modifico el QUERY para que busque del catalogo solo las
                  cuentas que sean nivel 3, analitica,con auxiliares,referencia
    MODIFICADO P: Juan F. Soto
    FECHA MOD   : Junio 7, 1995.
==============================================================================
}
GLOBALS
  "cgprgb000.4gl"
 DEFINE mayor RECORD
   cod_aux      SMALLINT,
   cod_sec      SMALLINT,
   fecha        DATE,
   tipo         SMALLINT,
   ref          CHAR(14),
   cuenta_no    CHAR(8),
   descripcion  CHAR(30),
   num_doc      CHAR(12),
   detalle1     CHAR(30),
   detalle2     CHAR(30),
   debito       DECIMAL(12,2),
   credito      DECIMAL(12,2),
   clave        CHAR(6)
  END RECORD
  DEFINE fecha_inicial,fecha_final DATE
 MAIN
 DEFER INTERRUPT
 CALL ARG_VAL(1) RETURNING usuarios
 CALL ARG_VAL(2) RETURNING clave
 CALL ARG_VAL(3) RETURNING impresor
  
  CONNECT to "smarmotech"  USER  usuarios USING clave
 SELECT a.* INTO p_compania.* FROM companias a

 CALL cgprrp014()
END MAIN

  FUNCTION cgprrp014()
  LET int_flag = FALSE

  OPTIONS
     FORM LINE 8
     
   OPEN FORM cgfmrp014 FROM "cgfmrp014"
   DISPLAY FORM cgfmrp014
   DISPLAY "cgprrp014" AT 4,3 
   DISPLAY "MAYOR GENERAL DETALLADO X REFERENCIA" AT 6,22 

   LET tipo_papel = 1
   CALL msgrp000(tipo_papel)

   INPUT BY NAME fecha_inicial,fecha_final

    AFTER FIELD fecha_inicial
     IF fecha_inicial IS NULL THEN
        LET numero_msg = 16
        CALL msg(numero_msg)
        NEXT FIELD fecha_inicial
     END IF

     AFTER FIELD fecha_final
      IF fecha_final IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD fecha_final
       END IF

       IF fecha_inicial > fecha_final THEN
          LET numero_msg = 51
          CALL msg(numero_msg)
          NEXT FIELD fecha_inicial
        END IF
    END INPUT
    
    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
     END IF

     CONSTRUCT criterio ON a.cuenta_no,a.num_doc,a.cod_aux,a.cod_Sec
                         FROM cuenta_no,cod_sp,cod_sp_Sec,num_doc

     IF int_flag THEN
        LET numero_msg = 2
        CALL msg(numero_msg)
        LET int_flag = FALSE
        RETURN
      END IF

# Buscando las referencias de las cuentas que tienen resumenes pendientes
# a una fecha determinada y movimientos a la fecha
      LET selec ="SELECT a.cod_aux,a.cod_sec,a.fecha,a.tipo,a.ref, ",
                 "a.cuenta_no,b.descripcion,a.num_doc,a.detalle_1, ",
                 "a.detalle_2,a.debito,a.credito ",
                 "FROM cgtb00004 a,cgtb00001 b ",
                 "WHERE a.cuenta_no = b.cuenta_no AND a.status_t IS NULL AND ",
                 "      ((b.nivel = 3 and b.analitico = 'S' and b.cata = 'S'",
                 " and  b.ref = 'S') or ",
                 "      (b.nivel = 3 and b.analitico = 'S' and b.ref = 'S')) ",
                 " and ",
                 "      a.fecha <= ? AND (a.cod_sec is not null or  ",
                 "      a.num_doc is not null) and ",
                  criterio CLIPPED

       DISPLAY "<<<Buscando Informacion... Espere por Favor>>>" AT 19,14
       ATTRIBUTE(blue)

      CALL defecto(usuarios,clave,impresor) RETURNING imprime,negrilla_on,negrillas_of,
                                                       doble_on,doble_off,comp_on,comp_off,
                                                       doce,normal,archivo,copia

                                                       
       START REPORT mayor_ref TO archivo
 
       PREPARE comando FROM selec
       DECLARE busco CURSOR FOR comando
       OPEN busco USING fecha_final

       
       DISPLAY "<<<Reporte Generandose...  Espere por Favor>>>" AT 19,14
       ATTRIBUTE(blue)
                  
       WHILE status != NOTFOUND
       FETCH busco INTO mayor.*
            IF STATUS = NOTFOUND THEN
               EXIT WHILE
            END IF

            IF int_flag THEN
                LET numero_msg = 2
                CALL msg(numero_msg)
                LET int_flag = FALSE
                FINISH REPORT mayor_ref
                EXIT WHILE
            END IF 

          LET mayor.clave = mayor.cod_aux using "&&",mayor.cod_sec using "&&&&"
          OUTPUT TO REPORT mayor_ref(mayor.*,fecha_inicial,fecha_final)
         END WHILE
         FINISH REPORT mayor_ref
         CLEAR SCREEN
      RUN imprime
 END FUNCTION

REPORT mayor_ref(x,fecha1,fecha2)
   DEFINE x RECORD
     cod_aux      SMALLINT,
     cod_sec      SMALLINT,
     fecha        DATE,
     tipo         SMALLINT,
     ref          CHAR(14),
     cuenta_no    CHAR(8),
     descripcion  CHAR(30),
     num_doc      CHAR(12),
     detalle1     CHAR(30),
     detalle2     CHAR(30),
     debito       DECIMAL(12,2),
     credito      DECIMAL(12,2),
     clave        CHAR(6)
   END RECORD
   DEFINE fecha1,fecha2 DATE
   DEFINE total1,total2,total3,total4,total5,total6,debito,credito,balance,
          balance_final DECIMAL(12,2)

   DEFINE nosale CHAR(1)
## DEFINICION DE LAS VARIABLES DE IMPRESION
    DEFINE doble_on CHAR(2)
    DEFINE doble_off CHAR(2)
    DEFINE negrillas_on CHAR(2)
    DEFINE negrillas_off CHAR(2)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(2)
    DEFINE normal CHAR(2)
    DEFINE hora CHAR(5)

    DEFINE nombre1,nombre2 CHAR(30)
    OUTPUT
## DEFINICION DE LOS MARGENES DE IMPRESION
     TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 3
    ORDER BY x.cuenta_no,x.clave,x.num_doc

    FORMAT
      PAGE HEADER

        LET doble_on =  ASCII 14
        LET doble_off = ASCII 20
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET comp_on = ASCII 15
        LET comp_off = ASCII 18
        LET doce = ASCII 27, ASCII 77
        LET normal = ASCII 27, ASCII 80

        LET hora = time

## AQUI SE INDICA LA IMPRESION DE LOS ENCABEZADOS
           PRINT COLUMN   1, comp_on,negrillas_on
           LET l = (131 - LENGTH(p_compania.nombre CLIPPED))/2
           PRINT COLUMN   1, "cgprrp014",
                 COLUMN   l, p_compania.nombre CLIPPED,
                 COLUMN 124, "Pag. ",pageno using "###"
           PRINT COLUMN  42, "       Sistema de Contabilidad General", 
                 COLUMN 124, today using "dd/mm/yyyy"
           PRINT COLUMN  42, "    Mayor General Detallado Por Referencia",
                 COLUMN 127, hora
           SKIP 1 LINE
           PRINT COLUMN   1, "Fecha: Del ", fecha1 USING "dd/mm/yyyy",
                                    " Al ", fecha2 USING "dd/mm/yyyy"

           PRINT COLUMN 1, "--------------------------------------------------",
                           "--------------------------------------------------",
                           "-------------------------------"

           PRINT COLUMN  1, "C O D.",
                 COLUMN 19, "D e s c r i p c i o n", 
                 COLUMN 104,"B a l a n c e"

           PRINT COLUMN 1, "--------------------------------------------------",
                           "--------------------------------------------------",
                           "-------------------------------"

           PRINT COLUMN  65, negrillas_off
## AQUI SE INDICA LA IMPRESION DEL DETALLE
      BEFORE GROUP OF x.cuenta_no
         PRINT COLUMN  1, negrillas_on
         PRINT COLUMN  2, "Cuenta No. ",x.cuenta_no CLIPPED,"  ",
                          x.descripcion CLIPPED
         PRINT COLUMN  1, negrillas_off
   
         LET total3 = 0
         LET total4 = 0
       BEFORE GROUP OF x.clave
         
         LET total5 = 0
         LET total6 = 0
         PRINT COLUMN  1, negrillas_on
         PRINT COLUMN  2, "Auxiliar   ",x.cod_aux using "&&","-",
                                        x.cod_sec using "&&&&";
        IF x.cod_aux = 1 THEN
          SELECT nom1_emp,apell1_emp INTO nombre1,nombre2 FROM adtb00003
          WHERE num_emp = x.cod_sec
          PRINT " ",nombre1 clipped," ",nombre2,negrillas_off

        ELSE
          LET nombre1 = null
          LET nombre2 = null
          SELECT nom_sp INTO nombre2 FROM cotb00001
          WHERE cod_sp  = x.cod_aux and
                cod_sp_sec = x.cod_sec
          PRINT " ",nombre2 #,negrillas_off

        END IF
        SKIP 1 LINE
        
           PRINT COLUMN  1, "Fecha",
                 COLUMN 11, "Refer.",
                 COLUMN 24, "Documento",   
                 COLUMN 38, "Detalle",
                 COLUMN 80, "DR",
                 COLUMN 95, "CR",
                 COLUMN 110,"Balance"
          PRINT COLUMN   1,negrillas_off

       BEFORE GROUP OF x.num_doc
         LET balance = 0

         SELECT SUM(b.debito - b.credito) INTO balance FROM cgtb00004 b
         WHERE b.cuenta_no = x.cuenta_no AND b.num_doc = x.num_doc
         AND   b.status_t IS NULL AND b.fecha < fecha1

         SELECT SUM(b.debito - b.credito) INTO balance_final
         FROM cgtb00004 b
         WHERE b.cuenta_no = x.cuenta_no AND b.num_doc = x.num_doc
         AND   b.status_t IS NULL AND b.fecha < fecha2

         IF balance_final IS NULL THEN
            LET balance_final = 0
         END IF
         LET nosale = "S"
         IF balance = 0 THEN
            LET nosale = "N"
         END IF
         IF balance IS NULL THEN
            LET balance = 0
         END IF
        IF balance >= 0 THEN
         LET total1 = balance 
         LET total2 = 0
        ELSE
         LET total2 = balance 
         LET total1 = 0
        END IF
         IF balance != 0 OR balance_final != 0 THEN
            IF nosale = "S" THEN
               PRINT COLUMN   1,fecha1-1 USING "dd/mm/yyyy",
                     COLUMN  11,x.num_doc,
                     COLUMN  27,"Resumen"," ","Balance al Cierre", 
                     COLUMN  70,total1  USING "#,###,###,###.##",
                     COLUMN  88,total2  USING "#,###,###,###.##",
                     COLUMN 108,balance USING "(,(((,(((,(((.##)"
            END IF
         END IF

      ON EVERY ROW
        IF x.fecha >= fecha1 and
           x.fecha <= fecha2 THEN
         IF x.debito IS NULL THEN
            LET x.debito = 0
         END IF
         IF x.credito IS NULL THEN
            LET x.credito = 0
         END IF

         LET total1 = total1 + x.debito
         LET total2 = total2 + x.credito
         LET balance = balance + (x.debito - x.credito)

         PRINT COLUMN   1,x.fecha USING "dd/mm/yyyy",
               COLUMN  11, x.num_doc,
               COLUMN  24,x.ref CLIPPED,
               COLUMN  40,x.detalle1 CLIPPED," ",
               COLUMN  70,x.debito USING "#,###,###,###.##",
               COLUMN  88,x.credito USING "#,###,###,###.##",
               COLUMN 108,balance USING "(,(((,(((,(((.##)"

        IF x.detalle2 is not null THEN
           PRINT  COLUMN 27, x.detalle2 CLIPPED
        END IF
        END IF

        AFTER GROUP OF x.num_doc
         IF balance != 0 OR balance_final != 0 THEN
          PRINT COLUMN   1,negrillas_on
          PRINT COLUMN  70,"----------------",
                COLUMN  88,"----------------",
                COLUMN 108,"----------------"
          PRINT COLUMN   1, "Total Referencia   -->",
                COLUMN  70,total1 USING "#,###,###,###.##", 
                COLUMN  88,total2 USING "#,###,###,###.##",
                COLUMN 108,balance USING "(,(((,(((,(((.##)"
          PRINT COLUMN   1,negrillas_off

           LET total3 = total3 + total1
           LET total4 = total4 + total2
           LET total5 = total5 + total1   
           LET total6 = total6 + total2   
         END IF
       
        AFTER GROUP OF x.clave
          IF balance != 0 OR balance_final != 0 THEN
          PRINT COLUMN   1,negrillas_on
          PRINT COLUMN  72,"----------------",
                COLUMN  90,"----------------",
                COLUMN 110,"----------------"
          PRINT COLUMN   1, "Total Auxiliar     -->",
                COLUMN  68,total5 USING "#,###,###,###.##", 
                COLUMN  90,total6 USING "#,###,###,###.##",
                COLUMN 110,total5-total6 USING "(,(((,(((,(((.##)"
          PRINT COLUMN   1,negrillas_off
          END IF

          AFTER GROUP OF x.cuenta_no
          PRINT COLUMN   1,negrillas_on 
          PRINT COLUMN  68,"----------------",
                COLUMN  90,"----------------",
                COLUMN 110,"----------------"
          PRINT COLUMN   1, "Total cuenta -->",
                COLUMN  68,total3 USING "#,###,###,###.##", 
                COLUMN  90,total4 USING "#,###,###,###.##",
                COLUMN 110,total3 - total4 USING "(,(((,(((,(((.##)"
          PRINT COLUMN  68,"================",
                COLUMN  90,"================",
                COLUMN 110,"================"
          
          PRINT COLUMN   1,negrillas_off

         ON LAST ROW
            PRINT COLUMN 1,comp_off

END REPORT