{
=============================================================================
PROGRAMA   : CTPRRP032
OBJETIVO   : FORMULACION SEMI-ELABORADO
PROGRAMADOR: JUAN F. SOTO
FECHA      : FEBRERO 26, 1998
=============================================================================
}
GLOBALS
   "ctprgb000.4gl"
FUNCTION ctprrp032()
 DEFINE semi RECORD 
     cod_prod          LIKE cttb00001.cod_prod,
     cod_n             LIKE intb00001.cod_n,
     cod_grupo         LIKE intb00001.cod_n,
     cod_tipo          LIKE intb00001.cod_n,
     cod_sec           LIKE intb00001.cod_n,
     cantidad          LIKE cttb00011.cantidad,
     unidad            LIKE cttb00001.unidad_med,
     descripcion       LIKE cttb00001.descripcion,
     unidad_med        LIKE intb00001.unidad_med,
     descrip_esp       LIKE intb00001.descrip_esp
 END RECORD
 OPTIONS
   ERROR LINE 24,
   FORM LINE 8

 OPEN FORM ctfmrp032 FROM "ctfmrp032"
 DISPLAY FORM ctfmrp032
  
 DISPLAY "Formulacion Semi-Elaborados" AT 6,22
 LET tipo_papel = 1
 CALL msgrp000(tipo_papel)

 CONSTRUCT BY NAME criterio ON a.cod_prod
   IF int_flag THEN
      LET numero_msg = 2
      CALL msg(numero_msg)
      LET int_flag = FALSE 
      RETURN
   END IF
 LET selec = 
            "select  a.cod_prod, ",
	            "a.cod_n, ",
	            "a.cod_grupo, ",
	            "a.cod_tipo, ",
	            "a.cod_sec, ",
	            "a.cantidad, ",
                    "b.unidad_med usm, ",
                    "b.descripcion, ",
                    "c.unidad_med ump, ",
                    "c.descrip_esp ",
            "from cttb00011 a,cttb00001 b,intb00001 c  ",
            "where a.cod_prod = b.cod_prod and ",
                  "a.cod_n = c.cod_n and ",
                  "a.cod_grupo = c.cod_grupo and ",
                  "a.cod_tipo = c.cod_tipo and ",
                  "a.cod_sec = c.cod_sec and ",
                  "b.status_t is null AND ",criterio CLIPPED,
            "order by 1   "
         DISPLAY "Impresion En Proceso.... Espere Por Favor" AT 17,14
         PREPARE comando FROM selec
         DECLARE busca CURSOR FOR comando
   
         START REPORT prtsemi TO "C:\\archivo"
         FOREACH busca INTO semi.*

              OUTPUT TO REPORT prtsemi(semi.*)
         END FOREACH
         FINISH REPORT prtsemi
   RUN "type C:\\archivo > %USPRINT%" END FUNCTION
 REPORT prtsemi(x)
 DEFINE x RECORD 
     cod_prod          LIKE cttb00001.cod_prod,
     cod_n             LIKE intb00001.cod_n,
     cod_grupo         LIKE intb00001.cod_n,
     cod_tipo          LIKE intb00001.cod_n,
     cod_sec           LIKE intb00001.cod_n,
     cantidad          LIKE cttb00011.cantidad,
     unidad            LIKE cttb00001.unidad_med,
     descripcion       LIKE cttb00001.descripcion,
     unidad_med        LIKE intb00001.unidad_med,
     descrip_esp       LIKE intb00001.descrip_esp
 END RECORD
OUTPUT
 LEFT MARGIN 0
FORMAT

PAGE HEADER 
       PRINT COLUMN 1, "ctprrp032",
             COLUMN 23, "  M A R M O T E C H, S. A.",
             COLUMN 70, "Pag. ",pageno USING "<<<"
       PRINT COLUMN 23, "FORMULACION SEMI-ELABORADOS",
             COLUMN 70, TODAY USING "DD/MM/YYYY"
       SKIP 1 LINE

BEFORE GROUP OF x.cod_prod
   PRINT COLUMN 1,"SEMI-ELABORADO: ",x.cod_prod USING "####"," ",
                                     x.descripcion," ",x.unidad
   PRINT COLUMN 1, "========================================================",
                   "==========================="
   PRINT COLUMN 3, "MATERIALES",
         COLUMN 75, "CANTIDAD"
   PRINT COLUMN 1, "========================================================",
                   "==========================="
   SKIP 1 LINE

ON EVERY ROW 
   PRINT COLUMN 3, x.cod_n USING "&","-",
                   x.cod_grupo USING "&","-",
                   x.cod_tipo USING "&&","-",
                   x.cod_sec USING "&&&"," ",
                   x.descrip_esp," ",x.unidad_med,
         COLUMN 70, x.cantidad USING "#,###.####"
AFTER GROUP OF x.cod_prod
  SKIP 1 LINE
END  REPORT