{
-------------------------------------------------------------------------------
PROGRAMA             :  INPRRP009
OBJETIVO             :  Existencias a diferentes fechas.
PROGRAMADOR          :  Ing. Betania Guerrero Perez
FECHA REALIZACION    :  Septiembre 29, 1992
MODIFICADO POR       :  Ing. Juan Fco. Soto.
FECHA MODIFICACION   :  Octubre 27, 1992.
DESCRIPCION          :  Agregar Columna Costo Standard
-------------------------------------------------------------------------------
}
GLOBALS "inprgb000.4gl"
DEFINE total_p DECIMAL (18,4),ptotal_c DEC(18,4),
       imp1 CHAR(3), total_c SMALLINT
       
MAIN      
   WHENEVER ERROR CONTINUE          
   DEFER INTERRUPT
   CALL ARG_VAL(1) RETURNING usuarios
   CALL ARG_VAL(2) RETURNING clave
   CALL ARG_VAL(3) RETURNING impresor 
   CALL STARTLOG("inprrp009.log")
   CONNECT to "decomarmol" USER  usuarios USING clave

   SELECT * INTO p_companias.* FROM companias
   CALL integridad() 
    IF bandera <> 0 THEN
       ERROR "HA OCURRIDO UN ERROR AL CONECTARME A LA BASE DE DATOS"
    END IF   
   CALL inprrp009()
END MAIN

FUNCTION inprrp009()
    DEFINE mes CHAR(2)
    DEFINE idx_ant,idx_cos,idx_act SMALLINT
    DEFINE ano_act CHAR(4)
    DEFINE salir,primera CHAR(1)
    DEFINE balance_in DECIMAL(12,2)
    DEFINE existe RECORD
           cod_n        LIKE intb00001.cod_n,
           cod_grupo    LIKE intb00001.cod_grupo,
           cod_tipo     LIKE intb00001.cod_tipo,
           cod_sec      LIKE intb00001.cod_sec,
           descrip_esp  LIKE intb00001.descrip_esp,
           unidad_med   LIKE intb00001.unidad_med,
           existe_ant   DECIMAL(10,2),
           existe_act   DECIMAL(10,2),
           costo      LIKE intb00013.costo_st
    END RECORD

    DEFINE costos RECORD
     cod_n SMALLINT,
     cod_grupo SMALLINT,
     cod_tipo SMALLINT,
     cod_sec  SMALLINT,
     fecha CHAR(2),
     costo_st LIKE intb00013.costo_st
   END RECORD

   DEFINE actual RECORD
      cod_n  SMALLINT,
      cod_grupo SMALLINT,
      cod_tipo  SMALLINT,
      cod_sec   SMALLINT,
      balance   LIKE intb00006.cantidad_2
   END RECORD

   DEFINE anterior RECORD
      cod_n  SMALLINT,
      cod_grupo SMALLINT,
      cod_tipo  SMALLINT,
      cod_sec   SMALLINT,
      balance   LIKE intb00006.cantidad_2
   END RECORD

   DEFINE select_cost,select_act,select_ant CHAR(1000)

    # WHENEVER ERROR CONTINUE

    OPTIONS
       FORM LINE 8,
       ERROR LINE 23,
       COMMENT LINE 21

    OPEN FORM infmrp009 FROM "infmrp009"
    DISPLAY FORM infmrp009
    CALL pantalla()
    DISPLAY "inprrp009" AT 4,3
    DISPLAY "Existencias a Diferentes Fechas" AT 6,24

    LET tipo_papel = 1
    CALL msgrp000(tipo_papel)

    INPUT BY NAME datos_cons.fech_in,datos_cons.fech_fi
    AFTER FIELD fech_in
    IF datos_cons.fech_in IS NULL THEN
       LET numero_msg = 16
       CALL msg(numero_msg)
       NEXT FIELD fech_in
     END IF

    AFTER FIELD fech_fi
    IF datos_cons.fech_fi IS NULL THEN
       LET numero_msg = 16
       CALL msg(numero_msg)
       NEXT FIELD fech_in
     END IF
  END INPUT

    IF int_flag THEN
       LET numero_msg = 2
       CALL msg(numero_msg)
       LET int_flag = false
       RETURN
    END IF
     LET ano_act = year(datos_cons.fech_fi)

    CONSTRUCT criterio ON b.cod_n,b.cod_grupo, b.cod_tipo,b.cod_sec
                     FROM cod_n,cod_grupo,cod_tipo,cod_sec

   LET select_cost =
   "SELECT a.cod_n,a.cod_grupo,a.cod_tipo,a.cod_sec,max(a.mes_fin), ",
   "       a.costo_st,a.mes_ini  ",
   "FROM intb00013 a,intb00002 b ",
   "WHERE a.ano = ? and b.cod_n = a.cod_n and b.cod_grupo = a.cod_grupo and ",
   "      b.cod_tipo = b.cod_tipo and b.cod_sec  = a.cod_sec and ",
   "      b.status_t is null AND a.status_t IS NULL AND ",criterio CLIPPED,
   " GROUP BY a.cod_n,a.cod_grupo,a.cod_tipo,a.cod_sec, ",
   "       a.costo_st,a.mes_ini ORDER BY a.cod_n,a.cod_grupo,a.cod_tipo,a.cod_sec, ",
   "       a.costo_st,a.mes_ini " 

  DISPLAY "<< Estoy Buscando Los Costos Actuales >>" AT 19,14 
  ATTRIBUTE (REVERSE,BOLD) 

  LET SELEC = 
     "SELECT b.cod_n,b.cod_grupo,b.cod_tipo,b.cod_sec,b.descrip_esp, ",
     "       b.unidad_med ",
     "FROM  intb00001 b ",
     "WHERE b.status_t is null AND ",criterio clipped,
     " ORDER BY b.cod_n,b.cod_grupo,b.cod_tipo,b.cod_sec"

    DISPLAY "<< Estoy Buscando Las Materias Primas  >>"
            AT 19,14 ATTRIBUTE (REVERSE,BOLD) 

    DISPLAY "                                         "
            AT 19,14 
    DISPLAY "<< Reporte Generandose ...  Por Favor Espere. >>"
            AT 19,14 ATTRIBUTE (REVERSE) 
            
CALL defecto(usuarios,clave,impresor) RETURNING imprime,negrilla_on,negrillas_of,
                                                       doble_on,doble_off,comp_on,comp_off,
                                                       doce,normal,archivo,copia

                                                       
       LET opt1 = fgl_winquestion("Atencion","Desea Reporte por Pantalla?",
                             "no","yes|no","question",0)
       IF opt1 = "yes" THEN
          START REPORT paul TO screen
       ELSE
          START REPORT paul TO archivo
       END IF
       
    
    LET idx_ant = 1
    LET idx_act = 1
    LET idx_cos = 1
    
    LET progreso = 10
    DISPLAY progreso to progreso
    CALL ui.Interface.refresh()

  PREPARE busca_costo FROM select_cost 
  DECLARE material_costo SCROLL CURSOR FOR busca_costo
  OPEN material_costo USING ano_act
    CALL integridad() 
    
    PREPARE busca FROM selec
    DECLARE accion CURSOR FOR busca
    OPEN accion
   
    WHILE status != notfound
      FETCH   accion INTO existe.* 
       IF status = notfound THEN
          EXIT WHILE
       END IF

       IF int_flag THEN
          LET numero_msg = 2
          CALL msg(numero_msg)
          LET int_flag = false
          RETURN
       END IF
    LET progreso = progreso + 5
    IF progreso > 30 THEN
       LET progreso = 30
    END IF
    DISPLAY progreso to progreso
    CALL ui.Interface.refresh()

# Busqueda de los costos actuales     
       LET existe.costo = 0
       LET salir = "N"  
       WHILE salir != "S"
          FETCH ABSOLUTE idx_cos material_costo  INTO costos.*  
           IF status = notfound THEN
              LET idx_cos = 1
              LET salir = "S"
              EXIT WHILE
           END IF

           LET idx_cos = idx_cos + 1
          
           IF costos.cod_n     = existe.cod_n     AND
              costos.cod_grupo = existe.cod_grupo AND
              costos.cod_tipo  = existe.cod_tipo  AND
              costos.cod_sec   = existe.cod_sec   THEN
          
           LET progreso = progreso + 5
           IF progreso > 60 THEN
              LET progreso = 60
           END IF

              LET existe.costo = costos.costo_st      
              LET salir = "S"
              LET idx_cos = 1
              EXIT WHILE
           END IF
           DISPLAY progreso to progreso
           CALL ui.Interface.refresh()

        END WHILE

# Busqueda de los balances actuales y anteriores

        LET existe.existe_ant = 0
        SELECT SUM(a.cantidad_2) INTO existe.existe_ant FROM intb00006 a
        WHERE (a.cod_n = existe.cod_n AND a.cod_grupo = existe.cod_grupo AND
              a.cod_tipo = existe.cod_tipo AND a.cod_sec = existe.cod_sec) AND
              (a.status_t IS NULL) AND (a.fecha <= datos_cons.fech_in) 

        IF existe.existe_ant IS NULL THEN
           LET existe.existe_ant = 0
        END IF
        
        LET existe.existe_act = 0
        SELECT SUM(a.cantidad_2) INTO existe.existe_act FROM intb00006 a
        WHERE (a.cod_n = existe.cod_n AND a.cod_grupo = existe.cod_grupo AND
              a.cod_tipo = existe.cod_tipo AND a.cod_sec = existe.cod_sec) AND
              (a.status_t IS NULL) AND (a.fecha <= datos_cons.fech_fi) 

        IF existe.existe_act IS NULL THEN
           LET existe.existe_act = 0
        END IF
    LET progreso = progreso + 5
    IF progreso > 95 THEN
       LET progreso = 95
    END IF
    DISPLAY progreso to progreso
    CALL ui.Interface.refresh()

        OUTPUT TO REPORT paul(existe.*)
    END WHILE      
     LET progreso = 100
    DISPLAY progreso to progreso
    CALL ui.Interface.refresh()

    FINISH REPORT paul
   
    DISPLAY BY NAME total_p,ptotal_c
                                            
       LET imp1 = fgl_winquestion("Atencion","Desea Imprimir este Reporte?",
                             "no","yes|no","question",0)
    
    LET imp1 = UPSHIFT(imp1)
     LET cmd = null
    LET cmd ='copy ',archivo CLIPPED,' ', FGL_GETENV("FGLSPOOL")||"\\INRP09.txt"
   
     RUN cmd
     CALL ui.Interface.frontCall("standard","getenv", ["FILEREPORTE"], [dcmd] )
     LET cmd= FGL_GETENV("FGLSPOOL")||"\\INRP09.txt" 
     
     CALL fgl_putfile(cmd,dcmd)
   
   
    IF imp1 = "YES" THEN
    RUN imprime
    END IF
    LET total_p = 0
    LET total_c = 0
    CLEAR SCREEN
END FUNCTION

REPORT paul(x)
   DEFINE x RECORD
          cod_n       LIKE intb00001.cod_n,
          cod_grupo   LIKE intb00001.cod_grupo,
          cod_tipo    LIKE intb00001.cod_tipo,
          cod_sec     LIKE intb00001.cod_sec,
          descrip_esp LIKE intb00001.descrip_esp,
          unidad_med  LIKE intb00001.unidad_med,
          existe_ant DECIMAL(10,2),
          existe_act DECIMAL(10,2),
          costo       LIKE intb00013.costo_st
   END RECORD,
   total_costo,total_general DEC(12,2)

   DEFINE doble_on CHAR(2)
   DEFINE doble_off CHAR(2)
   DEFINE negrillas_on CHAR(2)
   DEFINE negrillas_off CHAR(2)
   DEFINE comp_on CHAR(3)
   DEFINE comp_off CHAR(2) 
   DEFINE doce CHAR(2)
   DEFINE hora CHAR(5)
   OUTPUT
   TOP MARGIN 0
   LEFT MARGIN 0
   BOTTOM MARGIN 2
   FORMAT
   PAGE HEADER
       LET doble_on =  ASCII 14
       LET doble_off = ASCII 20
       LET negrillas_on = ASCII 27, ASCII 69
       LET negrillas_off = ASCII 27, ASCII 70
       LET comp_on = ASCII 030
       LET comp_off = ASCII 18
       LET doce = ASCII 27, ASCII 77
       LET hora = time

       LET lj = (99 - LENGTH(p_companias.nombre CLIPPED))/2
       PRINT doce
       PRINT COLUMN 1, "inprrp009",
             COLUMN lj, p_companias.nombre CLIPPED,
             COLUMN 92, "Pag. ",pageno using "###"
       PRINT COLUMN 27, "    Sistema de Inventario de Materia Prima",
             COLUMN 92, today using "dd/mm/yyyy"
       PRINT COLUMN 27, "       Existencias a Diferentes Fechas",
             COLUMN 95, hora

       SKIP 1 LINES
       PRINT COLUMN 1, "--------------------------------------------------",
                       "--------------------------------------------------" 

       PRINT COLUMN 48, "Existencia",
             COLUMN 63, "Existencia",
             COLUMN 75, "Costo Std.",
             COLUMN 96, "Total"

       PRINT COLUMN 1, "Codigo",
             COLUMN 12, "Descripcion",
             COLUMN 48, "Al ",datos_cons.fech_in using "dd/mm/yyyy",
             COLUMN 63, "Al ", datos_cons.fech_fi using "dd/mm/yyyy",
             COLUMN 75, "Al ",datos_cons.fech_fi using "dd/mm/yyyy"

       PRINT COLUMN 1, "--------------------------------------------------",
                       "--------------------------------------------------"
          
      SKIP 1 LINE
      ON EVERY ROW
       IF total_p is null THEN
         LET total_p = 0
       END IF
       LET total_costo = 0
       LET total_costo = x.existe_act * x.costo

       LET total_p = total_costo + total_p
       PRINT COLUMN 1,  x.cod_n USING "&","-", x.cod_grupo USING "&","-",
                        x.cod_tipo USING "&&","-",x.cod_sec USING "&&&",
             COLUMN 12, x.descrip_esp CLIPPED,
             COLUMN 42, x.unidad_med,
             COLUMN 45, x.existe_ant USING "---,---,---.##",
             COLUMN 60, x.existe_act USING "---,---,---.##",
             COLUMN 75, x.costo USING "###,###.####",
             COLUMN 88, total_costo USING "---,---,-##.####"
     
     ON LAST ROW
       LET ptotal_c = SUM(x.existe_act) 
       PRINT COLUMN 60, "------------",
             COLUMN 88, "-------------"
       PRINT COLUMN 60, ptotal_c USING "----,---,---.##",
             COLUMN 88, total_p USING "###,###,###.##"
       

       SKIP 2 LINES
       PRINT COLUMN 1, "==================================================",
                       "=================================================="

       PRINT COLUMN 4, "Total Registros Impresos =", count(*) USING "<<<<"
       PRINT COLUMN 4, ASCII 27, ASCII 80
 END REPORT