{
-----------------------------------------------------------------------------
FORMULARIO      : CCFMMT001
OBJETIVO        : Captura la documentacion de los Recibos de Pago (CCPRMT001)
REALIZADO POR   : Ing. Betania Guerrero Perez
FECHA           : Enero 26, 1993
-----------------------------------------------------------------------------
}
database smarmotech    
screen size 24 by 80
{
   Cuenta    [n1      ][fg                        ] Deposito [dp      ]
   Tipo      [a0][t1                   ]  Numero de Documento  [f001  ]
   Cliente   [f2]-[f003][b                          ]NCF[co              ]
   Vendedor  [f004][c                             ]     [ncf       ]
   Fecha     [f005      ]                   Valor Recibo   [vr          ] 
   Comentario[com                          ]Remanente      [re          ]
\g----------------------------------------------------------------------------\g
  No. Avance      Aplicacion   Valor Pendiente    Descuento      Valor Pagado
\g----------------------------------------------------------------------------\g
  [nnc   ]      [f006        ] [f009         ]  [pk1       ]   [f002         ]
  [nnc   ]      [f006        ] [f009         ]  [pk1       ]   [f002         ]
  [nnc   ]      [f006        ] [f009         ]  [pk1       ]   [f002         ]
                                                                =============
         Balance Documento [f012         ]    Valor Recibo     [f011         ]
}
end
tables
cctb00001
attributes
com = formonly.comentario;
ncf = formonly.kncf;
co  = formonly.codigodgii;
n1 = formonly.cuenta_no,comments="Digite cuenta asignada al banco";
dp = formonly.deposito,comments=
     "En caso de ser un pago, digite numero de deposito";
vr = formonly.valor_ctrl,comments = "Digite el Monto del Recibo o Dcto.";
fg = formonly.nombre_cta,noentry;
a0 = cctb00001.tipo_doc,autonext,upshift,include = ("NC","PG","ND","DV", "OD","OC","RC","RM"),
 comments = "PG-Pago   ND-Nota Dr.   NC-Nota Cr.   DV-Devolucion Dinero  OD- OTROS DEBITOS, OC-OTROS CREDITOS";
f011 = formonly.p_total,noentry;
f012 = formonly.nc_pend,noentry;
t1   = formonly.nombre_tipo,noentry;
f001 = cctb00001.num_doc,comments = "Digite Numero de Docuemnto";
f2 = cctb00001.tipo_cliente,autonext,default = 12,
   comments = "Presione Ctrl-W o Digite el codigo del cliente";
f003 = cctb00001.sec_cliente,autonext,
   comments = "Presione Ctrl-W o Digite el codigo del cliente";    
b = formonly.nom_cli,noentry;
f004 = cctb00001.cod_emp_sec,autonext,
   comments = "Presione Ctrl-W o Digite el codigo del vendedor";
c = formonly.nombre_emp,noentry;
f005 = cctb00001.fecha_orig,format = "dd/mm/yyyy";
pk1  = formonly.desc_p;
f006 = cctb00001.aplica_a, comments = 
"Presione Ctrl-W Para Buscar Documentos Pendientes";
f009 = formonly.valor_pen,noentry;
f002 = formonly.valor_pag;
nnc  = formonly.num_nc type integer;
re   = formonly.remanente;
instructions
 screen record s_recibo[3] (num_nc,aplica_a,valor_pen,desc_p,valor_pag)
 
 delimiters " "
end