{
-------------------------------------------------------------------------------
PROGRAMA             :  VEPRRP024
OBJETIVO             :  Devoluciones por Vendedor
PROGRAMADOR          :  Juan F. Soto             
FECHA REALIZACION    :  Diciembre 3, 1993   
-------------------------------------------------------------------------------
}

GLOBALS "veprgb000.4gl"
# Variables para controlar que el nombre del articulo y del deduciones 
# se busque una sola vez

    DEFINE codigo,codigo_ant CHAR(7)
    DEFINE vende,vende_ant CHAR(7)
#   DEFINE mes1 ARRAY[12] OF CHAR(10)
    DEFINE selec28 CHAR(1000)

# Variables para la captura de la informacion del reporte

    DEFINE mes SMALLINT
    DEFINE cod_cia SMALLINT
    DEFINE salir,ventas CHAR(1)

FUNCTION veprrp024()
# Variables que toman los valores del query y a la vez estas mismas variables
# Asignan estos valores a otra que se imprimira posteriormente
    DEFINE deduc RECORD
          sec_vend       SMALLINT,
          fecha_factura  DATE,    
          factura        INTEGER,  
          cond_pago      SMALLINT,
          nombre_vend    CHAR(30), 
          apellido_vend  CHAR(30),
          cod_n          SMALLINT,
          cod_grupo      SMALLINT,
          cod_tipo       SMALLINT,
          cod_sec        SMALLINT,
          cantidad       INTEGER,
          precio         DECIMAL(10,2),
          porc_venta     DECIMAL(10,4),
          descrip_esp    CHAR(30),
          vende          CHAR(6)
     END RECORD
     DEFINE fecha1,fecha2 DATE
# Atrapa el error de run-time

#   WHENEVER ERROR CONTINUE
# Especificaciones para el desplegue de errores y formulario.
# Reserva lineas para tales fines.

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21
# Desplegue del formulario de entrada de informacion

    OPEN FORM vefmrp024 FROM "vefmrp024"
    DISPLAY FORM vefmrp024
#----------------------------------------------------------

    CALL pantalla()

    DISPLAY "veprrp024" AT 4,3
    DISPLAY "Devoluciones por Vendedor" AT 6,27 

## Tipo de papel necesario para imprimir el reporte
    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

# Entrada de datos para el reporte

   INPUT BY NAME cod_cia,mes,ventas
    AFTER FIELD cod_cia
       IF cod_cia IS NULL THEN
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD cod_cia
       END IF

    AFTER FIELD mes 
      IF mes IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD mes
      END IF

     SELECT a.fecha_inicio,a.fecha_corte INTO fecha1,fecha2
     FROM prdtable a 
     WHERE a.ano = YEAR(TODAY) AND a.mes = mes

    AFTER FIELD ventas    
      IF ventas IS NULL THEN
          LET numero_msg = 16
          CALL msg(numero_msg)
          NEXT FIELD ventas
      END IF
    
    END INPUT
   
      IF int_flag THEN
         LET numero_msg = 2
         CALL msg(numero_msg)
         LET int_flag = false
         RETURN
      END IF

  CONSTRUCT criterio ON a.sec_vend,c.cod_n,c.cod_grupo,c.cod_tipo,c.cod_sec
                      FROM sec_vend,cod_n,cod_grupo,cod_tipo,cod_sec

#-------------------------------------------------------------------
# Chequo de la cancelacion del programa con la variable global int_flag

      IF int_flag THEN
         LET numero_msg = 2
         CALL msg(numero_msg)
         LET int_flag = false
         RETURN
      END IF
#--------------------------------------------------------------------
# Prepara al sistema operativo para recibir el reporte

      START REPORT deduce TO "C:\\archivo" 
# Buscando las informaciones del reporte

    DISPLAY "                                                     " AT 19,14
    DISPLAY "<< Buscando Informacion ... Espere Por Favor >>" AT 19,14
           ATTRIBUTE (REVERSE,BOLD)

 LET selec28 =
  "SELECT a.sec_vend,c.fecha,c.fact_no,a.cond_pago,b.nom1_emp,b.apell1_emp, ",
  "       c.cod_n,c.cod_grupo,c.cod_tipo,c.cod_sec,SUM(c.cantidad_2) ",
  "FROM iptb00006 c,vetb00002 a, adtb00003 b ",
  "WHERE c.fecha between ? and ? and a.ventas = ? AND ",
  "      a.sec_vend = b.num_emp AND c.status_t IS NULL AND ",
  "      a.cod_cia = ? AND c.fact_no = a.factura AND ",
  "   (c.cod_mov = 12 OR c.cod_mov = 13) AND c.fact_no IS NOT NULL AND ",
  criterio clipped," GROUP BY 1,2,3,4,5,6,7,8,9,10 ORDER BY 1,3"

      PREPARE b_vende FROM selec28
      DECLARE c_vende CURSOR FOR b_vende
      OPEN c_vende USING fecha1,fecha2,ventas,cod_cia

#---------------------------------------------------------------------------

    DISPLAY "                                              " AT 19,14
    DISPLAY "<< Reporte Generandose ... Por Favor Espere >>" AT 19,14
            ATTRIBUTE (REVERSE)

# Loop para darle salida al Query hasta que la variable global status = 100

      LET codigo_ant = "  "
      LET salir = "N"
      WHILE salir != "S"         
      FETCH   c_vende INTO deduc.*
      IF status = notfound THEN
         LET salir = "N"
         EXIT WHILE
      END IF

# Busco los datos detallados de la factura en la tabla de detalle de ventas
        SELECT a.precio,b.descrip_esp INTO deduc.precio,deduc.descrip_esp
        FROM vetb00003 a,iptb00002 b
        WHERE a.cod_n = b.cod_n AND a.cod_grupo = b.cod_grupo AND   
              a.cod_tipo = b.cod_tipo AND a.cod_sec = b.cod_sec AND
              a.cod_n = deduc.cod_n AND a.cod_grupo = deduc.cod_grupo AND
              a.cod_tipo = deduc.cod_tipo AND a.cod_sec = deduc.cod_sec AND
              a.status_t IS NULL AND a.factura = deduc.factura

# Busco la descripcion del articulo
       LET codigo = deduc.cod_n using "&",
                    deduc.cod_grupo using "&",
                    deduc.cod_tipo using "&&",
                    deduc.cod_sec using "&&&"

#-------------------------------------------------------------------------------
# Se hace esta asignacion a otra variable para tener el codigo del deduc
# que esta en dos campos, en una sola variable para poder hacer ruptura de 
# control
       LET deduc.vende = deduc.sec_vend using "&&&&"

# Salida hacia la impresion del reporte, este llama la rutina que
# resuelve los reportes en 4GL

        LET deduc.porc_venta = 0
        SELECT porc_ventas INTO deduc.porc_venta FROM vetb00011
        WHERE cod_n = deduc.cod_n and cod_grupo = deduc.cod_grupo and
              cod_tipo = deduc.cod_tipo and cod_sec  = deduc.cod_sec and
              sec_vend = deduc.sec_vend and status_t is null

       OUTPUT TO REPORT deduce (deduc.*)
    END WHILE

# Aqui se le especifica al sistema operativo que el reporte ha terminado
# el sistema operativo hace el resto

   FINISH REPORT deduce
#---------------------------------------------------------------------
   CLEAR SCREEN
RUN "type C:\\archivo > %USPRINT%" END FUNCTION
# Rutina de reporte 

REPORT deduce(x)
# Variable que toma el valor de la funcion que llamo a esta rutina

    DEFINE x RECORD
          sec_vend       SMALLINT,
          fecha_factura  DATE,    
          factura        INTEGER,  
          cond_pago      SMALLINT,
          nombre_vend    CHAR(30), 
          apellido_vend  CHAR(30) ,
          cod_n          SMALLINT,
          cod_grupo      SMALLINT,
          cod_tipo       SMALLINT,
          cod_sec        SMALLINT,
          cantidad       INTEGER,
          precio         DECIMAL(10,2),
          porc_venta     DECIMAL(10,4),
          descrip_esp    CHAR(30),
          deduc       CHAR(6)  
    END RECORD
# Esta variable toma el valor del nombre del mes para imprimirse

    DEFINE nombre_mes CHAR(10)
#------------------------------------------------------------------
# Estas variables son constantes en todos los reportes de RAYOVAC 
# para no estar definiendolas en cada momento.
# Estas variables son los caracteres ASCII para ser interpretados por
# el printer.

    DEFINE doble_on CHAR(2)
    DEFINE doble_off CHAR(2)
    DEFINE negrillas_on CHAR(2)
    DEFINE negrillas_off CHAR(2)
    DEFINE comp_on CHAR(2)
    DEFINE comp_off CHAR(2) 
    DEFINE doce CHAR(3)
    DEFINE normal CHAR(2) 
#----------------------------------------------------------------------
# Esta variable es para asignarle la hora del dia e imprimir en HH:MM

    DEFINE hora CHAR(5)
#-----------------------------------------------------------------------
# Con esta variable se hace un calculo porcentual

    DEFINE porc DECIMAL(10,4)
#-----------------------------------------------------------------------
# Variables totales del reporte
    DEFINE t_valor,t_unidades,total_gen,total_vend,valor_pagar DECIMAL(12,2)
# Definicion de salida del reporte, margenes.

    OUTPUT
      TOP MARGIN 0
      LEFT MARGIN 0
      BOTTOM MARGIN 4
#------------------------------------------------------------------------

    ORDER BY x.deduc,x.factura

    FORMAT
      PAGE HEADER
# Asignaciones de los valores ASCII para la impresion

        LET doble_on =  ASCII 14
        LET doble_off = ASCII 20
        LET negrillas_on = ASCII 27, ASCII 69
        LET negrillas_off = ASCII 27, ASCII 70
        LET comp_on = ASCII 15 
        LET comp_off = ASCII 18
        LET doce = ASCII 030
        LET normal = ASCII 27, ASCII 80
        LET hora = time
# Funcion  que busca los meses del ano

        CALL meses()
        LET nombre_mes = mes1[mes]
#--------------------------------------------------------------------------

        LET lj = (104 - LENGTH(p_companias.nombre CLIPPED))/2
        PRINT COLUMN 1, comp_on
        PRINT COLUMN 1, "veprrp024",
              COLUMN lj, p_companias.nombre CLIPPED,
              COLUMN 92, "Pag.",
              COLUMN 97, pageno using "###"
        PRINT COLUMN 41, "Sistema de Ventas ",
              COLUMN 90, today using "dd/mm/yyyy"
        PRINT COLUMN 33, "Relacion Deducciones por Vendedor",
              COLUMN 95, hora

        PRINT COLUMN 40, doble_on,nombre_mes,doble_off
        IF cod_cia = 1 THEN
            PRINT COLUMN 1, "Rayovac Dominicana"
        ELSE
           PRINT COLUMN 1, "Distribuidora Dominicana de Pilas"
        END IF

        SKIP 1 LINES
        PRINT COLUMN 1, "--------------------------------------------------",
                        "--------------------------------------------------", 
                        "--------------------"
         PRINT COLUMN   2, "FACTURA",   
              COLUMN  10, "FECHA",
              COLUMN  20, "PRODUCTO",
              COLUMN  66, "VALOR",
              COLUMN  75, "UNIDADES",    
              COLUMN  84, "COMISION",    
              COLUMN  94, "DEDUCCION"

              PRINT COLUMN 1, 
                    "--------------------------------------------------", 
                    "--------------------------------------------------", 
                    "--------------------"

      IF total_gen is null THEN
         LET total_gen = 0
      END IF
      SKIP 1 LINE
      BEFORE GROUP OF x.deduc
             LET t_unidades = 0
             LET total_vend = 0
             LET t_valor = 0

# Impresion del nombre del deduc
       SELECT nom1_emp,apell1_emp INTO x.nombre_vend,x.apellido_vend
                                 FROM adtb00003 WHERE
                                      num_emp = x.sec_vend

             PRINT COLUMN  1,doble_on,"VENDEDOR : ", 
                             x.nombre_vend clipped," ",
                             x.apellido_vend clipped, doble_off 

             SKIP 1 LINE
# Impresion detalle del reporte

      ON EVERY ROW
# Calculo para dar total de las unidades vendidas 

             LET t_unidades = t_unidades + x.cantidad
# Si la compania es uno(1) se toma el porciento por la cantidad
# esto es que para la compania rayovac es cantidad por porciento de venta

# Cuando es para distribuidora se toma el bruto de la factura o sea
# cantidad por precio y a este valor se le calcula el porciento

             IF cod_cia = 1 THEN
                LET valor_pagar = x.cantidad * x.porc_venta
                LET porc = x.porc_venta 
             ELSE
                LET valor_pagar = (x.cantidad * x.precio) * (x.porc_venta / 100)
                LET porc = x.porc_venta / 100
             END IF

# Para el deduc que factura en la compania que usualmente es al contado
# se le paga el porciento por valores brutos vendidos
             IF x.cond_pago = 1 THEN
                LET valor_pagar = (x.cantidad * x.precio) * x.porc_venta
                LET porc = x.porc_venta
             END IF
#-----------------------------------------------------------------------------

             PRINT COLUMN 1, x.factura using "&&&&&&",
                   COLUMN 9, x.fecha_factura using "dd/mm/yy",
                   COLUMN 20, x.cod_n using "&","-",x.cod_grupo using "&","-",
                              x.cod_tipo using "&&","-",x.cod_sec using "&&&", 
                              " ",x.descrip_esp," ";
# Cuando la compania es distribuidora (2) se imprime la cantidad por precio
# solamente.  
             IF cod_cia = 2 or x.cond_pago = 1 THEN
                PRINT COLUMN 63, x.cantidad * x.precio using "##,###,###";
                LET t_valor = t_valor + (x.cantidad * x.precio)
             END IF

             PRINT COLUMN 74, x.cantidad using "###,###",
                   COLUMN 84, porc using "###.####",
                   COLUMN 91, valor_pagar using "###,###.##"

# Esta es la acumulacion de lo que se le va ha pagar al deduc
            LET total_vend = valor_pagar + total_vend

      AFTER GROUP OF x.deduc
            PRINT COLUMN 63, "----------",
                  COLUMN 74, "-------",
                  COLUMN 91, "-----------"

            PRINT COLUMN  50, "Total A Pagar: ",
                  COLUMN  63, t_valor using "##,###,###",
                  COLUMN 74, t_unidades   using "##,###,###",
                  COLUMN 91, total_vend     using "###,###.##"
            SKIP 1 LINE
            LET total_gen = total_gen + total_vend

        AFTER GROUP OF x.factura
           SKIP 1 LINE
     ON LAST ROW
     PRINT comp_off
     END REPORT