{
-------------------------------------------------------------------------------
PROGRAMA             :  PRPRRP013
OBJETIVO             :  Validacion maestra de operacion
PROGRAMADOR          :  Tadeo A. Ferreras          
FECHA REALIZACION    :  Oct. 07, 1994   
-------------------------------------------------------------------------------
}

GLOBALS "prprgb000.4gl"

  FUNCTION prprrp013()
      #WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

    OPEN FORM prfmrp013 FROM "prfmrp013"
    DISPLAY FORM prfmrp013
    CALL pantalla()
    DISPLAY "prprrp013" AT 4,3
    DISPLAY "Validacion Maestra de Operaciones" AT 6,23

     LET tipo_papel = 1
     CALL msgrp000(tipo_papel)
 ########### Captura de valores para el criterio de busqueda ############

     CONSTRUCT criterio ON a.codigo FROM codigo
     IF int_flag THEN
        LET numero_msg = 2
        CALL msg(numero_msg)
        LET int_flag = FALSE
        RETURN
     END IF

     LET selec = " SELECT a.* FROM prtb00005 a ",
                 " WHERE a.status_t IS NULL AND ",criterio CLIPPED

     DISPLAY "Buscando Informacion... Espere Por Favor" AT 19,14

     PREPARE comando FROM selec
     DECLARE busca CURSOR FOR comando

     START REPORT reporte_13 TO "C:\\archivo" 
     DISPLAY "Impresion En Proceso... Espere Por Favor" AT 19,14

     FOREACH busca INTO prtb05.*

       IF int_flag THEN 
          LET numero_msg = 2
          CALL msg(numero_msg)
          LET int_flag = FALSE
          RETURN
       END IF

      OUTPUT TO REPORT reporte_13(prtb05.*)
  END FOREACH
  FINISH REPORT reporte_13
RUN "type C:\\archivo > %USPRINT%" END FUNCTION

# Rutina de Impresion de las informaciones 
REPORT reporte_13(x)   

# Variable para tomar las informaciones
  DEFINE x RECORD LIKE prtb00005.*

  DEFINE doble_on CHAR(3)
  DEFINE doble_off CHAR(3)
  DEFINE negrillas_on CHAR(6)
  DEFINE negrillas_off CHAR(6)
  DEFINE comp_on CHAR(2)
  DEFINE comp_off CHAR(2) 
  DEFINE doce CHAR(2)
  DEFINE normal CHAR(3) 
  DEFINE hora CHAR(5)

  OUTPUT
    TOP MARGIN 0
    LEFT MARGIN 0
    BOTTOM MARGIN 2
    ORDER BY x.codigo

    FORMAT

      PAGE HEADER

# Validacion de los caracteres ascii
        LET doble_on =  ASCII 001
        LET doble_off = ASCII 002
        LET negrillas_on = ASCII 27, ASCII 69 
        LET negrillas_off = ASCII 27, ASCII 70 
        LET comp_on = ASCII 15
        LET comp_off = ASCII 18 
        LET doce = ASCII 27, ASCII 77
        LET normal = ASCII 029
        LET hora = time

# Impresion de los encabezados

           PRINT negrillas_on
           PRINT COLUMN  1, "prprrp013",
                 COLUMN 18, "R A Y . O . V A C  D O M I N I C A N A,  S. A.",
                 COLUMN 72, "Pag. ",pageno using "###"
           PRINT COLUMN 18, "            Sistema de Produccion",
                 COLUMN 72, today using "dd/mm/yy"
           PRINT COLUMN 18, "       Validacion Maestra de Operaciones",
                 COLUMN 75, hora
           SKIP 1 LINE

           PRINT COLUMN  1,"--------------------------------------------------",
                           "------------------------------"
           PRINT COLUMN  1, "OPERACION",
                 COLUMN 40, "NOMBRE"
           PRINT COLUMN  1,"--------------------------------------------------",
                           "------------------------------"
           PRINT negrillas_off

          ON EVERY ROW

           PRINT COLUMN  1, x.codigo USING "&&&&",
                 COLUMN 40, x.descripcion CLIPPED

          ON LAST ROW
       
           PRINT negrillas_on 
           PRINT COLUMN  1, "Total Registros ---> ",COUNT(*) USING "####"
           PRINT negrillas_off

          END REPORT