{
-------------------------------------------------------------------------------
PROGRAMA             :  ACPRRP001
OBJETIVO             :  Listado del control de activos Fijos
PROGRAMADOR          :  Tadeo A. Ferreras 
FECHA REALIZACION    :  Sept. 28, 1993 
-------------------------------------------------------------------------------
}
GLOBALS "acprgb000.4gl"
##### Registro para buscar la inforacion
    DEFINE act_fij RECORD
           codigo         SMALLINT,
           descripcion    CHAR(30),
           cuenta_no      CHAR(8),
           dcto_compra    CHAR(10) ,
           fech_compra    DATE, 
           vida_util      SMALLINT, 
           status_t       CHAR(1),
           valor_compra   DECIMAL(12,2),
           depr_acum      DECIMAL(12,2),
           valor_libro    DECIMAL(12,2),
           deprec         DECIMAL(12,2)
    END RECORD

#### Funcion que realiza la busqueda

MAIN
 DEFER INTERRUPT
 CALL ARG_VAL(1) RETURNING usuarios
 CALL ARG_VAL(2) RETURNING clave
 
 CONNECT to "smarmotech"  user  usuarios USING clave
 SELECT a.* INTO p_companias.* FROM companias a

 CALL acprrp001()
END MAIN

FUNCTION acprrp001()

#WHENEVER ERROR CONTINUE

 OPTIONS
   FORM LINE 8,
   ERROR LINE 23,
   COMMENT LINE 21

 OPEN FORM acfmrp001 FROM "acfmrp001"
 DISPLAY FORM acfmrp001
 #CALL pantalla()
 DISPLAY "acprrp001" AT 4,3
 DISPLAY "Control de Activos Fijos" AT 6,28

 LET tipo_papel = 1
 CALL msgrp000(tipo_papel)

 INPUT BY NAME p_ano1,p_mes1  

    BEFORE FIELD p_ano1
      LET p_ano1 = YEAR(TODAY)
      DISPLAY BY NAME p_ano1

    AFTER FIELD p_ano1       
      IF p_ano1 is null THEN  
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD p_ano1        
      END IF

    AFTER FIELD p_mes1       
      IF p_mes1 is null THEN  
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD p_mes1        
      END IF

      SELECT  CONVERT(VARCHAR(10),a.fecha_corte,103) INTO fecha_corte FROM prdtable a
      WHERE a.ano = p_ano1 AND a.mes = p_mes1
      
      IF STATUS = NOTFOUND THEN
         LET numero_msg = 3
         CALL msg(numero_msg)
         NEXT FIELD p_ano1
      END IF
 END INPUT
 IF int_flag THEN
    LET numero_msg = 2
    CALL msg(numero_msg)
    LET int_flag = false
    RETURN
 END IF

# Creando criterio de busqueda de inforacion de los activos

 CONSTRUCT criterio ON c.codigo,c.cuenta_no
                  FROM codigo,cuenta_no

 LET selec1 = 
    "SELECT  c.codigo,c.descripcion,c.cuenta_no,convert(varchar(10),c.fech_compra,103), ",
    "       CONVERT(VARCHAR(10),c.fech_compra,103),c.duracion,c.status_t,SUM(a.monto) ",
    "FROM actb00001 c LEFT OUTER JOIN actb00004 a ON c.codigo = a.codigo,actb00002 b ",
    "WHERE  (c.status_t IS NULL) AND a.status_t IS NULL ",
    "  AND a.fecha <= ? AND a.cod_mov = b.cod_mov AND b.uso = '1' AND ",
    criterio CLIPPED," GROUP BY c.codigo,c.descripcion,c.cuenta_no,c.fech_compra,c.fech_compra,c.duracion,c.status_t ORDER BY c.codigo"

    DISPLAY "<< Buscando Informacion ... Espere Por Favor. >>" AT 19,14
                ATTRIBUTE (REVERSE,BOLD)

   PREPARE busca_act FROM selec1 
   DECLARE activos SCROLL CURSOR FOR busca_act     
   OPEN activos USING fecha_corte
   
   CALL seleccionarsalida() RETURNING r_output
   CALL configureoutput(r_output) RETURNING handler
   START REPORT controles TO XML HANDLER handler
   
   FOREACH activos INTO act_fij.*

         LET act_fij.depr_acum   = 0
         LET act_fij.deprec      = 0
         LET act_fij.valor_libro = 0

         SELECT SUM(a.monto)*-1 INTO act_fij.depr_acum FROM actb00004 a
         WHERE a.codigo = act_fij.codigo AND a.status_t IS NULL AND 
               a.fecha <= fecha_corte AND a.monto < 0

         IF act_fij.depr_acum IS NULL THEN
            LET act_fij.depr_acum = 0
         END IF

         SELECT SUM(a.monto)*-1 INTO act_fij.deprec  FROM actb00004 a
         WHERE a.codigo = act_fij.codigo AND a.status_t IS NULL AND 
               a.fecha = fecha_corte AND a.cod_mov = 5

         IF act_fij.deprec IS NULL THEN
            LET act_fij.deprec      = 0
         END IF
         
         #IF (act_fij.depr_acum+act_fij.deprec) >= (act_fij.valor_compra-1) THEN
         IF (act_fij.depr_acum+act_fij.deprec) > (act_fij.valor_compra) THEN
            LET act_fij.valor_libro = 1
            LET act_fij.depr_acum = act_fij.valor_compra - 1
            LET act_fij.deprec = 0
         ELSE
            LET act_fij.valor_libro=act_fij.valor_compra-act_fij.depr_acum 
         END IF
         OUTPUT TO REPORT controles(act_fij.*)  
   END FOREACH
   FINISH REPORT controles 
 END FUNCTION

 ###### Funcion que genera el reporte
    REPORT controles(x)
    DEFINE x RECORD
           codigo         SMALLINT,
           descripcion    CHAR(30),
           cuenta_no      CHAR(8),
           dcto_compra    CHAR(10) ,
           fech_compra    DATE, 
           vida_util      INTEGER,
           status_t       CHAR(1),
           valor_compra   DECIMAL(12,2),
           depr_acum      DECIMAL(12,2),
           valor_libro    DECIMAL(12,2),
           deprec         DECIMAL(12,2)
    END RECORD

    DEFINE hora CHAR(5)

    OUTPUT
       TOP MARGIN 0
       LEFT MARGIN 0
       BOTTOM MARGIN 2
       PAGE LENGTH 100
   #### Sorteando la salida de informacion
    ORDER BY x.cuenta_no,x.codigo

    FORMAT
      PAGE HEADER
        LET hora = time
          LET l = (140 - LENGTH(p_compania.nombre CLIPPED))/2
          PRINT COLUMN   1, comp_on,negrillas_on
          PRINT COLUMN   1, "acprrp001",
                COLUMN  l, p_compania.nombre CLIPPED,
                COLUMN 133, "Pag. ",pageno USING "###"
          LET l = (140 - LENGTH("Sistema de Activos Fijos"))/2
          PRINT COLUMN  l, "Sistema de Activos Fijos           ",
                COLUMN 133, today using "dd/mm/yyyy"
          LET l = (140 - LENGTH("Control de Activos"))/2
          PRINT COLUMN  l, "Control de Activos",
                COLUMN 136, hora
          SKIP 1 LINE
          PRINT COLUMN   1, "FECHA DE CORTE: ",fecha_corte USING "dd/mm/yy"  
          PRINT COLUMN 1, "--------------------------------------------------",
                          "--------------------------------------------------",
                          "--------------------------------------------------"

          PRINT COLUMN  45, "Documento",
                COLUMN  57, "Fecha",     
                COLUMN  73, "Valor",
                COLUMN  86, "Depreciacion",
                COLUMN 103, "Depreciacion",
                COLUMN 122, "Valor", 
                COLUMN 137, "Vida"

          PRINT COLUMN   1, "Activo",
                COLUMN  45, "Compra",
                COLUMN  57, "Compra", 
                COLUMN  73, "Original",
                COLUMN  86, "Acumulada",
                COLUMN 103, "Mes",
                COLUMN 122, "Libro",
                COLUMN 137, "Util"

          PRINT COLUMN 1, "--------------------------------------------------",
                          "--------------------------------------------------",
                          "--------------------------------------------------"
          PRINT negrillas_off

      ON EVERY ROW
     #### Realizando los cxalculos de  depreciacion

         PRINT COLUMN   1, x.codigo USING "&&&&&&","  ",x.descripcion CLIPPED,
               COLUMN  45, x.dcto_compra CLIPPED,
               COLUMN  57, x.fech_compra USING "dd/mm/yyyy",
               COLUMN  67, x.valor_compra USING "###,###,###.##",
               COLUMN  84, x.depr_acum  USING "###,###,###.##",
               COLUMN 105, x.deprec USING "###,###.##",
               COLUMN 116, x.valor_libro USING "###,###,###.##",
               COLUMN 138, x.vida_util USING "&&"

    AFTER GROUP OF x.cuenta_no

         PRINT COLUMN   1, negrillas_on 
         PRINT COLUMN   5, "TOTAL CUENTA---> ",x.cuenta_no CLIPPED,
               COLUMN  67, GROUP SUM(x.valor_compra) USING "###,###,###.##",
               COLUMN  84, GROUP SUM(x.depr_acum) 
                           USING "###,###,###.##",
               COLUMN 101, GROUP SUM(x.deprec) USING "###,###,###.##",
               COLUMN 116, GROUP SUM(x.valor_libro) USING "###,###,###.##"
         PRINT COLUMN   1, negrillas_off

    ON LAST ROW
         PRINT COLUMN   1,negrillas_on 
         PRINT COLUMN   5,"TOTAL GRAL.---> ",
               COLUMN  67, SUM(x.valor_compra) USING "###,###,###.##",
               COLUMN  84, SUM(x.depr_acum) USING "###,###,###.##",
               COLUMN 101, SUM(x.deprec) USING "###,###,###.##",
               COLUMN 116, SUM(x.valor_libro) USING "###,###,###.##"
         PRINT COLUMN   1,negrillas_off,normal

     END REPORT