#######################################################################
# SISTEMA   : DOCUMENTACION DE SISTEMA
# PROGRAMA  : DSPRRP006.4GL
# OBJETIVO  : Relacion de Programas y Tablas
# AUTOR     : Tadeo A. Ferreras F.
# FECHA     : JUNIO 30, 1995
########################################################################
DATABASE rayovac
GLOBALS
 "dsprgb000.4gl" 

 DEFINE opt1 CHAR(1)

FUNCTION dsprrp006()

OPTIONS
  FORM LINE 8,
  ERROR LINE 23,
  PROMPT LINE 23

  OPEN FORM dsfmrp006 FROM "dsfmrp006"
  DISPLAY FORM dsfmrp006 
  CALL pantalla()
  DISPLAY "dsprrp006" AT 4,3 ATTRIBUTE(RED)
  DISPLAY "Relacion de Programas y Tablas" AT 6,25 ATTRIBUTE(BLACK)

  LET tipo_papel = 1
  CALL msgrp000(tipo_papel)

   CONSTRUCT criterio ON b.cod_sistema,a.programa,a.tabla 
                    FROM cod_sistema,programa,tabla

   IF int_flag THEN
      LET numero_msg = 2
      CALL msg(numero_msg)
      LET int_flag = FALSE
      RETURN
   END IF

   LET selec = 
    "SELECT UNIQUE b.cod_sistema,a.programa,b.descripcion,a.tabla, ",
    "              c.descripcion ",
    "FROM dstb00006 a, dstb00001 b, OUTER dstb00005 c ",
    "WHERE a.programa = b.programa AND a.status_t IS NULL AND ",
    "      a.tabla = c.tabla AND b.status_t IS NULL AND ",
    "      c.status_t IS NULL AND ",criterio CLIPPED

    DISPLAY "<< Buscando Informacion... Espere Por Favor >>" AT 19,14

    PREPARE comando FROM selec
    DECLARE busca CURSOR FOR comando
    
    START REPORT reporte6 TO "c:\dsrp06"

    DISPLAY "<< Reporte Generandose...  Espere Por Favor >>" AT 19,14

    FOREACH busca INTO reg_imp6.*
       IF int_flag THEN
          LET numero_msg = 2
          CALL msg(numero_msg)
          LET int_flag = FALSE
          RETURN
       END IF

       OUTPUT TO REPORT reporte6(reg_imp6.*)
    END FOREACH
    FINISH REPORT reporte6
    RUN "type c:\dsrp06 > \\rovdom2\contabi"
END FUNCTION

REPORT reporte6(x)
 DEFINE x RECORD
    cod_sistema     CHAR(2),
    programa        LIKE dstb00006.programa,
    descripcion_p   CHAR(60),
    tabla           LIKE dstb00006.tabla,           
    descripcion_t   CHAR(60)
 END RECORD
 DEFINE entr1 ARRAY[200] OF CHAR(60)
 DEFINE proc1 ARRAY[200] OF CHAR(60)
 DEFINE sali1 ARRAY[200] OF CHAR(60)
 DEFINE sistema CHAR(35)
 DEFINE negrillas_on,negrillas_off,comp_on,comp_off,normal CHAR(2)
 DEFINE hora char(5)

  OUTPUT
  LEFT MARGIN 0
  ORDER BY x.cod_sistema,x.programa,x.tabla

 FORMAT
 PAGE HEADER
    LET negrillas_on = ASCII 27,ASCII 69
    LET negrillas_off = ASCII 27,ASCII 70
    LET comp_on       = ASCII 15
    LET comp_off      = ASCII 18
    LET normal        = ASCII 27, ASCII 80 
    LET hora          = TIME     

  PRINT COLUMN   1, negrillas_on,comp_off
  PRINT COLUMN   1, "dsprrp006",
        COLUMN  17, "R A Y . O . V A C  D O M I N I C A N A,  S. A.",
        COLUMN  73, "Pag. ", PAGENO USING "###"
  PRINT COLUMN  17, "           GERENCIA DE INFORMATICA",
        COLUMN  73, TODAY USING "dd/mm/yyyy"
  PRINT COLUMN  17, "       RELACION DE PROGRAMAS Y TABLAS",
        COLUMN  76, hora

  PRINT comp_on
  PRINT COLUMN  4, "PROGRAMA",
        COLUMN 72, "TABLA"
  PRINT negrillas_off

  BEFORE GROUP OF x.cod_sistema
   SKIP TO TOP OF PAGE

   SELECT a.desc_sistema INTO dstb03.desc_sistema FROM dstb00003 a
   WHERE a.cod_sistema = x.cod_sistema AND a.status_t IS NULL

   IF STATUS = NOTFOUND THEN
      LET dstb03.desc_sistema = "SIN DESCRIPCION"
   END IF

   PRINT COLUMN   4, negrillas_on,x.cod_sistema CLIPPED," ",
                    dstb03.desc_sistema CLIPPED,negrillas_off
   SKIP 1 LINE

  BEFORE GROUP OF x.programa

   SKIP 1 LINE
   PRINT COLUMN  4, x.programa CLIPPED," ",x.descripcion_p CLIPPED;
 
  ON EVERY ROW
  
   PRINT COLUMN 74, x.tabla CLIPPED," ",x.descripcion_t CLIPPED 

 # AFTER GROUP OF x.cod_sistema
 #  SKIP TO TOP OF PAGE

  ON LAST ROW
   PRINT comp_off
 END REPORT