{
 PROGRAMA          : INPRCS006
 OBJETIVO          : Programa Consulta Balances    Materia Prima.
 PROGRAMADOR       : Juan Fco. Soto (Johnny)
 FECHA REALIZACION : Agosto 18,1992. 
}
GLOBALS
  "inprgb000.4gl"
  
 MAIN                
   DEFER INTERRUPT
   CALL ARG_VAL(1) RETURNING usuarios
   CALL ARG_VAL(2) RETURNING clave
   CALL ARG_VAL(3) RETURNING impresor 
   #let usuarios = "jsoto"
   #let clave = "lmmjvsd2009"
   
   CONNECT to "decomarmol" USER  usuarios USING clave

   SELECT * INTO p_companias.* FROM companias
   CALL inprcs006()
 END MAIN

FUNCTION inprcs006()
  DEFINE fecha1 char(8)
  DEFINE hora1 char(5)
  DEFINE balance_in DECIMAL(12,2),
         query1 STRING
  
  LET fecha1 = today using "dd/mm/yy"
  LET hora1 = time
  LET int_flag = false
  LET bandera = 0
  
  #WHENEVER ERROR CONTINUE

  CLEAR SCREEN
  OPTIONS
    ERROR LINE 24,
    FORM LINE 4,
    COMMENT LINE 22,
    PROMPT LINE 23
  
  OPEN FORM infmcs006 FROM "infmcs006"
  DISPLAY FORM infmcs006
   
  INITIALIZE datos_gen.* TO NULL

 LABEL volver:
 INPUT BY NAME datos_cons.*                                   
  BEFORE FIELD fech_in
   LET datos_cons.fech_in = today using "dd/mm/yyyy"
   DISPLAY BY NAME datos_cons.fech_in

  BEFORE FIELD fech_fi
    LET datos_cons.fech_fi = today using "dd/mm/yyyy"
    DISPLAY BY NAME datos_cons.fech_fi

  AFTER FIELD cod_sec

      SELECT descrip_esp,unidad_med 
      INTO datos_cons.descrip_esp,articulos.unidad_med
      FROM intb00001
      WHERE cod_n   = datos_cons.cod_n and cod_grupo = datos_cons.cod_grupo and
            cod_tipo = datos_cons.cod_tipo and cod_sec = datos_cons.cod_sec and
            status_t is null

      IF STATUS = NOTFOUND THEN
         LET numero_msg = 3
         CALL msg(numero_msg)
         CLEAR FORM
         NEXT FIELD cod_n  
      END IF
      DISPLAY BY NAME datos_cons.descrip_esp,articulos.unidad_med

      CALL integridad()
      IF bandera = 1 THEN
         LET bandera = 0
         RETURN
      END IF

    AFTER FIELD bodega

      SELECT * FROM intb00009 where cod_bodega = datos_cons.bodega
      IF STATUS = NOTFOUND THEN
         LET numero_msg = 3
         CALL msg(numero_msg)
         NEXT FIELD bodega
      END IF

      SELECT * FROM intb00002
      WHERE cod_n = datos_cons.cod_n and cod_grupo = datos_cons.cod_grupo and
            cod_tipo = datos_cons.cod_tipo and cod_sec  = datos_cons.cod_sec and
            bodega  = datos_cons.bodega

      IF STATUS = NOTFOUND THEN
         LET numero_msg = 3
         CALL msg(numero_msg)
         CLEAR FORM
         NEXT FIELD cod_n  
      END IF

   AFTER FIELD fech_fi

      IF datos_cons.fech_fi IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD fech_in
      END IF

      IF datos_cons.fech_in IS NULL THEN
         LET numero_msg = 16
         CALL msg(numero_msg)
         NEXT FIELD fech_in
      END IF

      IF datos_cons.fech_in > datos_cons.fech_fi THEN
         LET numero_msg = 86
         CALL msg(numero_msg)
         NEXT FIELD fech_in
      END IF

   AFTER INPUT             
      EXIT INPUT
  END INPUT

  IF int_flag THEN
     LET numero_msg = 2
     CALL msg(numero_msg)
     LET int_flag = false
     CLEAR SCREEN
    RETURN
  END IF
  DISPLAY "Buscando Informacion... Espere Por Favor" AT 24,2 ATTRIBUTE (blue)

  SELECT SUM(cantidad_2) INTO balance FROM intb00006 
  WHERE cod_n = datos_cons.cod_n and cod_grupo = datos_cons.cod_grupo and
        cod_tipo = datos_cons.cod_tipo and cod_sec  = datos_cons.cod_sec and
        fecha < datos_cons.fech_in and status_t is null 
 
  IF balance is null THEN
     LET balance = 0
  END IF
  LET balance_in = balance

  DISPLAY "Balance Inicial Al: " AT 13,30 ATTRIBUTE (blue)
  DISPLAY datos_cons.fech_in using "dd/mm/yyyy" AT 13,51 ATTRIBUTE (blue)
  DISPLAY balance_in using "---,---,---.##" AT 13,61 ATTRIBUTE (blue)

  
  LET query1 = 
   "SELECT   p.num_doc,convert(char(10),p.fecha,103),p.cantidad_2,p.cod_mov ",
  " FROM intb00006 p ",
  " WHERE p.cod_n = ? and p.cod_grupo = ? and ",
        " p.cod_tipo = ? and p.cod_sec = ? and  ",
        " p.status_t is null and p.fecha between ? and ?  ",
  " ORDER BY p.fecha "
  
  PREPARE comando FROM query1
  DECLARE jhonn_1  CURSOR FOR comando
  OPEN jhonn_1 USING datos_cons.cod_n,datos_cons.cod_grupo,datos_cons.cod_tipo,
  datos_cons.cod_sec,datos_cons.fech_in,datos_cons.fech_fi
  
  LET idx = 1
  FOREACH  jhonn_1  INTO csmov.*
   CALL integridad()
   IF bandera = 1 THEN
      LET bandera = 0  
      RETURN
   END IF
   
   LET balance = balance + csmov.cantidad_2
   LET csmov1[idx].fecha_2 = csmov.fecha_1
   LET csmov1[idx].balance = balance USING "---,---,---.##"
   LET csmov1[idx].num_doc = "(",csmov.cod_mov using "&&",")"," ",
                             csmov.num_doc USING "&&&&&&"

    IF csmov.cantidad_2 < 0 THEN
       LET csmov1[idx].entrada = null
       LET csmov1[idx].salida     = csmov.cantidad_2 USING "---,---,---.##"
    ELSE 
       LET csmov1[idx].salida  = null
       LET csmov1[idx].entrada    = csmov.cantidad_2 USING "###,###,###.##"
    END IF
    IF idx < 9 THEN
       DISPLAY csmov1[idx].num_doc TO s_csmov[idx].num_doc
       DISPLAY csmov1[idx].fecha_2  TO s_csmov[idx].fecha
       DISPLAY csmov1[idx].entrada TO s_csmov[idx].entrada
       DISPLAY csmov1[idx].salida  TO s_csmov[idx].salida
       DISPLAY csmov1[idx].balance TO s_csmov[idx].balance
    END IF
    LET idx = idx + 1
 END FOREACH
 DISPLAY "                                                       " AT 24,2
 LET balance_in = 0
 CALL set_count(idx - 1)
 DISPLAY ARRAY csmov1 TO s_csmov.*
 IF int_flag THEN
    LET numero_msg = 2
    CALL msg(numero_msg)
    LET int_flag = false
    CLEAR SCREEN
    RETURN
 END IF
 CLEAR FORM
 DISPLAY "                                                       " AT 13,6
 DISPLAY "                  " AT 13,60
 GOTO volver
END FUNCTION