{
-------------------------------------------------------------------------------
PROGRAMA             :  CCPRRP026
OBJETIVO             :  Devoluciones sobre ventas
PROGRAMADOR          :  Juan Fco. Soto           
FECHA                :  Diciembre 3, 1993.
-------------------------------------------------------------------------------
}
GLOBALS "ccprgb000.4gl"
# Variables para controlar que el nombre del articulo y del vendedor 
# se busque una sola vez

    DEFINE p_mes SMALLINT
    DEFINE vende,vende_ant CHAR(7)
    DEFINE selec_26 CHAR(1000)

# Variables para la captura de la informacion del reporte

    DEFINE mes SMALLINT
    DEFINE cod_cia SMALLINT
    DEFINE salir,ventas CHAR(1)

FUNCTION ccprrp026()
# Variables que toman los valores del query y a la vez estas mismas variables
# Asignan estos valores a otra que se imprimira posteriormente
    DEFINE vendedor RECORD
          sec_vend       SMALLINT,
          fecha          DATE,    
          factura        INTEGER,  
          cod_n          SMALLINT,
          cod_grupo      SMALLINT,
          cod_tipo       SMALLINT,
          cod_sec        SMALLINT,
          cantidad       DECIMAL(12,3),
          valor          DECIMAL(10,2),
          descrip_esp    CHAR(30)
     END RECORD
     DEFINE fecha1,fecha2 DATE
# Atrapa el error de run-time

#   WHENEVER ERROR CONTINUE
# Especificaciones para el desplegue de errores y formulario.
# Reserva lineas para tales fines.

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21
# Desplegue del formulario de entrada de informacion

    OPEN FORM ccfmrp026 FROM "ccfmrp026"
    DISPLAY FORM ccfmrp026
#----------------------------------------------------------

    CALL pantalla()

    DISPLAY "ccprrp026" AT 4,3
    DISPLAY "  Devolucion Del Mes " AT 6,29 

## Tipo de papel necesari para imprimir el reporte
    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

# Entrada de datos para el reporte

   INPUT BY NAME cod_cia,p_mes,ventas
    AFTER FIELD cod_cia
       IF cod_cia IS NULL THEN
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD cod_cia
       END IF

    AFTER FIELD p_mes 
      IF p_mes IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD p_mes
      END IF

     SELECT a.fecha_inicio,a.fecha_corte INTO fecha1,fecha2
     FROM prdtable a 
     WHERE a.ano = YEAR(TODAY) AND a.mes = p_mes

    AFTER FIELD ventas    
      IF ventas IS NULL THEN
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD ventas
      END IF
    
    END INPUT
   
      IF int_flag THEN
         LET numero_msg = 2
         CALL msg(numero_msg)
         LET int_flag = false
         RETURN
      END IF

  CONSTRUCT criterio ON a.sec_vend,b.cod_n,b.cod_grupo,b.cod_tipo,b.cod_sec
                      FROM sec_vend,cod_n,cod_grupo,cod_tipo,cod_sec

#-------------------------------------------------------------------
# Chequo de la cancelacion del programa con la variable global int_flag

      IF int_flag THEN
         LET numero_msg = 2
         CALL msg(numero_msg)
         LET int_flag = false
         RETURN
      END IF
#--------------------------------------------------------------------
# Prepara al sistema operativo para recibir el reporte

      START REPORT devolucion TO "C:\\archivo"
# Buscando las informaciones del reporte

    DISPLAY "                                                     " AT 19,14
    DISPLAY "<< Buscando Informacion ... Espere Por Favor >>" AT 19,14
           ATTRIBUTE (REVERSE,BOLD)

      LET selec_26 =
         "SELECT a.sec_vend,b.fecha,b.fact_no,b.cod_n,b.cod_grupo, ",
         "       b.cod_tipo,b.cod_sec,SUM(b.cantidad_2) ",
         "FROM vetb00002 a, iptb00006 b ",
         "WHERE ",criterio CLIPPED," AND b.status_t IS NULL AND ",
         "      b.fecha between ? AND ? AND b.cod_mov IN(12,13) AND ",
         "      a.ventas = ? AND a.status_t IS NULL AND a.cod_cia = ? AND ",
         "      b.fact_no = a.factura GROUP BY 1,2,3,4,5,6,7 "

      PREPARE b_vende FROM selec_26
      DECLARE c_vende CURSOR FOR b_vende
      OPEN c_vende USING fecha1,fecha2,ventas,cod_cia

#---------------------------------------------------------------------------

    DISPLAY "                                              " AT 19,14
    DISPLAY "<< Reporte Generandose ... Por Favor Espere >>" AT 19,14
            ATTRIBUTE (REVERSE)

# Loop para darle salida al Query hasta que la variable global status = 100

      LET salir = "N"
      WHILE salir != "S"         
      FETCH   c_vende INTO vendedor.*
      IF status = notfound THEN
         LET salir = "S"
         EXIT WHILE
      END IF

      IF int_flag THEN
         LET numero_msg = 2
         CALL msg(numero_msg)
         LET int_flag = FALSE
         RETURN
      END IF

# Busco los datos detallados de la factura en la tabla de detalle de ventas

      LET vendedor.valor = 0
      SELECT a.precio INTO vendedor.valor FROM vetb00003 a
      WHERE a.cod_n = vendedor.cod_n AND a.cod_grupo = vendedor.cod_grupo AND
            a.cod_tipo = vendedor.cod_tipo AND a.cod_sec = vendedor.cod_sec AND
            a.status_t IS NULL AND a.factura = vendedor.factura

      IF vendedor.cantidad IS NULL THEN
         LET vendedor.cantidad = 0
      END IF
      IF vendedor.valor IS NULL THEN
         LET vendedor.valor = 0
      END IF
      LET vendedor.valor = vendedor.valor * vendedor.cantidad

      SELECT a.descrip_esp INTO vendedor.descrip_esp FROM intb00001 a
      WHERE a.cod_n = vendedor.cod_n AND a.cod_grupo = vendedor.cod_grupo AND
            a.cod_tipo = vendedor.cod_tipo AND a.cod_sec = vendedor.cod_sec AND
            a.status_t IS NULL

       DISPLAY "                                                " AT 20,14
       DISPLAY vendedor.descrip_esp," ",vendedor.factura 
       AT 20,14
       OUTPUT TO REPORT devolucion (vendedor.*)
    END WHILE

# Aqui se le especifica al sistema operativo que el reporte ha terminado
# el sistema operativo hace el resto

   FINISH REPORT devolucion
#---------------------------------------------------------------------
   CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION
# Rutina de reporte 

REPORT devolucion(x)
# Variable que toma el valor de la funcion que llamo a esta rutina

    DEFINE x RECORD
          sec_vend       SMALLINT,
          fecha          DATE,    
          factura        INTEGER,  
          cod_n          SMALLINT,
          cod_grupo      SMALLINT,
          cod_tipo       SMALLINT,
          cod_sec        SMALLINT,
          cantidad       DECIMAL(12,3),
          valor          DECIMAL(10,2),
          descrip_esp    CHAR(30)
    END RECORD
# Esta variable toma el valor del nombre del mes para imprimirse

    DEFINE nombre_mes CHAR(10)
    DEFINE nombre,apellido CHAR(15)
#------------------------------------------------------------------
# Estas variables son constantes en todos los reportes de RAYOVAC 
# para no estar definiendolas en cada momento.
# Estas variables son los caracteres ASCII para ser interpretados por
# el printer.

    DEFINE doble_on CHAR(2)
    DEFINE doble_off CHAR(2)
    DEFINE negrillas_on CHAR(2)
    DEFINE negrillas_off CHAR(2)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(3)
    DEFINE normal CHAR(2) 
#----------------------------------------------------------------------
# Esta variable es para asignarle la hora del dia e imprimir en HH:MM

    DEFINE hora CHAR(5)
#-----------------------------------------------------------------------
# Con esta variable se hace un calculo porcentual

    DEFINE porc DECIMAL(10,4)
#-----------------------------------------------------------------------
# Variables totales del reporte
    DEFINE t_valor,t_unidades,total_gen,total_vend,valor_pagar DECIMAL(12,2)
# Definicion de salida del reporte, margenes.

    OUTPUT
      TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 4
#------------------------------------------------------------------------

    ORDER BY x.sec_vend,x.factura

    FORMAT
      PAGE HEADER
# Asignaciones de los valores ASCII para la impresion

        LET doble_on =  ASCII 14
        LET doble_off = ASCII 20
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET comp_on = ASCII 15 
        LET comp_off = ASCII 18
        LET doce = ASCII 27, ASCII 77
        LET normal = ASCII 27, ASCII 80
        LET hora = time

# Funcion  que busca los meses del ano
        SELECT @descrip INTO nombre_mes FROM mestable WHERE @mes = p_mes    
#--------------------------------------------------------------------------

        LET lj = (88 - LENGTH(p_companias.nombre CLIPPED))/2
        PRINT COLUMN 1, doce    
        PRINT COLUMN  1, "ccprrp026",
              COLUMN lj, p_companias.nombre CLIPPED,
              COLUMN 81, "Pag. ",pageno using "###"
        PRINT COLUMN 21, "         Sistema de Cuentas Por Cobrar",
              COLUMN 81, today using "dd/mm/yy"
        PRINT COLUMN 21, "              Devolucion Del Mes     ",
              COLUMN 84, hora

        PRINT COLUMN 1, doble_on,"MES: ",nombre_mes,doble_off
        PRINT COLUMN 1, "--------------------------------------------------",
                          "--------------------------------------"
        PRINT COLUMN   1, "FACTURA",   
              COLUMN   9, "FECHA",
              COLUMN  18, "PRODUCTO",
              COLUMN  71, "VALOR",
              COLUMN  81, "UNIDADES"
        PRINT COLUMN 1, "--------------------------------------------------", 
                          "--------------------------------------"

      SKIP 1 LINE
      BEFORE GROUP OF x.sec_vend
             LET t_unidades = 0
             LET total_vend = 0
             LET t_valor = 0

# Impresion del nombre del vendedor
       SELECT nom1_emp,apell1_emp INTO nombre,apellido
       FROM adtb00003 WHERE num_emp = x.sec_vend

             PRINT COLUMN  1,doble_on,"VENDEDOR : ", 
                             "(",x.sec_vend using "&&&",")",
                             nombre clipped," ",apellido clipped,doble_off 

             SKIP 1 LINE
# Impresion detalle del reporte

      ON EVERY ROW

             PRINT COLUMN  1, x.factura using "&&&&&&",
                   COLUMN  9, x.fecha using "dd/mm/yy",
                   COLUMN 18, x.cod_n using "&",x.cod_grupo using "&",
                              x.cod_tipo using "&&",x.cod_sec using "&&&", 
                              " ",x.descrip_esp[1,30],
                   COLUMN 57, x.valor using "#,###,###.##",
                   COLUMN 70, x.cantidad using "###,###.###"

      AFTER GROUP OF x.factura
           SKIP 1 LINE

      AFTER GROUP OF x.sec_vend
            PRINT COLUMN  57, "------------",
                  COLUMN  70, "-----------"

            PRINT COLUMN  50, "Total",
                  COLUMN  57, GROUP SUM(x.valor) using "#,###,###.##",
                  COLUMN  70, GROUP SUM(x.cantidad) using "###,###.###"
            SKIP 1 LINE
            LET total_gen = total_gen + total_vend

   ON LAST ROW
     PRINT comp_off
 END REPORT