{
------------------------------------------------------------------------
 FORMULARIO        : ADFMMT019
 OBJETIVO          : Pantalla para introducir las informaciones de los
                     adiestramientos que reciben los empleados. 
                     Es utilizada por: ADPRMT019
 PROGRAMADOR       : Ing. Betania Guerrero Perez
 FECHA REALIZACION : Junio 24, 1993  
------------------------------------------------------------------------
}
SCHEMA smarmotech

TOOLBAR
  ITEM nuevo (TEXT="Nuevo", IMAGE="new", COMMENT="Adicionar Registos")
  ITEM buscar (TEXT="Buscar", IMAGE="find", COMMENT="Buscar Regustros")  SEPARATOR
  ITEM salir (TEXT="Salir", COMMENT = "Salir del Programa", IMAGE="quit") 
END
LAYOUT (TEXT="FORMULARIO MANTENIMIENTO ADIESTRAMIENTO", STYLE="basic")
  
GRID
{
<G "EMPLEADO"                                                                       >
 Fecha     [f000      ]
 Ficha No. [f001]-[f002]-[f3]-[f4] [a                                         ]
 Profesion [f05]  [b                                     ]
 Tipo de Evento   [f ] [c                                ] 
           [f007                                                              ]

<G "ENTRENAMIENTO"                                                                  >
 Fecha del Evento   [f008      ]      Costo del Evento  [f009        ]
 Solicitante [f010]-[f011]-[f2]-[f5] [d                                       ]
 Supervisor  [f014]-[f015]-[f6]-[f7] [g                                       ]
 Aprobado    [f018]-[f019]-[f8]-[f1] [h                                       ]

<G                                                                                  >
 Estado del Registro [j]
 Usuario Creador     [f020            ]  Usuario Modificador  [f022           ]
 Fecha Creacion      [f021            ]  Fecha Modificacion   [f023            ]
}
end
tables
adtb00022,adtb00010
attributes
dateedit f000 = adtb00022.fecha,format = "dd/mm/yyyy";
f001 = adtb00022.num_emp,autonext,
 comments = "Digite la ficha del empleado o Presione Ctrl-W para busqueda";
f002 = adtb00022.departamento,noentry; 
f3 = adtb00022.nivel_emp,noentry;
f4 = adtb00022.cod_puesto,noentry; 
a = formonly.descrip1,noentry;
f05 = adtb00022.cod_prof,autonext,comments = 
"Digite el codigo de la profesion del empleado o Presione Ctrl-W para busqueda";
b = adtb00010.nom_prof,noentry;
f = adtb00022.evento,autonext,include = (1,2,3,4),
 comments = "Digite 1- Seminario 2- Curso 3- Taller 4- Conferencia";
c = formonly.descrip,noentry;
f007 = adtb00022.nom_evento,upshift,
 comments = "Digite el titulo del evento";
dateedit f008 = adtb00022.fech_evento,format = "dd/mm/yyyy",
 comments = "Digite la fecha del evento";
f009 = adtb00022.costo_evento,comments = "Digite el costo del evento";
f010 = adtb00022.num1_emp,autonext,
 comments = "Digite la ficha del empleado o Presione Ctrl-W para busqueda";
f011 = adtb00022.departamento1,noentry; 
f2 = adtb00022.nivel1_emp,noentry; 
f5 = adtb00022.cod1_puesto,noentry; 
d = formonly.descrip2,noentry;
f014 = adtb00022.num2_emp,autonext,
 comments = "Digite la ficha del empleado o Presione Ctrl-W para busqueda";
f015 = adtb00022.departamento2,noentry; 
f6 = adtb00022.nivel2_emp,noentry; 
f7 = adtb00022.cod2_puesto,noentry; 
g = formonly.descrip3,noentry;
f018 = adtb00022.num3_emp,autonext,
 comments = "Digite la ficha del empleado o Presione Ctrl-W para busqueda";
f019 = adtb00022.departamento3,noentry; 
f8 = adtb00022.nivel3_emp,noentry; 
f1 = adtb00022.cod3_puesto,noentry; 
h = formonly.descrip4,noentry;
j = adtb00022.status_t,noentry;
f020 = adtb00022.us_crea,noentry;
f021 = adtb00022.fech_crea,noentry;
f022 = adtb00022.us_mod,noentry;
f023 = adtb00022.fech_mod,noentry;
instructions
  delimiters " "
end