{
==============================================================================
    PROGRAMA    : CGPRRP005
    SISTEMA     : Sistema de Contabilidad General
    Objetivo    : Imprimir el Diario general
    PROGRAMADOR : Tadeo A. Ferreras
    FECHA       : Oct. 05, 1993
==============================================================================
}
GLOBALS
  "cgprgb000.4gl"
 DEFINE diario RECORD
   fecha        DATE,
   tipo         SMALLINT,
   ref          CHAR(14),
   cuenta_no    CHAR(8),
   descripcion  CHAR(30),
   detalle1     CHAR(30),
   detalle2     CHAR(30),
   debito       DECIMAL(12,2),
   credito      DECIMAL(12,2)
 END RECORD
 DEFINE fecha_inicial,fecha_final DATE
 DEFINE t_debito,t_credito,t_balance DECIMAL(12,2)
 DEFINE p_ano CHAR(4)
 DEFINE p_mes SMALLINT
MAIN
 DEFER INTERRUPT
 CALL ARG_VAL(1) RETURNING usuarios
 CALL ARG_VAL(2) RETURNING clave
 CALL ARG_VAL(3) RETURNING impresor
  
  CONNECT to "smarmotech"  USER  usuarios USING clave
 SELECT a.* INTO p_compania.* FROM companias a

 CALL cgprrp005()
END MAIN

 FUNCTION cgprrp005()
  LET int_flag = FALSE

  OPTIONS
     FORM LINE 8
     
     OPEN FORM cgfmrp005 FROM "cgfmrp005"
     DISPLAY FORM cgfmrp005
     DISPLAY "cgprrp005" AT 4,3
     DISPLAY "     Diario General    " AT 6,28 

     LET tipo_papel = 1
     CALL msgrp000(tipo_papel)

     INPUT BY NAME p_ano,p_mes

      AFTER FIELD p_ano
       IF p_ano IS NULL THEN
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD p_ano
       END IF

     AFTER FIELD p_mes
      IF p_mes IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD p_mes
      END IF

  END INPUT
    
  IF int_flag THEN
     LET numero_msg = 2
     CALL msg(numero_msg)
     LET int_flag = FALSE
     RETURN
  END IF

     SELECT fecha_inicio,fecha_corte INTO fecha_inicial,fecha_final
     FROM prdtable WHERE ano = p_ano and mes = p_mes

     CONSTRUCT criterio ON a.cuenta_no FROM cuenta_no

     IF int_flag THEN
        LET numero_msg = 2
        CALL msg(numero_msg)
        LET int_flag = FALSE
        RETURN
     END IF

      LET selec = 
         "SELECT a.fecha,a.tipo,a.ref,a.cuenta_no,b.descripcion,a.detalle_1, ",
         "       a.detalle_2,a.debito,a.credito  ",
         "FROM cgtb00004 a,cgtb00001 b ",
         "WHERE (a.fecha BETWEEN ? AND ? AND a.cuenta_no = b.cuenta_no AND ",
         "       a.status_t is null) AND ",criterio CLIPPED," ORDER BY 4,1,3 "

       DISPLAY "<<<Buscando Informacion... Espere por Favor>>>" AT 19,14
       ATTRIBUTE(blue)

      CALL defecto(usuarios,clave,impresor) RETURNING imprime,negrilla_on,negrillas_of,
                                                       doble_on,doble_off,comp_on,comp_off,
                                                       doce,normal,archivo,copia

                                                       
       START REPORT diario_gral TO archivo
 
       PREPARE comando FROM selec
       DECLARE busco CURSOR FOR comando
       OPEN busco USING fecha_inicial,fecha_final

       
       DISPLAY "<<<Reporte Generandose...  Espere por Favor>>>" AT 19,14
       ATTRIBUTE(blue)
                  
       WHILE status != NOTFOUND
       FETCH busco INTO diario.*
            IF STATUS = NOTFOUND THEN
               EXIT WHILE
            END IF

            IF int_flag THEN
                LET numero_msg = 2
                CALL msg(numero_msg)
                LET int_flag = FALSE
                FINISH REPORT diario_gral
                EXIT WHILE
            END IF 

          OUTPUT TO REPORT diario_gral(diario.*,fecha_inicial,fecha_final)
         END WHILE
         FINISH REPORT diario_gral
         DISPLAY BY NAME t_debito,t_credito,t_balance  
LABEL atras:
         PROMPT "Desea Imprimir Este Reporte [S/N]... ? " FOR CHAR opcion
         LET opcion = upshift(opcion)

         IF (opcion != "S" AND opcion != "N") OR opcion IS NULL THEN
            LET numero_msg =-1301
            CALL msg(numero_msg)
            GOTO atras
         END IF
         IF opcion = "S" THEN
            RUN imprime
         END IF
        
         CLEAR SCREEN
       END FUNCTION

REPORT diario_gral(x,fecha1,fecha2)
   DEFINE x RECORD
     fecha        DATE,
     tipo         SMALLINT,
     ref          CHAR(14),
     cuenta_no    CHAR(8),
     descripcion  CHAR(30),
     detalle1     CHAR(30),
     detalle2     CHAR(30),
     debito       DECIMAL(12,2),
     credito      DECIMAL(12,2)
   END RECORD
   DEFINE fecha1,fecha2 DATE
   DEFINE total1,total2,total3,total4,total5,total6,debito,credito,balance
          DECIMAL(12,2)

## DEFINICION DE LAS VARIABLES DE IMPRESION
    DEFINE doble_on CHAR(2)
    DEFINE doble_off CHAR(2)
    DEFINE negrillas_on CHAR(2)
    DEFINE negrillas_off CHAR(2)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(2)
    DEFINE normal CHAR(2)
    DEFINE hora CHAR(5)

    OUTPUT
## DEFINICION DE LOS MARGENES DE IMPRESION
     TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 3

     #ORDER BY x.cuenta_no,x.ref
    FORMAT
      PAGE HEADER

        
        LET doble_on =  ASCII 14
        LET doble_off = ASCII 20
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET comp_on = ASCII 15
        LET comp_off = ASCII 18
        LET doce = ASCII 27, ASCII 77
        LET normal = ASCII 27, ASCII 80
        LET hora = time
## AQUI SE INDICA LA IMPRESION DE LOS ENCABEZADOS
           LET l = (125 - LENGTH(p_compania.nombre CLIPPED))/2
           PRINT COLUMN   1, comp_on,negrillas_on
           PRINT COLUMN   1, "cgprrp005",
                 COLUMN  l,p_compania.nombre CLIPPED,
                 COLUMN 124, "Pag. ",pageno using "###"
           LET l = (125 - LENGTH("SISTEMA DE CONTABILIDAD GENERAL"))/2
           PRINT COLUMN  l, "SISTEMA DE CONTABILIDAD GENERAL", 
                 COLUMN 124, today using "dd/mm/yy"

           LET l = (125 - LENGTH("DIARIO GENERAL"))/2
           PRINT COLUMN  l, "DIARIO GENERAL",
                 COLUMN 127, hora
           LET l = (125 - LENGTH("ffffffffffffffffffffffff"))/2
           PRINT COLUMN  l, "Del ",fecha1 USING "dd/mm/yy"," Al ",
                                    fecha2 USING "dd/mm/yy"

        PRINT COLUMN 1, "---------------------------------------------------",
                        "---------------------------------------------------",
                        "-----------------------------"

           PRINT COLUMN  1, "FECHA",
                 COLUMN 11, "DOCUMENTO",   
                 COLUMN 27, "DETALLE",
                 COLUMN 75, "DEBITO",
                 COLUMN 95, "CREDITO",
                 COLUMN 115,"BALANCE"

        PRINT COLUMN 1, "----------------------------------------------------",
                        "----------------------------------------------------" ,
                        "-----------------------------"

    skip 1 line
## AQUI SE INDICA LA IMPRESION DEL DETALLE
      BEFORE GROUP OF x.cuenta_no
         PRINT COLUMN  1, negrillas_on
         PRINT COLUMN  2, "Cuenta No. ",x.cuenta_no CLIPPED,"  ",
                          x.descripcion CLIPPED
         PRINT COLUMN  1, negrillas_off

         LET total1 = 0
         LET total2 = 0
         LET balance = 0
         SELECT sum(a.debito-a.credito) INTO balance FROM cgtb00004 a
         WHERE a.cuenta_no = x.cuenta_no AND a.fecha < fecha1 AND 
               a.status_t IS NULL

         IF balance is null THEN
            LET balance = 0
         END IF
         PRINT COLUMN   2,"BALANCE INICIAL ",
               COLUMN 110,balance using "((((,(((,((#.##)"

      ON EVERY ROW
         IF x.debito IS NULL THEN
            LET x.debito = 0
         END IF
         IF x.credito IS NULL THEN
            LET x.credito = 0
         END IF

         LET total1 = total1 + x.debito
         LET total2 = total2 + x.credito
         LET balance = balance + (x.debito - x.credito)

         PRINT COLUMN   1,x.fecha USING "dd/mm/yy",
               COLUMN  11,x.ref CLIPPED,
               COLUMN  27,x.detalle1 CLIPPED," ",
               COLUMN  68,x.debito USING "###,###,###.##",
               COLUMN  90,x.credito USING "###,###,###.##" ,
               COLUMN 110, balance USING "((((,(((,((#.##)"

         IF x.detalle2 is not null THEN
            PRINT COLUMN 27, x.detalle2 CLIPPED
         END IF

          AFTER GROUP OF x.cuenta_no

          PRINT COLUMN  68,"--------------",
                COLUMN  90,"--------------",
                COLUMN 110,"--------------"

          PRINT COLUMN   1,"Total Cuenta -->",
                COLUMN  68, GROUP SUM(x.debito) USING "###,###,###.##", 
                COLUMN  90, GROUP SUM(x.credito) USING "###,###,###.##",
                COLUMN 110, balance USING "((((,(((,(((.##)"

                IF total3 IS NULL THEN
                   LET total3 = 0
                END IF

                IF total4 IS NULL THEN
                   LET total4 = 0
                END IF

                IF total5 is null THEN
                   LET total5 = 0
                END IF

                LET total3 = total3 + total1
                LET total4 = total4 + total2
                LET total5 = total5 + balance

          SKIP 1 LINE
          ON LAST ROW
          PRINT COLUMN  68,"==============",
                COLUMN  90,"==============",
                COLUMN 110,"=============="
          PRINT COLUMN   1, "Total General -->",
                COLUMN  68, SUM(x.debito) USING "###,###,###.##", 
                COLUMN  90, SUM(x.credito) USING "###,###,###.##",
                COLUMN 110,total5 USING "((((,(((,(((.##)"

          LET t_debito = total3
          LET t_credito = total4
          LET t_balance = total5
          PRINT COLUMN  68,"==============",
                COLUMN  90,"==============",
                COLUMN 110,"==============",
                comp_off
                LET total3 = 0
                LET total4 = 0
                LET total5 = 0
                LET total1 = 0
                LET total2 = 0
                LET balance= 0


   END REPORT