{
-------------------------------------------------------------------------------
PROGRAMA              :  NOPRRP020
OBJETIVO              :  LISTAR LOS MOVIMIENTOS FIJOS DE LOS EMPLEADOS
PROGRAMADOR           :  Ing. Juan Soto
FECHA REALIZACION     :  Febrero 3, 1993
-------------------------------------------------------------------------------
}
GLOBALS "noprgb000.4gl"

FUNCTION noprrp020()

## DEFINICION DEL REGISTRO DE BUSQUEDA CON LOS CAMPOS NECESARIOS PARA 
## EL REPORTE
    DEFINE salir CHAR(1)
    DEFINE acumula RECORD
           cod_mov    LIKE notb00008.cod_mov,
           num_emp    LIKE notb00008.num_emp,
           valor      DECIMAL(12,2)
    END RECORD

    DEFINE cooper RECORD
        num_emp       LIKE notb00008.num_emp,
        departamento  LIKE adtb00003.departamento,
        nivel_emp     LIKE adtb00003.nivel_emp,
        cod_puesto    LIKE adtb00003.cod_puesto,
        nom1_emp      LIKE adtb00003.nom1_emp,
        apell1_emp    LIKE adtb00003.apell1_emp,
        tipo_emp      LIKE notb00008.tipo_emp,
        cod_mov       LIKE notb00008.cod_mov,
        descrip_mov   LIKE notb00002.descrip_mov,
        clase_mov     LIKE notb00008.clase_mov,
        valor         LIKE notb00008.valor,
        cantidad      DECIMAL(10,2),
        num_nomi      LIKE notb00008.num_nomi,
        fecha_al      LIKE notb00010.fecha_al
    END RECORD

# WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

    CLEAR SCREEN

    OPEN FORM nofmrp020 FROM "nofmrp020"
    DISPLAY FORM nofmrp020
    CALL pantalla()
    DISPLAY "noprrp020" AT 4,3
    DISPLAY "Movimientos Fijos de Empleado" AT 6,25

## INDICA EL TIPO DE PAPEL NECESARIO PARA EL REPORTE.  1 - PAPEL 9 1/2 X 11
## 2 - PAPEL 14 7/8 X 11
    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

## AQUI SE INDICA EL CRITERIO DE BUSQUEDA DEL REPORTE 
    INPUT BY NAME cooper.num_nomi,cooper.tipo_emp
    AFTER INPUT
     IF cooper.num_nomi is null THEN
        LET numero_msg = 16
        CALL msg(numero_msg)
        NEXT FIELD num_nomi
     END IF
     IF cooper.tipo_emp is null THEN
        LET numero_msg = 16
        CALL msg(numero_msg)
        NEXT FIELD tipo_emp
     END IF
     EXIT INPUT
     END INPUT

    CONSTRUCT criterio ON a.cod_mov FROM cod_mov

    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
    END IF

## SE SELECCIONAN LOS CAMPOS NECESARIOS PARA EL REPORTE
    LET SELEC = 
     "SELECT UNIQUE a.num_emp,b.departamento,b.nivel_emp,b.cod_puesto, ",
     "       b.nom1_emp,b.apell1_emp,b.nomina,a.cod_mov,c.descrip_mov, ",
     "       c.clase_mov ,a.valor,a.cantidad ",
     "FROM adtb00003 b,notb00008 a,notb00002 c ",
     "WHERE a.num_emp = b.num_emp and a.cod_mov = c.cod_mov and ",
     "      b.nomina = ? and a.status_t is null AND c.tipo_mov = 'F' AND ",
     criterio clipped," ORDER BY 9,1,2,3,4"

    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
    END IF

     DISPLAY "Buscando Informacion ... Espere Por Favor" AT 19,14
     ATTRIBUTE (REVERSE,BOLD)

## SE PREPARA LA INFORMACION SELECCIONADA
    PREPARE comando FROM selec

      CALL integridad()
         IF bandera = 1 THEN
            LET bandera = 0
            RETURN
        END IF 

    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
    END IF

## SE DECLARA EL CURSOR PARA BUSCAR LA INFORMACION SELECCIONADA
    DECLARE accion CURSOR FOR comando
    OPEN accion USING cooper.tipo_emp

      DISPLAY "                                                " AT 19,14
      DISPLAY "<< Reporte Generandose ...  Por Favor Espere. >>" 
              AT 19,14 ATTRIBUTE (REVERSE) 

    START REPORT repfijo TO "C:\\archivo"

## SE BUSCA LA INFORMACION DE LOS CAMPOS DEL REGISTRO PARA DARLE
## SALIDA AL REPORTE
    WHILE status != notfound 
    FETCH accion INTO cooper.* 
    IF status = notfound THEN
       EXIT WHILE
    END IF

    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = FALSE
       RETURN
    END IF

         OUTPUT TO REPORT repfijo(cooper.*)
    END WHILE
    FINISH REPORT repfijo

    CLEAR SCREEN

RUN "type C:\\archivo > %USPRINT%" END FUNCTION

## DEFINICION DEL REGISTRO DE IMPRESION CON LOS CAMPOS NECESARIOS PARA
## EL REPORTE
    REPORT repfijo(x)
       DEFINE x RECORD
        num_emp       LIKE notb00008.num_emp,
        departamento  LIKE adtb00003.departamento,
        nivel_emp     LIKE adtb00003.nivel_emp,
        cod_puesto    LIKE adtb00003.cod_puesto,
        nom1_emp      LIKE adtb00003.nom1_emp,
        apell1_emp    LIKE adtb00003.apell1_emp,
        tipo_emp      LIKE notb00008.tipo_emp,
        cod_mov       LIKE notb00008.cod_mov,
        descrip_mov   LIKE notb00002.descrip_mov,
        clase_mov     LIKE notb00008.clase_mov,
        valor         LIKE notb00008.valor,
        cantidad      DECIMAL(10,2),
        num_nomi      LIKE notb00008.num_nomi,
        fecha_al      LIKE notb00010.fecha_al
       END RECORD
 
## DEFINICION DE LAS VARIABLES DE IMPRESION
    DEFINE doble_on CHAR(2)
    DEFINE doble_off CHAR(2)
    DEFINE negrillas_on CHAR(2)
    DEFINE negrillas_off CHAR(2)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(2)
    DEFINE normal CHAR(2)
    DEFINE hora CHAR(5)
    DEFINE valor1,total,total1 DECIMAL(10,2)
    DEFINE l smallint
    DEFINE varia CHAR(30)

    OUTPUT

## DEFINICION DE LOS MARGENES DE IMPRESION
     TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 3

    FORMAT
      PAGE HEADER
        LET doble_on =  ASCII 14
        LET doble_off = ASCII 20
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET comp_on = ASCII 15
        LET comp_off = ASCII 18
        LET doce = ASCII 27, ASCII 77  
        LET normal = ASCII 27, ASCII 80
        LET hora = time
        LET varia = x.descrip_mov
        LET l = (77 - LENGTH(p_companias.nombre CLIPPED))/2

## SE CALCULA LA LONGITUD DE LA VARIABLE -VARIA-

## AQUI SE INDICA LA IMPRESION DE LOS ENCABEZADOS
           PRINT COLUMN 1, comp_off,normal,negrillas_on
           PRINT COLUMN  3, "noprrp020",
                 COLUMN  l, p_companias.nombre CLIPPED,
                 COLUMN 70, "Pag. ",pageno using "###"
           PRINT COLUMN 27, "  Movimientos Fijos   ",
                 COLUMN 70, today using "dd/mm/yy"
          LET l = (77 - LENGTH(varia CLIPPED))/2
           PRINT COLUMN  L, varia,
                 COLUMN 73, hora

   SKIP 1 LINE
## SE IMPRIME EL NUMERO DE NOMINA Y LA FECHA
           PRINT COLUMN  3, "Nomina No.: ",x.num_nomi using "<<<<",
                            " Al: ",x.fecha_al using "dd/mm/yy"

## SE SELECCIONA EL TIPO DE NOMINA A IMPRIMIR
                    IF x.tipo_emp = "Q" THEN
                       LET descr = "QUINCENAL"
                    ELSE
                       IF x.tipo_emp = "V" THEN
                          LET descr = "VENDEDOR"
                       ELSE
                          LET descr = "SEMANAL"
                       END IF
                    END IF

        PRINT COLUMN  3, descr

        PRINT COLUMN 3, "---------------------------------------------------",
                        "------------------------"

           PRINT COLUMN  3, "Codigo No.",
                 COLUMN 19, "Nombre",
                 COLUMN 51, "Cantidad",
                 COLUMN 73, "Valor"   

        PRINT COLUMN 3, "----------------------------------------------------",
                        "-----------------------" 
       PRINT COLUMN 1, negrillas_off

## SE INDICA EL SALTO DE PAGINA CUANDO SE IMPRIMEN TODOS LOS MOVIMIENTOS
      BEFORE GROUP OF x.cod_mov
        SKIP TO TOP OF PAGE
        LET total1 = 0
        LET total  = 0

     BEFORE GROUP OF x.num_emp
         LET valor1 = 0
## AQUI SE CALCULAN LOS TOTALES GENERALES
         IF total1 IS NULL THEN
            LET total1 = 0
         END IF
         LET total1 = total1 + x.valor

         IF total IS NULL THEN
            LET total = 0
         END IF
         LET total = total + x.cantidad

## AQUI COMIENZA LA IMPRESION DEL DETALLE
         PRINT COLUMN  3, x.num_emp using "&&&&","-",
                          x.departamento using "&&&&","-",
                          x.nivel_emp using "&&","-",
                          x.cod_puesto using "&&",
                          " ",x.nom1_emp clipped," ",x.apell1_emp clipped,
               COLUMN 50, x.cantidad using "##,###.##",
               COLUMN 69, x.Valor  using "##,###.##"

## AQUI SE IMPRIMEN LOS TOTALES GENERALES
    AFTER GROUP OF x.cod_mov
             PRINT COLUMN  1, negrillas_on
             PRINT COLUMN  3, "TOTAL GENERAL",
                   COLUMN 49, total using "###,###.##",
                   COLUMN 68, total1 using "###,###.##"
             PRINT COLUMN  1, negrillas_off

END REPORT