{
----------------------------------------------------------------------------
 FORMULARIO        : ADFMMT022
 OBJETIVO          : Pantalla para actualizar las informaciones comunes de
                     la accion de personal y la maestra de empleados.
                     Es utilizada por: ADPRMT022
 PROGRAMADOR       : Ing. Betania Guerrero Perez
 FECHA REALIZACION : Noviembre 19, 1993
----------------------------------------------------------------------------
}
SCHEMA smarmotech 
 
TOOLBAR
  ITEM nuevo (TEXT="Nuevo", IMAGE="new", COMMENT="Adicionar Registos")
  ITEM buscar (TEXT="Buscar", IMAGE="find", COMMENT="Buscar Regustros")  SEPARATOR
  ITEM salir (TEXT="Salir", COMMENT = "Salir del Programa", IMAGE="quit") 
END
 
screen size 24 by 80
{
Ficha No.[f000]-[f001]-[f2]-[f3]
[b                                                                 ]
Puesto[l                             ] Plan [pl   ] [pn                   ] 
Depto.[m                             ] Monto Asegurado [ma            ]
Clase Emp.[ce   ]  Monto Seg. Dental [msd           ]NIS[nis              ]
Dir.[f004                      ] [f005] [f006           ] [f007           ]
Ced [f010       ]              Serie [f011  ]          Sexo [x][ tx       ]
Telefono [f008    ]            Fecha de Nacimiento [p         ] 
Nacionalidad [p1] [p2                           ]      Licencia [m1       ]
Estado Civil [a] [c       ]    Tipo de Sangre [f03]    Sueldo [s          ]  
Nomina[d] [d1         ]  Fecha de Entrada [fe        ]
Paga Seguro [z]       Codigo Seguro [c1  ][c2  ][c3   ] Cuenta No:[ca        ]
Depto. Corporativo [co   ]-[dc                             ]Med.[m12          ]
Dias P, Vacaciones [dp  ]M. Seg. Int.[seg1        ]Care [car         ]   
}
end
tables
adtb00007,adtb00003,
adtb00001,adtb00004
attributes
m12 = adtb00003.monto_Seg_med;
seg1= adtb00003.monto_seg_int;
car = adtb00003.monto_care;
nis = formonly.pnis,comments = "CODIGO IDENTIFICACION SEGURIDAD SOCIAL";
ca  = adtb00003.cuenta_no,comments = "No. de Cuenta para pagar nomina automatica";
f000 = adtb00003.num_emp,noentry;
f001 = adtb00003.departamento;
f2 = adtb00003.nivel_emp;
f3 = adtb00003.cod_puesto;
b = formonly.descrip1,noentry;
l = adtb00004.nom_puesto,noentry;
m = adtb00001.nom_dpto,noentry;
pl = formonly.cod_plan;
pn = formonly.m_descrip;
ma = formonly.monto_asegurado;
ce = formonly.clase_emp,upshift;
msd = formonly.monto_seg_dental;
f004 = adtb00003.calle,upshift;
f005 = adtb00003.casa_num,upshift;
f006 = adtb00003.barrio,upshift;
f007 = adtb00003.urbanizacion,upshift;
f010 = adtb00003.cedula,autonext,comments = "Digite la cedula del empleado";
f011 = adtb00003.serie,autonext,comments = "Digite la serie del empleado";
p = adtb00003.fech_nac,format = "dd/mm/yyyy",
 comments = "Digite la fecha de nacimiento del empleado";
p1 = adtb00003.cod_nac,autonext,
 comments = "Digite la nacionalidad del empleado";
p2 = adtb00007.nom_nac,noentry;
m1 = adtb00003.licencia,noentry;
f008 = adtb00003.telefono,upshift,picture="###-####";
a = adtb00003.estado_civil,upshift,include = ("S", "C"),
 comments = "Digite S = Soltero, C = Casado";
c = formonly.descr,noentry;
f03 = adtb00003.tipo_sangre,
 comments = "Digite el tipo de sangre del empleado";
s = adtb00003.sueldo_ac;
d = adtb00003.nomina, upshift,include = ("Q", "S", "V"),
 comments = "Digite Q = Quincenal, S = Semanal, V = Vendedor";
d1 = formonly.descrip,noentry;
fe = adtb00003.fech_efec,format = "dd/mm/yyyy";
x  = formonly.p_sexo type char,upshift,include= ("M","F"),comments =
     "Digite  M  Para SEXO MASCULINO   y  F Para FEMENINO";
tx = formonly.tipo_sexo,noentry;
c1 = adtb00003.cod_seg1;
c2 = adtb00003.cod_seg2;
c3 = adtb00003.cod_seg3;
z  = adtb00003.paga_seg,include=("S","N"),required,comments=
     "Digite S  si el empleado paga SEGURO,  N en caso contario";
co = formonly.dep_corp;
dc = formonly.nombre_depto,upshift,noentry;
dp = formonly.dias_pend;
end