#######################################################################
# SISTEMA   : DOCUMENTACION DE TABLA 
# PROGRAMA  : DSPRRP005.4GL
# OBJETIVO  : Documentacion de Las Tablas de cada Sistema
# AUTOR     : Tadeo A. Ferreras F.
# FECHA     : JUNIO 14, 1995
########################################################################
DATABASE rayovac
GLOBALS
 "dsprgb000.4gl" 

 DEFINE opt1 CHAR(1)
 DEFINE fecha2 DATE
 DEFINE num_emp2 INTEGER
 DEFINE impresor,printer SMALLINT,       
        archivo,archivo1 CHAR(20),
        imprime,imprime1 CHAR(80),
 letras RECORD  
       negrillas_on  CHAR(6),
       negrillas_off CHAR(6),
       doble_on      CHAR(6),
       doble_off     CHAR(6),
       comp_on       CHAR(6),
       comp_off      CHAR(6),
       doce          CHAR(6),
       normal        CHAR(6)
END RECORD

FUNCTION dsprrp005()

OPTIONS
  FORM LINE 8,
  ERROR LINE 23,
  PROMPT LINE 23
 
  LET impresor = FGL_GETENV("IMP") 
  CALL defecto(impresor) RETURNING imprime, letras.*,archivo 
 
  OPEN FORM dsfmrp005 FROM "dsfmrp005"
  DISPLAY FORM dsfmrp005 
  CALL pantalla()
  DISPLAY "dsprrp005" AT 4,3 ATTRIBUTE(RED)
  DISPLAY "Documentacion de Tablas" AT 6,28 ATTRIBUTE(BLACK)

  LET tipo_papel = 1
  CALL msgrp000(tipo_papel)

   CONSTRUCT criterio ON a.tabla,a.numero_act FROM tabla,numero_act 

   IF int_flag THEN
      LET numero_msg = 2
      CALL msg(numero_msg)
      LET int_flag = FALSE
      RETURN
   END IF

   LET selec = 
    "SELECT a.* FROM dstb00005 a WHERE a.status_t IS NULL AND ",
    criterio CLIPPED," ORDER BY a.secuencia "

    DISPLAY "<< Buscando Informacion... Espere Por Favor >>" AT 19,14

    PREPARE comando FROM selec
    DECLARE busca CURSOR FOR comando
    
    START REPORT reporte5 TO "c:\\dsrp05"

    DISPLAY "<< Reporte Generandose...  Espere Por Favor >>" AT 19,14

    FOREACH busca INTO reg_tab.*
       IF int_flag THEN
          LET numero_msg = 2
          CALL msg(numero_msg)
          LET int_flag = FALSE
          RETURN
       END IF

       OUTPUT TO REPORT reporte5(reg_tab.*)
    END FOREACH
    FINISH REPORT reporte5
    RUN  "type c:\dsrp05 > \\ROVDOM2\contabi"
END FUNCTION

REPORT reporte5(x)
 DEFINE x RECORD LIKE dstb00005.*
 DEFINE entr1 ARRAY[200] OF CHAR(60)
 DEFINE proc1 ARRAY[200] OF CHAR(60)
 DEFINE sali1 ARRAY[200] OF CHAR(60)
 DEFINE sistema CHAR(35)
 DEFINE doce,negrillas_on,negrillas_off,comp_on,comp_off,normal CHAR(2)
 DEFINE hora char(5)

  OUTPUT
  LEFT MARGIN 0
  ORDER BY x.tabla,x.numero_act

 FORMAT
 PAGE HEADER
    LET negrillas_on = ASCII 27,ASCII 69
    LET negrillas_off = ASCII 27,ASCII 70
    LET doce          = ASCII 27,ASCII 77
    LET comp_on       = ASCII 15
    LET comp_off      = ASCII 18
    LET normal        = ASCII 27, ASCII 80 
    LET hora          = TIME     

    PRINT COLUMN  1, negrillas_on,doce
    PRINT COLUMN  1, "dsprrp005",
          COLUMN 26, "R A Y . O . V A C  D O M I N I C A N A,  S. A.",
          COLUMN 91, "Pag. ",PAGENO USING "###"
    PRINT COLUMN 26, "           GERENCIA DE INFORMATICA",
          COLUMN 91, TODAY USING "dd/mm/yyyy"
    PRINT COLUMN 26, "           DOCUMENTACION DE TABLAS",
          COLUMN 94, hora
    PRINT negrillas_off

  BEFORE GROUP OF x.tabla
    SELECT UNIQUE a.num_emp1,a.fecha_creacion INTO num_emp2,fecha2 
    FROM dstb00005 a
    WHERE a.tabla = x.tabla  AND a.numero_act = 1
   
    SELECT a.nom1_emp,a.apell1_emp INTO nombre1,apellido1 FROM adtb00003 a
    WHERE a.num_emp = num_emp2    
   
    LET nombre = nombre1 CLIPPED," ",apellido1 CLIPPED
 
  BEFORE GROUP OF x.numero_act
    SKIP TO TOP OF PAGE
    PRINT negrillas_on 
    PRINT COLUMN  1, "NOMBRE DE LA TABLA : ", x.tabla
    PRINT COLUMN  1, "DESCRIPCION        : ", x.descripcion CLIPPED
    PRINT COLUMN  1, "USUARIO CREADOR    : ", "(",num_emp2 USING "####",") ",
                                               nombre CLIPPED
    PRINT COLUMN  1, "FECHA CREACION     : ", fecha2 USING "dd/mm/yyyy"
    PRINT negrillas_off

    IF x.numero_act > 1 THEN
       LET sistema = NULL
       SELECT a.nom1_emp,a.apell1_emp INTO nombre1,apellido1 FROM adtb00003 a
       WHERE a.num_emp = x.num_emp1    
 
       LET nombre = nombre1 CLIPPED," ",apellido1 CLIPPED
   
       PRINT negrillas_on 
       PRINT COLUMN 1,"USUARIO MODIFICADOR: ","(",x.num_emp1 USING "####",") ",
                                          nombre CLIPPED
       PRINT COLUMN 1,"FECHA ACTUALIZACION: ",x.fecha_creacion USING "dd/mm/yyyy",
             COLUMN 45, "ACTUALIZACION NO.: ", x.numero_act USING "####"
       PRINT negrillas_off
    END IF

    PRINT COLUMN  1, "----------------------------------------------------",
                     "----------------------------------------------"
    PRINT COLUMN  1, "Campo",
          COLUMN 20, "Descripcion Campo",
          COLUMN 74, "Tipo",
          COLUMN 82, "Longitud"
    PRINT COLUMN  1, "----------------------------------------------------",
                     "----------------------------------------------"
    PRINT negrillas_off
    LET j = 0

  ON EVERY ROW 
    SKIP 1 LINE
    PRINT COLUMN  1, x.campo CLIPPED,
          COLUMN 20, x.descrip_campo[1,50] CLIPPED,
          COLUMN 72, x.tipo CLIPPED,
          COLUMN 82, x.longitud CLIPPED

   IF x.descrip_campo[51,100] != " " THEN
      PRINT  COLUMN 20, x.descrip_campo[51,100] CLIPPED
   END IF
   IF x.descrip_campo[101,150] != " " THEN
      PRINT  COLUMN 20, x.descrip_campo[101,150] CLIPPED
   END IF

  #AFTER GROUP OF x.numero_act
   #SKIP TO TOP OF PAGE

  ON LAST ROW
    PRINT normal
 END REPORT